CONBI ;Kontrole kontrakten, produkten zonder bestelimpuls [ 04/23/2003  10:40 AM ]
 ;
 Do INIT^vhTERMINA
 Set %J=$$%J^vhRtn1()
 Kill ^HULP(%J)
 ; Doorlopen orders
 Set KLNr=0
 For  Set KLNr=$O(^KOD(KLNr)) Quit:KLNr=""  Do
 .Set KlantInd=^KK1(KLNr),ORDNr=0
 .For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:ORDNr=""  Do
 ..Quit:$P(^KOD(KLNr,"F",ORDNr,1),D,25)'="C"  ; Geen contract
 ..Set OLNr=99
 ..For  Set OLNr=$O(^KOD(KLNr,"F",ORDNr,OLNr)) Quit:OLNr=""  Do
 ...Set Rec=^KOD(KLNr,"F",ORDNr,OLNr),PRNr=$P(Rec,D,2)
 ...Quit:'PRNr 
 ...If '$D(^KPBI("D",KLNr,PRNr)) Do  ; Geen bestelimpuls
 ....Set SortKey=$$SORTKEY^PRODUKT(PRNr) Set:SortKey="" SortKey=PRNr Set ^HULP(%J,"BI",KlantInd,SortKey)=PRNr
 ...Set LeverDag=$P(Rec,D,25)
 ...Set:LeverDag'?5N LeverDag=$$INTDATE^vhDTyp(LeverDag,"DW")
 ...If LeverDag<+$H Do  ; Leveringstermijn verstreken
 ....Set SortKey=$$SORTKEY^PRODUKT(PRNr) Set:SortKey="" SortKey=PRNr Set ^HULP(%J,"LW",KlantInd,SortKey)=PRNr_D_$P(Rec,D,3)_D_$P(Rec,D,25)
 
 ; Geen bestelimpuls
 If $D(^HULP(%J,"BI")) Do
 .New R,From,To,Subject,Body,Count,KlantInd,KlantNaam,SortKey,Rec,PRNr,KortText,Status
 .Set From=$ZUTIL(110)_"@VANHOECKE.BE"
 .Set To=$$USERNAME^vhUSER("VDR","@",1) Set:To="" To=$$USERNAME^vhUSER("CW","@",1)
 .Set Subject="Contractorders (producten zonder bestelimpuls)"
 .Set Body="Volgende klant"_$S($O(^($O(^HULP(%J,"BI",""))))="":" heeft",1:"en hebben")
 .Set Body=Body_" contracten zonder bestelimpuls :"_$C(13),Count=0,KlantInd=""
 .For  Set KlantInd=$O(^HULP(%J,"BI",KlantInd)) Quit:KlantInd=""  Do
 ..Set Count=Count+1
 ..Set:Count>1 R="",$P(R,"-",54)="",$E(R,27)="|",Body=Body_$C(13)_R
 ..Set KlantNaam=$P(^KKL(KlantInd,0),D,2),SortKey=""
 ..For  Set SortKey=$O(^HULP(%J,"BI",KlantInd,SortKey)) Quit:SortKey=""  Do
 ...Set Rec=^HULP(%J,"BI",KlantInd,SortKey)
 ...Set PRNr=$P(Rec,D),KortText=$P(^KPR(PRNr,0),D)
 ...Set Body=Body_$C(13)_KlantNaam_$J("",26-$L(KlantNaam))_"| "_KortText,KlantNaam=""
 .Set Status=$$SendMiniMail^vhLib(From,To,Subject,Body)
 
 ; Verstreken kontrakten
 If $D(^HULP(%J,"LW")) Do
 .New R,From,To,Subject,Body,Count,KlantInd,KlantNaam,SortKey,Rec,PRNr,KortText,Status
 .Set From=$ZUTIL(110)_"@VANHOECKE.BE"
 .Set To=$$USERNAME^vhUSER("VDR;PVH;LDS","@",1) Set:To="" To=$$USERNAME^vhUSER("CW","@",1)
 .Set Subject="Contractorders (verstreken contracten)"
 .Set Body="Volgende klant"_$S($O(^($O(^HULP(%J,"LW",""))))="":" heeft",1:"en hebben")
 .Set Body=Body_" contracten die verstreken zijn :"_$C(13),Count=0,KlantInd=""
 .For  Set KlantInd=$O(^HULP(%J,"LW",KlantInd)) Quit:KlantInd=""  Do
 ..Set Count=Count+1
 ..Set:Count>1 R="",$P(R,"-",70)="",$E(R,27)="|",$E(R,55)="|",$E(R,63)="|",Body=Body_$C(13)_R
 ..Set KlantNaam=$P(^KKL(KlantInd,0),D,2),SortKey=""
 ..For  Set SortKey=$O(^HULP(%J,"LW",KlantInd,SortKey)) Quit:SortKey=""  Do
 ...Set Rec=^HULP(%J,"LW",KlantInd,SortKey)
 ...Set PRNr=$P(Rec,D),KortText=$P(^KPR(PRNr,0),D)
 ...Set Body=Body_$C(13)_$E(KlantNaam,1,26)_$J("",26-$L(KlantNaam))_"| "_KortText_" | "_$P(Rec,D,3)_" | "_$P(Rec,D,2),KlantNaam=""
 .Set Status=$$SendMiniMail^vhLib(From,To,Subject,Body)
 Kill ^HULP(%J)
 Quit
 ;