CEURMBST ; Conversie moederbonstatistiek naar Euro (^MBSTAT) ;[ 03/15/2001  9:21 AM ]
 Quit
 ;
T1 ;Wenst u alle moederbonstatistiek naar Euro te converteren?
T2 ;Conversie moederbonstatistiek naar Euro (^MBSTAT)
 ;
RUN(TxtPop) 
 New (TxtPop)
 Do
 .New TxtPop
 .Do INIT^vhTERMINA
 Set TxtPop=$G(TxtPop,1),Run=1
 Do:TxtPop
 .Write @F11,@F1
 .Set Txt(1)=$P($T(T1),";",2),Run=$$TXTPOP^CEUR(.Txt)
 Do:Run
 .Write !,$ZN,?10,$P($T(T2),";",2)
 .Kill ^CEURERR($ZN)
 .Set KLNr=0
 .For  Set KLNr=$O(^MBSTAT(KLNr)) Quit:KLNr=""  Do ONECUST(KLNr)
 Quit
 ;
ONECUST(KLNr) 
 New I,R,PRNr,Maand,FromMunt,ToMunt
 Set FromMunt="BEF",ToMunt="EUR"
 Set PRNr=""
 For  Set PRNr=$O(^MBSTAT(KLNr,PRNr)) Quit:PRNr=""  Do
 .Set Maand=""
 .For  Set Maand=$O(^MBSTAT(KLNr,PRNr,Maand)) Quit:Maand=""  Do
 ..Set R=^MBSTAT(KLNr,PRNr,Maand)
 ..If Maand=0 Do
 ...Set $P(R,D,5)=$$MUNT^vhRtn1(ToMunt,,,,$P(R,D,4))
 ..Else  For I=3,4,6 Set $P(R,D,I)=$$BEDRAG^CEUR($P(R,D,I),FromMunt,ToMunt)
 ..Set ^MBSTAT(KLNr,PRNr,Maand)=R
 Quit
 ;
DOC 
 ;Conversie ^MBSTAT (Moederbonstatistiek)
 ;
 ;
 ;Routine: RUN^CEURMBST()
 ;
 ;
 ;Geconverteerde nodes:
 ;
 ;^MBSTAT(KLNr,PRNr,0)
 ;  Veld 5  : de pariteit t.o.v. de Euro (ook voor de euro)
 ;
 ;^MBSTAT(KLNr,PRNr,Maand)
 ;  Velden 3, 4 en 6 in BEF omrekenen naar EUR
 ;***
 New L,R
 Write !,$ZN,!
 For L=1:1 Set R=$T(DOC+L) Quit:R=""!($P(R,";",2)="***")  Do
 .If $E(R)=" " Write !?5,$P(R,";",2,99)
 .Else  Xecute $P(R,";")_$P(R,";",2,99)
 Quit
 ;