#include Prod.Product 
#define LevHalux 6332
#Define Keller 1239
 
Receptie
	Write @F11,@F1,@FMTI,"Tandembox - Receptie : ",QN,@FMTi
	Set VanDatum=$H-90,TotDatum=$H
	Set PRNr=0
	Kill Sum
	For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  Do
	. Quit:'$D(^KPR(PRNr,"J"_$$$LevHalux))
	. Set GenTyp=$$GENTYP^HAD(PRNr)
	. Quit:$P(GenTyp,"\")'="TBX"
	. Quit:$P($$GENTYP^HAD(PRNr),"\",2)="PR+" ; geen pro +
	. Set VolgNr=""
	. For  Set VolgNr=$O(^PRHIST(PRNr,VolgNr),-1) Quit:VolgNr=""  Do  Quit:Dat<VanDatum
	. . Set Rec=^PRHIST(PRNr,VolgNr)
	. . Set Dat=+$P(Rec,D,1)
	. . Quit:$P(Rec,D,4)'="I"
	. . Quit:Dat<VanDatum
	. . Quit:Dat>TotDatum
	. . Set Qty=$P(Rec,D,2)
	. . Set Verpak=$LG(##class(Prod.Kenmerk.DataDefinitie).Get("TBX",PRNr,"VERPAK")) ; Verpakking
	. . Set:Verpak="" Verpak="X"
	. . Set:Verpak="I" Verpak="X"
	. . Set Sum(Dat,Verpak)=$G(Sum(Dat,Verpak))+Qty
	. . Set Sum(Dat)=$G(Sum(Dat))+Qty
	Set Dat=""
	Kill List
	For  Set Dat=$O(Sum(Dat),-1) Quit:Dat=""  Do
	. Set Rec=Dat_"\"_Sum(Dat)
	. Set Verpak=""
	. For  Set Verpak=$O(Sum(Dat,Verpak)) Quit:Verpak=""  Do
	. . Set VerpakPos=$Case(Verpak,"S":1,"Z":2,"O":3,"C":4,"P":5,"A":6,:7)+2
	. . Set $P(Rec,D,VerpakPos)=$P(Rec,D,VerpakPos)+Sum(Dat,Verpak)
	. Set List($I(List))=Rec
	
	Do INIT^vhLIST("HATBXLEAN","RCP",.LD)
	Do WRITE^vhLIST(.LD)
	For  Do  Quit:(Input="-")||(Input=".")
	. Set Input=$$SCROLL^vhLIST(.LD)
	Quit