CEURSTPR ; Conversie produktenstatistiek naar Euro (^KSTPR) ;[ 05/17/2001  10:31 AM ]
 Quit
 ;
T1 ;Wenst u alle produktenstatistiek naar Euro te converteren?
T2 ;Conversie produktenstatistiek naar Euro (^KSTPR)
 ;
RUN(TxtPop) 
 New (TxtPop)
 Do
 .New TxtPop
 .Do INIT^vhTERMINA
 Set TxtPop=$G(TxtPop,1),Run=1
 Do:TxtPop
 .Write @F11,@F1
 .Set Txt(1)=$P($T(T1),";",2),Run=$$TXTPOP^CEUR(.Txt)
 Do:Run
 .Write !,$ZN,?10,$P($T(T2),";",2)
 .Kill ^CEURERR($ZN)
 .Set PRNr=0
 .For  Set PRNr=$O(^KSTPR(PRNr)) Quit:PRNr=""  Do ONEPROD(PRNr)
 .Set Global=$P($P($T(T2),"(",2),")")
 .Do COMPRESS^CEUR(Global)
 Quit
 ;
ONEPROD(PRNr) 
 New I,R,KLNr,Maand,FromMunt,ToMunt
 Set FromMunt="BEF",ToMunt="EUR"
 Set KLNr=""
 For  Set KLNr=$O(^KSTPR(PRNr,KLNr)) Quit:KLNr=""  Do
 .Set Maand=""
 .For  Set Maand=$O(^KSTPR(PRNr,KLNr,Maand)) Quit:Maand=""  Do
 ..Set R=^KSTPR(PRNr,KLNr,Maand)
 ..If Maand=0 Do
 ...Set $P(R,D,5)=$$MUNT^vhRtn1(ToMunt,,,,$P(R,D,4))
 ..Else  For I=3,4,6 Set $P(R,D,I)=$$BEDRAG^CEUR($P(R,D,I),FromMunt,ToMunt)
 ..Set ^KSTPR(PRNr,KLNr,Maand)=R
 Quit
 ;
DOC 
 ;Conversie ^KSTPR (Produktenstatistiek)
 ;
 ;
 ;Routine: RUN^CEURSTPR()
 ;
 ;
 ;Geconverteerde nodes:
 ;
 ;^KSTPR(PRNr,KLNr,0)   
 ;  Veld 5  : de pariteit t.o.v. de Euro (ook voor de euro)
 ;
 ;^KSTPR(PRNr,KLNr,Maand)
 ;  Velden 3, 4 en 6 in BEF omrekenen naar EUR
 ;***
 New L,R
 Write !,$ZN,!
 For L=1:1 Set R=$T(DOC+L) Quit:R=""!($P(R,";",2)="***")  Do
 .If $E(R)=" " Write !?5,$P(R,";",2,99)
 .Else  Xecute $P(R,";")_$P(R,";",2,99)
 Quit
 ;