EWORDS3 ;E'WMS Markeren voor orderpicking [ 11/28/2003  10:51 AM ]
 ;
 ; Order mag gegroepeerd worden
CUMORD(Ref) 
 New R,CumOrd,EenOPerB,ORDNr,LevAdr,FaktAdr,LevVw,Munt,Export,NetBrut
 New DeurOrd,Bewaar,OrdTyp,VerwTyp,IsOrgal,VerpTyp,AventosAppart
 New VNode
 Kill:'$D(^HULP(%J,KLNr,"M","A")) ^HULP(%J,KLNr,"C")
 Set R=^HULP(%J,KLNr,"O",Ref),ORDNr=$P(R,D)
 Quit:$D(^HULP(%J,KLNr,"M","A",ORDNr)) 1
 Set CumOrd=1,Bewaar=""
 Do EENOPERB
 If CumOrd,'$L(Bewaar) Do AventosAppart
 If CumOrd,'$L(Bewaar) Do LEVADR
 If CumOrd,'$L(Bewaar) Do LEVVW
 If CumOrd,'$L(Bewaar) Do FAKTADR
 If CumOrd,'$L(Bewaar) Do MUNT
 If CumOrd,'$L(Bewaar) Do NETBRUT
 If CumOrd,'$L(Bewaar) Do EXPORT
 If CumOrd,'$L(Bewaar) Do DEUR
 If CumOrd,'$L(Bewaar) Do ORDTYP
 If CumOrd,'$L(Bewaar) Do ORGAL
 If CumOrd,'$L(Bewaar) Do VERPTYP
 If CumOrd,'$L(Bewaar) Do VERZW
 If CumOrd,'$L(Bewaar) Do TRANSPORTLINK
 
 If CumOrd,$L(Bewaar) Do
 . If Bewaar'=0,Bewaar'=1 Quit
 . If Bewaar Do
 . . Merge VNode=^HULP(%J,KLNr,"V")
 . . Do BEWAAR^EWORDS(.Ref)
 . . Merge ^HULP(%J,KLNr,"V")=VNode
 . . Do DISPLAY^vhScherm("EWORDSH",,,,"VERZWIJZE;GERAAPT;VERZZONE;VERZDATUM",1)
 . Else  Do
 . . Kill ^HULP(%J,KLNr,"M","A"),^HULP(%J,KLNr,"C")
 . . Do WRITE^vhLIST(.LD)
 . Set CumOrd=$$CUMORD(Ref)
 Quit CumOrd
 ;
 ; Een order per bon
EENOPERB 
 Set R=^HULP(%J,KLNr,"K",1),EenOPerB=$P(R,D,18)
 Set:EenOPerB=3 EenOPerB=0 ; Meerdere orders per bon, een bon per factuur
 If EenOPerB Do
 .Quit:'$D(^HULP(%J,KLNr,"M","A"))  Quit:$D(^HULP(%J,KLNr,"M","A",ORDNr))
 .Set Bewaar=$$^vhTXTPOP("EWORDS","EENOPERB")
 .Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
 ; Een Aventosorder per bon
AventosAppart 
 New TempORDNr
 Set R=^HULP(%J,KLNr,"K",1),AventosAppart=$G(^AventosAppart(KLNr)) ;$P(R,D,??)
 If AventosAppart Do
 .Quit:'$D(^HULP(%J,KLNr,"M","A"))  Quit:$D(^HULP(%J,KLNr,"M","A",ORDNr))
 .Set TempORDNr=$O(^HULP(%J,KLNr,"M","A",""))
 .If '$$BevatAventos^FLOW("O",ORDNr),'$$BevatAventos^FLOW("O",TempORDNr) Quit
 .Set Bewaar=$$^vhTXTPOP("EWORDS","AventosAppart")
 .Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
 ; Leveringsadres
LEVADR 
 New Param1,Param2,Param3,Param4,Param5,Param6
 Set LevAdr=^KOD(KLNr,"F",ORDNr,3)
 If '$D(^HULP(%J,KLNr,"C","LA")) Set ^HULP(%J,KLNr,"C","LA")=LevAdr
 Quit:$P(^HULP(%J,KLNr,"C","LA"),D,2,7)=$P(LevAdr,D,2,7)
 Set R=^HULP(%J,KLNr,"C","LA") Set:$P(R,D,2)="" R="\Zonder leveringsadres"
 Set:$P(LevAdr,D,2)="" LevAdr="\Zonder leveringsadres"
 Set Param1=$P(R,D,2),Param2=$P(R,D,5),Param3=$P(R,D,7)
 Set Param4=$P(LevAdr,D,2),Param5=$P(LevAdr,D,5),Param6=$P(LevAdr,D,7)
 Set Bewaar=$$^vhTXTPOP("EWORDS","LEVADR",,Param1,Param2,Param3,Param4,Param5,Param6)
 Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
 ; Leveringsvoorwaarde
LEVVW 
 New Param1,Param2
 Set R=^KOD(KLNr,"F",ORDNr,1),LevVw=$P(R,D,21)
 If '$D(^HULP(%J,KLNr,"C","LV")) Set ^HULP(%J,KLNr,"C","LV")=LevVw
 Quit:^HULP(%J,KLNr,"C","LV")=LevVw
 Set R=^HULP(%J,KLNr,"C","LV")
 Set Param1=R,Param2=LevVw
 Set Bewaar=$$^vhTXTPOP("EWORDS","LEVVW",,Param1,Param2)
 Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
 ; Fakturatieadres
FAKTADR 
 New Param1,Param2
 .Set R=^KOD(KLNr,"F",ORDNr,1),FaktAdr=$P(R,D,6)
 .If '$D(^HULP(%J,KLNr,"C","FA")) Set ^HULP(%J,KLNr,"C","FA")=FaktAdr
 .Quit:^HULP(%J,KLNr,"C","FA")=FaktAdr
 .Set R=^HULP(%J,KLNr,"C","FA")
 .Set Param1=R_" "_$P(^KKL(^KK1(R),0),D,2),Param2=FaktAdr_" "_$P(^KKL(^KK1(FaktAdr),0),D,2)
 .Set Bewaar=$$^vhTXTPOP("EWORDS","FAKTADR",,Param1,Param2)
 .Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
 ; Munt order
MUNT 
 New Param1,Param2
 Set R=^KOD(KLNr,"F",ORDNr,1),Munt=$P(R,D,18)
 If '$D(^HULP(%J,KLNr,"C","MT")) Set ^HULP(%J,KLNr,"C","MT")=Munt
 Quit:^HULP(%J,KLNr,"C","MT")=Munt
 Set R=^HULP(%J,KLNr,"C","MT")
 Set Param1=R,Param2=Munt
 Set Bewaar=$$^vhTXTPOP("EWORDS","MUNT",,Param1,Param2)
 Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
 ; Prijstype
NETBRUT 
 New Param1,Param2
 Set R=^KOD(KLNr,"F",ORDNr,1),NetBrut=$P(R,D,27)
 If '$D(^HULP(%J,KLNr,"C","NB")) Set ^HULP(%J,KLNr,"C","NB")=NetBrut
 Quit:^HULP(%J,KLNr,"C","NB")=NetBrut
 Set R=^HULP(%J,KLNr,"C","NB")
 Set Param1=$P("Netto\Bruto",D,R+1)_" prijzen",Param2=$P("Netto\Bruto",D,NetBrut+1)_" prijzen"
 Set Bewaar=$$^vhTXTPOP("EWORDS","NETBRUT",,Param1,Param2)
 Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
 ; Export
EXPORT 
 New Param1,Param2
 Set R=^KOD(KLNr,"F",ORDNr,1),Export=$P(R,D,14)
 If '$D(^HULP(%J,KLNr,"C","EX")) Set ^HULP(%J,KLNr,"C","EX")=Export
 Quit:^HULP(%J,KLNr,"C","EX")=Export
 Set R=^HULP(%J,KLNr,"C","EX")
 Set Param1=$P("Niet v\V",D,R+1)_"oor export",Param2=$P("Niet v\V",D,Export+1)_"oor export"
 Set Bewaar=$$^vhTXTPOP("EWORDS","EXPORT",,Param1,Param2)
 Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
 ; Burbidge-Folietec
DEUR 
 New Param1,Param2
 Set DeurOrd=$$DEURORD(KLNr,ORDNr)
 If '$D(^HULP(%J,KLNr,"C","DE")) Set ^HULP(%J,KLNr,"C","DE")=DeurOrd
 Quit:^HULP(%J,KLNr,"C","DE")=DeurOrd
 Set R=^HULP(%J,KLNr,"C","DE")
 Set Param1=$S(R["B":$P(^KLE(^KL1(5810),0),D,2),R["F":$P(^KLE(^KL1(6092),0),D,2),1:"Geen deuren")
 Set Param2=$S(DeurOrd["B":$P(^KLE(^KL1(5810),0),D,2),DeurOrd["F":$P(^KLE(^KL1(6092),0),D,2),1:"Geen deuren")
 Set Bewaar=$$^vhTXTPOP("EWORDS","DEUR",,Param1,Param2)
 Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
 ; Monster en proforma
ORDTYP 
 New Param1,Param2
 Set R=^KOD(KLNr,"F",ORDNr,1),OrdTyp=$P(R,D,25),VerwTyp=$P(R,D,29)
 Set:OrdTyp="K" OrdTyp=""
 If '$D(^HULP(%J,KLNr,"C","TO")) Set ^HULP(%J,KLNr,"C","TO")=OrdTyp
 If '$D(^HULP(%J,KLNr,"C","TV")) Set ^HULP(%J,KLNr,"C","TV")=VerwTyp
 If ^HULP(%J,KLNr,"C","TO")=OrdTyp,^HULP(%J,KLNr,"C","TV")=VerwTyp Quit
 Set R=^HULP(%J,KLNr,"C","TO")
 If OrdTyp'="M",OrdTyp'="P" Set OrdTyp=R
 Set R=^HULP(%J,KLNr,"C","TV")
 If VerwTyp'="F",VerwTyp'="P" Set VerwTyp=R
 Set Param2=$S(VerwTyp="P":"met",1:"zonder")_" "_$S(OrdTyp="M":"proforma",1:"")_"faktuur"
 Set Param1=$S(OrdTyp="M":"monster",1:"proforma")
 Set Bewaar=$$^vhTXTPOP("EWORDS","ORDTYP",,Param1,Param2)
 Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
 ; Verzendwijze
VERZW 
 New Param1,Param2,Param3
 Set VerzW=$$DEFAULT^KLVERZW(,KLNr,ORDNr)
 Quit:'$D(^HULP(%J,KLNr,"V"))  Quit:$P($P(^HULP(%J,KLNr,"V"),D),";")=$P(VerzW,";")
 Set R=$P(^HULP(%J,KLNr,"V"),D)
 Quit:'$L(R)
 Set Param1=$P(R,";")_" "_$P(^RES("KLANT","PI","VERZENDWIJZE","D",$P(R,";")),"`",2)
 Set Param2=VerzW_" "_$P(^RES("KLANT","PI","VERZENDWIJZE","D",$P(VerzW,";")),"`",2)
 Set Param3=$S($D(^HULP(%J,KLNr,"M","A")):"Wenst U de gemarkeerde orders te verwerken, of w",1:"W")
 Set Bewaar=$$^vhTXTPOP("EWORDS","VERZW"_'$D(^HULP(%J,KLNr,"M","A")),,Param1,Param2,Param3)
 Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
 ; Orgalux
ORGAL 
 New Param1,Param2
 Set IsOrgal=$$ISORGAL^FLOW("O",ORDNr)
 If IsOrgal,$G(^HULP(%J,KLNr,"C","AC")) Do  Quit
 .Set Bewaar=$$^vhTXTPOP("EWORDS","ORGALUXPERORD")
 .Set CumOrd=$S($L(Bewaar):1,1:"")
 If '$D(^HULP(%J,KLNr,"C","AC")) Set ^HULP(%J,KLNr,"C","AC")=IsOrgal
 Quit:^HULP(%J,KLNr,"C","AC")=IsOrgal
 Set R=^HULP(%J,KLNr,"C","AC")
 Set Param1=$P("Niet o\O",D,R+1)_"rgalux",Param2=$P("Niet o\O",D,IsOrgal+1)_"rgalux"
 Set Bewaar=$$^vhTXTPOP("EWORDS","ORGALUX",,Param1,Param2)
 Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
 ; Verpakkingstype
VERPTYP 
 New Param1,Param2
 Set VerpTyp=$$ORDER^VERPAK(ORDNr)
 If '$D(^HULP(%J,KLNr,"C","VP")) Set ^HULP(%J,KLNr,"C","VP")=VerpTyp
 Quit:^HULP(%J,KLNr,"C","VP")=VerpTyp
 Set R=^HULP(%J,KLNr,"C","VP")
 If $$CHKMIX^VERPAK(R,VerpTyp) Set ^HULP(%J,KLNr,"C","VP")=$$ADDTYPE^VERPAK(R,VerpTyp) Quit
 Set Param1=R,Param2=VerpTyp
 Set Bewaar=$$^vhTXTPOP("EWORDS","VERPTYP",,Param1,Param2)
 Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
DEURORD(KLNr,ORDNr) 
 New R,DeurOrd,OLNr,PRNr,LEVNr
 Set DeurOrd="",KLNr=$P($G(^KO1(ORDNr,"F")),D)
 Do:KLNr
 .Set OLNr=100
 .For  Set OLNr=$O(^KOD(KLNr,"F",ORDNr,OLNr)) Quit:'OLNr  Do
 ..Set R=^KOD(KLNr,"F",ORDNr,OLNr),PRNr=$P(R,D,2)
 ..Quit:'PRNr
 ..Set R=$O(^KPR(PRNr,"J"))
 ..Quit:$E(R)'="J"
 ..Set LEVNr=$P(^KPR(PRNr,R),D)
 ..If LEVNr=5810 Set:DeurOrd'["B" DeurOrd=DeurOrd_"B"
 ..Else  If LEVNr=6092 Set:DeurOrd'["F" DeurOrd=DeurOrd_"F"
 ..Else  If LEVNr=6428 Set:DeurOrd'["F" DeurOrd=DeurOrd_"F"
 ..Else  Set:DeurOrd'["?" DeurOrd=DeurOrd_"?"
 Set:$L(DeurOrd)'=1 DeurOrd="?"
 Quit DeurOrd
 ;
 ; Transportlink
TRANSPORTLINK
 New TransportLink,Param1,Param2
 Set R=^KOD(KLNr,"F",ORDNr,1),TransportLink=$P(R,D,12)
 If '$D(^HULP(%J,KLNr,"C","TP")) Set ^HULP(%J,KLNr,"C","TP")=TransportLink
 Quit:^HULP(%J,KLNr,"C","TP")=TransportLink
 Set R=^HULP(%J,KLNr,"C","TP")
 Set Param1=$$TRANSPORTEUR^TRANSP($P(R,";"),1),Param2=$$TRANSPORTEUR^TRANSP($P(TransportLink,";"),1)
 Set Bewaar=$$^vhTXTPOP("EWORDS","TRANSPORTLINK",,Param1,Param2)
 Set CumOrd=$S($L(Bewaar):1,1:"")
 Quit
 ;
CHECK(CONSNr,TextPop) 
 New R,KLNr,Check,Krediet,Rembours,VooruitBetaling,VerzW,ORDNr,OrdTyp,KredLim,Dubieus,IsMonster,IsProforma,SendWMS
 Set R=^ORDW("D",CONSNr),KLNr=$P(R,D),VerzW=$P(R,D,2)
 Set SendWMS=$P(^KKL(^KK1(KLNr),2),D,8)
 Set Check=$E(SendWMS,$L(SendWMS)) ; Geen vrijgave door boekhouding nodig
 If 'Check Do
 .Set R=^KKL(^KK1(KLNr),3),Rembours=$P(R,D),VooruitBetaling=$P(R,D,2),Dubieus=$P(R,D,8)
 .Set Krediet=$$WAARDIG^KREDIET(KLNr,,,,,.Hulp),KredLim=$P(Krediet,D,3)
 .Set ORDNr=$O(^ORDW("D",CONSNr,"D","")),R=^KOD(KLNr,"F",ORDNr,1)
 .Set IsMonster=$P(R,D,25)="M",IsProforma=$P(R,D,25)="P"
 .Set Check=IsMonster ; Monster
 .If 'Check,'VooruitBetaling Set Check=IsProforma ; Proforma indien niet op vooruitbetaling
 .Set:'Check Check=$$ISTERUGN(CONSNr) ; Terugname
 .If 'Check,'VooruitBetaling Set Check='$$STOCKUPD(CONSNr) ; Zonder stockupdate
 .Quit:Check
 .If Rembours,KredLim=1,'Dubieus,'$$OPENST^KREDIET(KLNr,"F") Set Check=1_D_Rembours_D_$P(Krediet,D)_D_VooruitBetaling_D_Dubieus Quit
 .If $E(VerzW,1,2)="AF" Do RPLBON^REMBOURS(KLNr,CONSNr,1) Set Rembours=""
 .Set Check=$P(Krediet,D) Set:Check Check='Rembours Set:Check Check='VooruitBetaling Set:Check Check='Dubieus
 .Set Check=Check_D_Rembours_D_$P(Krediet,D)_D_VooruitBetaling_D_Dubieus
 If 'Check!$G(Rembours),$G(TextPop) Do
 .New Tekst,Count
 .If KLNr=4682,IsMonster Set Check=1 Quit
 .Set Count=1,Tekst(Count)="Deze klant staat op ªBªK"
 .If Dubieus Set Tekst(Count)=Tekst(Count)_"DUBIEUS"
 .Else  If VooruitBetaling Set Tekst(Count)=Tekst(Count)_$S('Krediet:"KODE",1:"VOORUITBETALING")
 .Else  If Rembours Set Tekst(Count)=Tekst(Count)_$S(Check:"REMBOURS",'Krediet:"KODE",1:"REMBOURS")
 .Else  Set Tekst(Count)=Tekst(Count)_"KODE"
 .Set Tekst(Count)=Tekst(Count)_"ªbªk!"
 .If 'Krediet Do
 ..New Openst,VervSald,FaktDat
 ..Set Count=Count+1,Tekst(Count)=""
 ..Set Openst=$P(Krediet,D,2),VervSald=$P(Krediet,D,4),FaktDat=$P(Krediet,D,5)
 ..Set:$L(FaktDat) Count=Count+1,Tekst(Count)="Oudste vervallen faktuur van "_$$EXTDATE^vhDTyp(FaktDat)
 ..If KredLim,KredLim<Openst Do
 ...Set Count=Count+1,Tekst(Count)="Kredietlimiet    :"_KredLim
 ...Set Count=Count+1,Tekst(Count)="Openstaand saldo :"_Openst
 .Set Count=Count+1,Tekst(Count)=""
 .Set Count=Count+1,Tekst(Count)="De "_$S(Rembours:$S(Dubieus:"boekhouding",VooruitBetaling:"boekhouding",Check:"verkoop",'Krediet:"boekhouding",1:"verkoop"),1:"boekhouding")
 .Set Tekst(Count)=Tekst(Count)_" moet leveringsbon "_CONSNr_" vrijgeven voor uitlevering."
 .Set R=$$WILD^vhTXTPOP("C;C","","Tekst")
 Quit Check
 ;
BELET(CONSNr,Aktie) 
 New R,KLNr,Check,Rembours,Krediet,VooruitBetaling,Dubieus
 Set Aktie=$G(Aktie)
 Set R=^ORDW("D",CONSNr),KLNr=$P(R,D),$P(R,D,20)="K",^ORDW("D",CONSNr)=R
 Set Check=$$CHECK(CONSNr),Rembours=$P(Check,D,2),Krediet=$P(Check,D,3),VooruitBetaling=$P(Check,D,4),Dubieus=$P(Check,D,5)
 If 'Check,Dubieus Do MAILDUB(CONSNr,Aktie) Quit
 If 'Check,'Krediet Do MAILKODE(CONSNr,Aktie) Quit
 If 'Check,VooruitBetaling Do MAILVBET(CONSNr,Aktie) Quit
 If Rembours Do
 . Quit:$$BehandelRemb(CONSNr)  ; Rembours afgehandeld op orderniveau
 . If $G(Optie)'["A",$$REMBOVZ^REMBOURS(KLNr)'="A" Quit ; Remboursoverzicht (afgehandeld ingedrukt)
 . Do MAILREMB(CONSNr,Aktie)
 Quit
 ;
 ; Type="K" MAILKODE
 ; Type="R" MAILREMB
 ; Type="V" MAILVBET
CHKMAIL(Type) 
 Goto CHKMAIL^EWORDS3b
 ;
MAILKODE(CONSNr,Aktie) 
 Goto MAILKODE^EWORDS3b
 ;
MAILVBET(CONSNr,Aktie) 
 Goto MAILVBET^EWORDS3b
 ;
MAILREMB(CONSNr,Aktie) 
 Goto MAILREMB^EWORDS3b
 ;
MAILDUB(CONSNr,Aktie) 
 Goto MAILDUB^EWORDS3b
 ;
VRIJGAVE(CONSNr,MailId,Aktie,Param) 
 New R,Tekst,KLNr,KLNaam,VerzW,VerzDat,DOutDate,WMSStat,TUserId,Type
 Set R=^ORDW("D",CONSNr),WMSStat=$P(R,D,20),KLNr=$P(R,D),Type=$P(Param,";"),TUserId=$P(Param,";",2)
 If WMSStat="K" Do
 .If Type="K",'$$ASK^vhWACHTW("BOEKHOUD.","","",0) Quit
 .Quit:'$$^vhTXTPOP("EWORDS3","VRIJGAVE","",CONSNr,$P(^KKL(^KK1(KLNr),0),D,2))
 .Do CHKLEVT^EWORDST4(CONSNr)
 .Set R=^ORDW("D",CONSNr),$P(R,D,20)="",^ORDW("D",CONSNr)=R,DOutDate=$P($P(R,D,3),",")
 .Set VerzW=$P(R,D,2),VerzDat=$P(R,D,5)
 .If Aktie="",DOutDate'>$H Do SEND^EWORDSW(CONSNr) ; Doorsturen naar WMS
 .If Aktie="B" Do UITLEV^EWORDS2(CONSNr,1) ; Bon opmaken
 .Set Count=0,R=^KKL(^KK1(KLNr),0),KLNaam=$P(R,D,2)
 .Set Count=Count+1,Tekst(Count)="Mail van : "_$$USERNAME^vhUSER(CUserId)
 .Set Count=Count+1,Tekst(Count)="~Klant    : "_KLNr_" "_KLNaam
 .Set Count=Count+1,Tekst(Count)="~Lev. bon : "_CONSNr_$J($$EXTDATE^vhDTyp(VerzDat),9)
 .Set Tekst(Count)=Tekst(Count)_" "_^RES("KLANT","PI","VERZENDWIJZE","D",$P(VerzW,";"),"N")
 .Set Count=Count+1,Tekst(Count)="~~Deze leveringsbon is vrijgegeven en "
 .Set Tekst(Count)=Tekst(Count)_$S(Aktie="B":"opgemaakt.",1:"verzonden naar het WMS.")
 .Set Ref(1)="KL\"_KLNr_"\R\O"
 .Set:'TUserId R=^vhMAIL("D",MailId),TUserId=$P(R,D,6)
 .Quit:'TUserId
 .Set:TUserId'=CUserId R=$$SYSTEM^vhMAIL("KL",KLNr,"Bon "_CONSNr_" -> vrijgegeven",TUserId,.Tekst,.Ref,1)
 .Kill Link,^vhMAIL("D",MailId,"R",2),^vhMAIL("D",MailId,"R",3)
 .Kill ^vhMAIL("D",MailId,"R",4),^vhMAIL("D",MailId,"S")
 .Do DELUSERS(MailId)
 Quit
 ;
DELETE(CONSNr,MailId,Param) 
 New R,Tekst,KLNr,KLNaam,VerzW,VerzDat,DOutDate,WMSStat,TUserId,Type,ORDNr,ORDNrs
 Set R=^ORDW("D",CONSNr),WMSStat=$P(R,D,20),KLNr=$P(R,D),Type=$P(Param,";"),TUserId=$P(Param,";",2)
 If WMSStat="K" Do
 .Quit:'$$^vhTXTPOP("EWORDS3","DELETE","",CONSNr,$P(^KKL(^KK1(KLNr),0),D,2))
 .Set $P(R,D,20)="",^ORDW("D",CONSNr)=R,DOutDate=$P($P(R,D,3),",")
 .Set VerzW=$P(R,D,2),VerzDat=$P(R,D,5)
 .Set (ORDNr,ORDNrs)=""
 .For  Set ORDNr=$O(^ORDW("D",CONSNr,"D",ORDNr)) Quit:ORDNr=""  Set ORDNrs=ORDNrs_";"_ORDNr
 .Set $E(ORDNrs)=""
 .Do STORE^LOG("ORDW",CONSNr,"V",ORDNrs) ; Logging (verwijderd)
 .Do REMWMS^EWORDST(CONSNr) ; Verwijderen
 .Set Count=0,R=^KKL(^KK1(KLNr),0),KLNaam=$P(R,D,2)
 .Set Count=Count+1,Tekst(Count)="Mail van : "_$$USERNAME^vhUSER(CUserId)
 .Set Count=Count+1,Tekst(Count)="~Klant    : "_KLNr_" "_KLNaam
 .Set Count=Count+1,Tekst(Count)="~Lev. bon : "_CONSNr_$J($$EXTDATE^vhDTyp(VerzDat),9)
 .Set Tekst(Count)=Tekst(Count)_" "_^RES("KLANT","PI","VERZENDWIJZE","D",$P(VerzW,";"),"N")
 .Set Count=Count+1,Tekst(Count)="~~Deze leveringsbon is verwijderd."
 .Set Ref(1)="KL\"_KLNr_"\R\O"
 .Set:'TUserId R=$G(^vhMAIL("D",MailId)),TUserId=$P(R,D,6)
 .Quit:'TUserId
 .Set:TUserId'=CUserId R=$$SYSTEM^vhMAIL("KL",KLNr,"Leveringsbon "_CONSNr,TUserId,.Tekst,.Ref,1)
 .Kill Link
 .Quit:'$D(^vhMAIL("D",MailId))
 .Kill ^vhMAIL("D",MailId,"R",2),^vhMAIL("D",MailId,"R",3)
 .Kill ^vhMAIL("D",MailId,"R",4),^vhMAIL("D",MailId,"S")
 .Do DELUSERS(MailId)
 Quit
 ;
LATER(MailId) 
 Do DELUSERS(MailId)
 Kill ^vhMAIL("D",MailId,"S")
 Quit
 ;
DELUSERS(MailId) 
 New R,System,TUserId
 Set TUserId=";"_$$TUSERID^vhMAIL(MailId)_";"
 Set TUserId=$P(TUserId,";"_CUserId_";")_";"_$P(TUserId,";"_CUserId_";",2)
 Set $E(TUserId)="",$E(TUserId,$L(TUserId))=""
 Do DELUSERS^vhMAIL(MailId,TUserId)
 Set R=^vhMAIL("D",MailId),System=$P($P(R,D,10),",",2)
 Kill:$L(System) ^vhMESSAGE(System,"MAIL",MailId)
 Quit
 ;
TEBET(CONSNr) 
 Quit $$TEBET^EWORDS3b(CONSNr)
 ;
ISTERUGN(CONSNr) 
 New R,IsTerugn,ORDNr,OLUNr
 Set IsTerugn=1,ORDNr=""
 For  Set ORDNr=$O(^ORDW("D",CONSNr,"D",ORDNr)) Quit:ORDNr=""  Do  Quit:'IsTerugn
 .Set OLUNr=""
 .For  Set OLUNr=$O(^ORDW("D",CONSNr,"D",ORDNr,OLUNr)) Quit:OLUNr=""  Do  Quit:'IsTerugn
 ..Set R=^ORDW("D",CONSNr,"D",ORDNr,OLUNr),IsTerugn=$P(R,D,4)<0
 Quit IsTerugn
 ;
STOCKUPD(CONSNr) 
 New R,StockUpd,KLNr,ORDNr,OLUNr,OLNr
 Set R=^ORDW("D",CONSNr),KLNr=$P(R,D),StockUpd=0,ORDNr=""
 For  Set ORDNr=$O(^ORDW("D",CONSNr,"D",ORDNr)) Quit:ORDNr=""  Do  Quit:'StockUpd
 .Set OLUNr=""
 .For  Set OLUNr=$O(^ORDW("D",CONSNr,"D",ORDNr,OLUNr)) Quit:OLUNr=""  Do  Quit:StockUpd
 ..Set R=^ORDW("D",CONSNr,"D",ORDNr,OLUNr),OLNr=^ORD("IU",ORDNr,OLUNr)
 ..Set R=^KOD(KLNr,"F",ORDNr,OLNr)
 ..Set StockUpd=$P(R,D,14)'["S" Set:StockUpd StockUpd=$P(R,D,14)'["Z"
 Quit StockUpd
 ;
CONSSTAT(WMSStat,KLNr,Date) 
 New CONSNr,CONSNrs
 Set Date=$G(Date) Set:Date="" Date=+$H
 Set CONSNr="",CONSNrs=";"
 For  Set CONSNr=$O(^ORDW("IK",KLNr,CONSNr)) Quit:CONSNr=""  Do
 .Set R=^ORDW("D",CONSNr)
 .If $L(WMSStat) Quit:$P(R,D,20)'=WMSStat
 .Quit:+Date'=+$P(R,D,22)
 .Set CONSNrs=CONSNrs_CONSNr_";"
 Set $E(CONSNrs)="",$E(CONSNrs,$L(CONSNrs))=""
 Quit CONSNrs
 ;
CHKMENU(Menu,Aktie) 
 New I,R,Ok,ORDNr,OLNr,OLUNr,PRNr,StockUpd,TempOrd
 Set Ok=0
 If Menu="F" Do
 .If Aktie="S" Do  ; Nieuwe selektie (nog te implementeren)
 ..Set Ok=1
 .Else  If Aktie="M" Do  ; Selekteer macro (nog te implementeren)
 ..Set Ok=1
 .Else  If "\WA\WD\"[(D_Aktie_D) Do  ; Aktiveer/Deaktiveer WMS-link
 ..Quit:$P("D\A",D,$G(^EWREC("P","NOSEND"))+1)'=$E(Aktie,2)
 ..Set Ok=1
 .Else  If Aktie="OL" Do
 ..Quit:'$G(^HULP(%J,"S","O","WEEK"))
 ..If $G(DOutSend)'="V",$G(DOutSend)'="L" Quit
 ..Set TempOrd=""
 ..For I=1:1 Quit:'$D(^HULP(%J,KLNr,"O",I))  Do  Quit:Ok
 ...Set R=^HULP(%J,KLNr,"O",I),ORDNr=$P(R,D)
 ...Set:ORDNr'=TempOrd Ok=$$CHKSERIE^EWORDS5(ORDNr,"OL") Set TempOrd=ORDNr
 Else  If Menu="E" Do
 .Quit:$G(Aktie)=""
 .If "\MO\DO\ML\DL\A\"[(D_Aktie_D) Do
 ..Set R=$G(^HULP(%J,KLNr,"O",LD("SELECT")))
 ..Quit:R=""
 ..Set ORDNr=$P(R,D),OLNr=$P(R,D,11),PRNr=$P(R,D,12),OLUNr=$P(R,D,19)
 ..If 'OLNr Do  Quit
 ...If Aktie="MO",'$D(^HULP(%J,KLNr,"M","A",ORDNr)) Set Ok=1
 ...If Aktie="DO",$D(^HULP(%J,KLNr,"M","A",ORDNr)) Set Ok=1
 ..If "\ML\A\"[(D_Aktie_D) Do
 ...If Aktie="ML",$D(^HULP(%J,KLNr,"M","A",ORDNr,OLUNr)) Quit
 ...Quit:'$$MIXMAN^EWORDS5(KLNr,PRNr)
 ...New Aantal,FysStock,TOENr
 ...Set Aantal=$P(R,D,13),FysStock=$P(R,D,14),TOENr=$P(R,D,17)
 ...Set StockUpd=$P(R,D,22)'["S" Set:StockUpd StockUpd=$P(R,D,22)'["Z"
 ...If Aktie="A" Quit:Aantal'>0  Quit:'StockUpd
 ...Quit:TOENr
 ...If StockUpd,Aantal>0,FysStock'>0 Quit
 ...Set:Aantal'>FysStock Ok=1 Set:Aktie="A" Ok=1
 ...Set Ok=1
 ..If Aktie="DL",$D(^HULP(%J,KLNr,"M","A",ORDNr,OLUNr)) Set Ok=1
 Quit Ok
 ;
 ; Rembours afgehandeld op orderniveau
BehandelRemb(CONSNr)
 New I,R,KLNr,ORDNr,ORDNrs,RembOrder,RembCons,Afgehandeld,KlNaam,Munt
 Set R=^ORDW("D",CONSNr),KLNr=$P(R,D),(RembOrder,RembCons)=0,(ORDNr,ORDNrs)=""
 For  Set ORDNr=$O(^ORDW("D",CONSNr,"D",ORDNr)) Quit:ORDNr=""  Do
 . Set R=^KOD(KLNr,"F",ORDNr,1),Afgehandeld=$P(R,D,37)
 . Quit:'Afgehandeld
 . Set ORDNrs=ORDNrs_","_ORDNr,RembOrder=RembOrder+$P(Afgehandeld,"#",3)
 . Set $P(R,D,37)="",^KOD(KLNr,"F",ORDNr,1)=R
 Do:RembOrder
 . Set R=$$CALCWMS^FLOWBON5(CONSNr),RembCons=$P(R,D),Munt=$P(R,D,7)
 . Set Afgehandeld=RembOrder=RembCons
 . Do:'Afgehandeld
 . . Set KlNaam=$P(^KKL(^KK1(KLNr),0),D,2)
 . . Set $E(ORDNrs)=""
 . . For I=1:1:$L(ORDNrs,",") Set $P(ORDNrs,",",I)=$$EXTNUM^vhDTyp($P(ORDNrs,",",I),0,".T",0)
 . . Set:$L(ORDNrs,",")>3 $P(ORDNrs,",",3,99)=$P(ORDNrs,",",3)_"..."
 . . Set Afgehandeld=$$^vhTXTPOP("EWORDS","CHKREMB","",KLNr,KlNaam,ORDNrs,$$EXTNUM^vhDTyp(RembOrder,0,".",$$MUNT^vhRtn1(Munt,4)),$$EXTNUM^vhDTyp(RembCons,0,".",$$MUNT^vhRtn1(Munt,4)),Munt)
 . Do:Afgehandeld
 . . Set R=^ORDW("D",CONSNr)
 . . Set $P(R,D,8)=$G(CUserId,$G(QU(1),$P($$DEVUSER^vhUSER(),";")))_"#"_$H_"#"_RembCons
 . . Set ^ORDW("D",CONSNr)=R
 Quit Afgehandeld
 ;
 ; Markering i.v.m. leveringsperformantie
MarkeerKredietProbleemInCONSNr(CONSNr,Code)
 New ORDNr
 Set ORDNr=""
 For  Set ORDNr=$O(^ORDW("D",CONSNr,"D",ORDNr)) Quit:ORDNr=""  Do MarkeerKredietProbleemInORDNr(ORDNr,Code)
 Quit
 ;
MarkeerKredietProbleemInORDNr(ORDNr,Code)
 New KLNr,OLNr
 Set KLNr=$P($G(^KO1(ORDNr,"F")),D)
 If KLNr {
	 Set OLNr=100
	 For  Set OLNr=$O(^KOD(KLNr,"F",ORDNr,OLNr)) Quit:OLNr=""  Set:$P(^KOD(KLNr,"F",ORDNr,OLNr),D,49)="" $P(^KOD(KLNr,"F",ORDNr,OLNr),D,49)=Code
 }
 Quit
 ;