CEURLKAN ; Conversie klantenanalyse naar Euro (^KLKAN) ;[ 05/17/2001  10:48 AM ]
 Quit
 ;
T1 ;Wenst u alle klantenanalyse naar Euro te converteren?
T2 ;Conversie klantenanalyse naar Euro (^KLKAN)
 ;
RUN(TxtPop) 
 New (TxtPop)
 Do
 .New TxtPop
 .Do INIT^vhTERMINA
 Set TxtPop=$G(TxtPop,1),Run=1
 Do:TxtPop
 .Write @F11,@F1
 .Set Txt(1)=$P($T(T1),";",2),Run=$$TXTPOP^CEUR(.Txt)
 Do:Run
 .Write !,$ZN,?10,$P($T(T2),";",2)
 .Kill ^CEURERR($ZN)
 .Set KLNr=0
 .For  Set KLNr=$O(^KLKAN(KLNr)) Quit:KLNr=""  Do ONECUST(KLNr)
 .Set Global=$P($P($T(T2),"(",2),")")
 .Do COMPRESS^CEUR(Global)
 Quit
 ;
ONECUST(KLNr) 
 New I,R,PRNr,FromMunt,ToMunt,Maand
 Set FromMunt="BEF",ToMunt="EUR"
 Set PRNr=""
 For  Set PRNr=$O(^KLKAN(KLNr,PRNr)) Quit:PRNr=""  Do
 .Set Maand=""
 .For  Set Maand=$O(^KLKAN(KLNr,PRNr,Maand)) Quit:Maand=""  Do
 ..Set R=^KLKAN(KLNr,PRNr,Maand)
 ..For I=1:1:15 Set $P(R,D,I)=$$BEDRAG^CEUR($P(R,D,I),FromMunt,ToMunt)
 ..Set ^KLKAN(KLNr,PRNr,Maand)=R
 Quit
 ;
DOC 
 ;Conversie ^KLKAN (Klantenanalyse)
 ;
 ;
 ;Routine: RUN^CEURLKAN()
 ;
 ;
 ;Geconverteerde nodes:
 ;
 ;^KLKAN(KLNr,PRNr,Maand)
 ;  Velden 1 t.e.m. 15 in BEF omrekenen naar EUR
 ;***
 New L,R
 Write !,$ZN,!
 For L=1:1 Set R=$T(DOC+L) Quit:R=""!($P(R,";",2)="***")  Do
 .If $E(R)=" " Write !?5,$P(R,";",2,99)
 .Else  Xecute $P(R,";")_$P(R,";",2,99)
 Quit
 ;