FADELAY ;Uitgestelde fakturatie ; [ 01/07/2002  1:58 PM ]
 ;
 Do INIT,REFRESH
 Do:$$MagFactureren^KF27()
 . Do KRITERIA
 . Do:$P(Kriteria,D) COMMAND
 . Kill ^HULP(%J)
 Lock
 Quit
 ;
COMMAND Set Input=""
 For  Quit:Input="-"  Quit:Input="CANC"  Do
 .Do REFRESH
 .Set Input=$$SCROLL^vhLIST(.LD)
 .Set BONNr=$P($G(^HULP(%J,LD("SELECT"))),D,1)
 .If Input="COM" Set Input="" Do CALL^vhMenu("FADELAY")
 .Set:Input="-" Input="CANC"
 .Do EXEC^vhMenu("FADELAY",.Input)
 Quit
 ;
FETCH 
 New R,KlantId,KLNr,BONNr,Count,SortKey,Datum
 Kill ^HULP(%J)
 Set KlantId=0
 For  Set KlantId=$O(^KKL(KlantId)) Quit:KlantId=""  Do
 .Set R=^KKL(KlantId,0),KLNr=$P(R,D),BONNr=""
 .For  Set BONNr=$O(^KUL(KLNr,"F",BONNr)) Quit:BONNr=""  Do
 ..Set R=$$FETCHL(KLNr,BONNr)
 ..Quit:'$L(R)
 ..Set Datum=$P(R,D,12),Datum=$$INTDATE^vhDTyp(Datum)
 ..Set SortKey=$S($P(Kriteria,D,2)="K":KlantId_Datum,1:Datum_KlantId)_BONNr
 ..Set ^HULP(%J,"S",SortKey)=R
 Set SortKey="",Count=0
 For  Set SortKey=$O(^HULP(%J,"S",SortKey)) Quit:SortKey=""  Do
 .Set R=^HULP(%J,"S",SortKey)
 .Set Count=Count+1,^HULP(%J,Count)=R
 Kill ^HULP(%J,"S")
 Set LD("MAX")=Count
 If 'Count Do
 .Do ADD^vhScherm(1,24),REFRESH
 .Set R=$$^vhTXTPOP("FLOWBON","FADELAY","",$$EXTDATE^vhDTyp($P(Kriteria,D)))
 Quit
 ;
FETCHL(KLNr,BONNr) 
 New R,KlantId,KlantNm,Gemeente,Land,BRec,Type,Bedrag,Regio
 Set BRec=^KUL(KLNr,"F",BONNr,1)
 If $$COMPDATE^vhDTyp($$INTDATE^vhDTyp($P(BRec,D,2)),"A","'>",$P(Kriteria,D)) Do
 .Set Bedrag=$$BEDRAG^FLOWBON(BONNr)
 .Set KlantId=^KK1(KLNr),R=$G(^KUL(KLNr,"F",BONNr,3))
 .If '$P(R,D) Set R=^KKL(KlantId,0) ;indien geen lev adres
 .Set KlantNm=$P(R,D,2),Gemeente=$P(R,D,7)
 .Set Regio=$P(^KKL(KlantId,0),D,20)
 .Set Land=$$LAND^vhRtn1($P(R,D,8))
 .Set R=BONNr_D_KLNr_D_KlantNm_D_$S(Land'="BE":Land_"-",1:"")_Gemeente_D_Bedrag
 .Set $P(R,D,11)=BRec
 .Set $P(R,D,10)=Regio
 Quit $G(R)
 ;
INIT 
 Set %J=$$%J^vhRtn1()
 Kill ^HULP(%J)
 Set Kriteria="\K"
 Do INIT^vhLIST("FLOWBON","FADELAY",.LD),ADD^vhScherm(1,24)
 Quit
 
RPLKL Quit:'LD("MAX")
 Set KLNr=$P($G(^HULP(%J,LD("SELECT"))),D,2)
 Quit:'KLNr
 Set Aktie=$$RAADPL^KLANT(KLNr,$P($G(Aktie,"L"),D))
 Do ADD^vhScherm(1,24)
 Quit
 ;
KRITERIA 
 New %SC,OldKrit
 Set OldKrit=Kriteria
 Set:$P(Kriteria,D)="" $P(Kriteria,D)=$$CALCDATE^vhDTyp(,"M","-1"),%SC=1
 Do EDIT^vhScherm("FADELAY")
 If Kriteria'=OldKrit Do
 .Do INIT^vhLIST("FLOWBON","FADELAY",.LD),ADD^vhScherm(1,24)
 .Kill ^HULP(%J),LD("MAX")
 .Do REFRESH
 .Do FETCH
 .Do ADD^vhScherm(1,24)
 Quit
 ;
REFETCH 
 Do FETCH,ADD^vhScherm(4,24)
 Quit
 ;
REFRESH 
 If sRT<4 Do DISPLAY^vhScherm("FADELAY","","","H")
 If sRB>3 Do WRITE^vhLIST(.LD)
 Do WRITE^vhLIST(.LD)
 Do RESET^vhScherm
 Quit
 ;
PRINT 
 New PLD
 Do INIT^vhLISTO("FLOWBON","FADELAY",.PLD)
 Set PLD(1)=$NA(^HULP(%J))
 Set PLD(5)=80
 Set PLD(10)=""
 Set PLD(11)="Uitgestelde fakturatie\Ref. datum "_$$EXTDATE^vhDTyp(sFL(1))
 Do PRINT^OUTPUT(.PLD,"PT")
 Quit
 
TRANSFER 
 New PLD
 Do INIT^vhLISTO("FLOWBON","FADELAYTRANS",.PLD)
 Set PLD(1)=$NA(^HULP(%J))
 Set PLD(5)=80
 Set PLD(10)=""
 Set PLD(11)="Uitgestelde fakturatie\Ref. datum "_$$EXTDATE^vhDTyp(sFL(1))
 Do PRINT^OUTPUT(.PLD,"T")
 Quit
 ;
INITMOD(NoMod,DontAsk) 
 Set (BONNr,KLNr)=""
 Set:$D(^HULP(%J,LD("SELECT"))) R=^HULP(%J,LD("SELECT")),X=$P(R,D)
 Quit:'X 0 Quit:'$D(^KU1(X)) 0
 Set BONNr=X,KLNr=+^KU1(X,"F")
 Quit:$G(NoMod) 1
 If $D(^KUL(KLNr,"G",BONNr)) Do TXT^vhINP("Deze bon is reeds gefaktureerd") Quit 0
 If '$D(^KUL(KLNr,"F",BONNr)) Do TXT^vhINP("Deze bon is gestorneerd"),REFETCH Quit 0
 Do ADD^vhLock("^KUL(KLNr,""F"",BONNr)")
 I '%TC Do  Quit 0
 .Do LDISP^vhLock("^KUL(KLNr,""F"",BONNr)","Order "_BONNr)
 .Set DL(2)=24 Do WL^PROC Kill DL(2)
 Quit 1
 ;
FAKTUUR 
 New R,KLNr,BONNr,ULNr
 Quit:'$$INITMOD(1)
 I $D(^KUL(KLNr,"G",BONNr)) Set FANr=$P(^KU1(BONNr,"F"),D,2),R=$$SHOW^RPLFAKT(FANr,7) Do ADD^vhScherm(7,24) Quit
 Quit:'$$INITMOD(0,1)
 Do S1^KF27,FDAT^KF27:'$D(FDT)!'$G(OK)
 If '$D(FDT)!'$G(OK) Do ADD^vhScherm(1,24) Quit
 Set ULNr=BONNr
 Do Locals("ULNr,FDT,BH,BJ,BM,BP,BX,OK")
 Do DO^vhPROGRAM("FE^KF27"),REFETCH
 Do ADD^vhScherm(1,24)
 Quit
 ;
MODBON 
 New %SC,R,KLNr,BONNr,ULNr,Old,New
 Quit:'$$ASK^vhWACHTW("MANAGER",,"",0)  Quit:'$$INITMOD()
 Set ULNr=BONNr
 Do Locals("ULNr")
 Set Old=^KUL(KLNr,"F",BONNr,1)
 Do DO^vhPROGRAM("FUE^KF9") If '$D(^KUL(KLNr,"F",BONNr)) Do REFETCH Quit
 Set New=^KUL(KLNr,"F",BONNr,1)
 Set %SC=1 If $P(Old,D,2)=$P(New,D,2),$P(Old,D,7)=$P(New,D,7) Set %SC=0
 If %SC Set ^HULP(%J,LD("SELECT"))=$$FETCHL(KLNr,BONNr)
 Do ADD^vhScherm(1,24)
 Quit
 ;
Locals(List) 
 New I
 For I=1:1:$L(List,",") Set $P(List,",",I)=""""_$P(List,",",I)_""""
 Xecute "For Locals="_List_" Set Locals(Locals)=@Locals"
 Quit
 ;