FOLTCAT ;Folietec opbouw cataloog[ 11/22/2003   1:21 PM ]
 Quit
 
EXPTAB(Munt,Taal,KLNr) 
 S %J=$$%J^vhRtn1()
 Kill ^HULP(%J)
 Set MetPrijs=1
 Do FETCH^FOLTECT
 Set Dev=0
 Set Dev=$$OPEN^vhDEV(,"FOLIETEC"_KLNr_".TXT","W")
 Use Dev
 Set Cnt=0
 For  Set Cnt=$O(^HULP(%J,Cnt)) Quit:Cnt=""  Do
 .Set FRec=^HULP(%J,Cnt)
 .If FRec["&S" Write ! Quit
 .Write $P(FRec,D,1),$C(9),$P(FRec,D,2),$C(9),$P(FRec,D,3),$C(9),$$FRONT^FOLTECT($P(FRec,D,4),1),$C(9),$$TYPE^FOLTECT($P(FRec,D,5),,1)
 .For Reeks=610,620,630,640,650,660 Do
 ..Set Prijs=$$PRIJS^FOLTECT(KLNr,Reeks,"F00",FRec)
 ..Write $C(9),$TR(Prijs,".",",")
 .Write !
 Close:0'[Dev Dev
 Quit
 
EXPORT(Munt,Taal,Reeks,KLNr) 
 If '$G(KLNr) Set KLNr=$S(Munt=$$MUNTKODE^vhRtn1("NLG"):3182,1:1247) ; Default KLANT PARTIKULIER
 Set TaalI=$S(Taal="F":11,1:8)
 Do VANNAAR^vhTERMINA("M")
 Set Dev=0
 Set Dev=$$OPEN^vhDEV(,"FOLT"_Reeks_Munt_Taal_".txt","W")
 Use Dev
 Set VolgNr=0
 For  Set VolgNr=$O(^FOLTEC("CAT",VolgNr)) Quit:VolgNr=""  Do
 .;W:Dev=0 ^(VolgNr),!
 .Do EXPONE(^(VolgNr))
 Close:0'[Dev Dev
 Quit
 
EXPONE(RecFolt) ;Recorddef : 1BasisType;2Type;3CodeCalc;4Hoogte;5Breedte;6Aank NLG;7Lijstprijs BEF niet afgerond;8Code Displ;9OmschrijvingN;10AfmN;11EenheidN;12OmschrijvingF;13AfmF;14EenheidF
 Set BType=$TR($P(RecFolt,D,1),FVAN,FNAAR)
 If BType="" Write ! Quit  ; Lege lijn
 Set Type=$P(RecFolt,D,2)
 Set Code=$P(RecFolt,D,3)
 If $L(Code)=1 Set Code="0"_Code
 Set CodeT=$P(RecFolt,D,8)
 If $L(CodeT)=1 Set CodeT="0"_CodeT
 Set Hoogte=$P(RecFolt,D,4)
 Set Breedte=$P(RecFolt,D,5)
 Set Lijst=$P(RecFolt,D,7)
 Set:BType'="X" Lijst=$$PRIJS^FOLTEC(,Reeks,"FOO",BType,Hoogte,Breedte,Type,Code,KLNr)
 Write $P(RecFolt,D,TaalI+1),$C(9),CodeT,$C(9),$P(RecFolt,D,TaalI+2),$C(9)
 Write $$CEL^vhFMT(0,"Lijst","N+","L","",$$MUNT^vhRtn1(Munt,4),"","","","")
 Write $S($L($P(RecFolt,D,TaalI+3)):$C(9)_$P(RecFolt,D,TaalI+3),1:""),!
 Quit
 
IMPORT Set Cnt=0
 Kill ^FOLTEC("CAT")
 Set FileNm=$$READ^vhDEV(,"*.TXT","D`CBREAD^FOLTCAT","DT","P")
 Kill ^["LVH,DEV"]FOLTEC("CAT")
 Merge ^["LVH,DEV"]FOLTEC("CAT")=^FOLTEC("CAT")
 Quit
 
CBREAD(Rec) 
 Set Cnt=Cnt+1
 If Cnt=1 Set ^FOLTEC("CAT")=Rec   ; De titel
 Else  Set ^FOLTEC("CAT",Cnt)=Rec
 Quit