KF0268 G 1 ;TONEN GEGEVENS PRODUKT BIJ ORDERS EN UITLEVERINGEN [ 08/06/2003  3:14 PM ]
 ;
1 I UGL="OD" D %SCHERM(KC,PR,R) G YZ
 S:$P(R,D,20)="" $P(R,D,20)=$P(R,D,10)
 S FP=2011 W @F,@F5 S FP=2002 W @F W:'$P(R,D,1) @F4,"NIET-ST",@F5 W:$P(R,D,1) " PRA-ST  " S FP=2011 W @F,": ",$P(R,D,2)
3 S FP=2028 W @F,"KLEIN VP : ",$P(R,D,6) S FP=2054 W @F,"LIJSTPR : ",$P(R,D,11)," ",$P(R,D,9),"/",$P(R,D,10)
5 W ! W:$P(R,D,18)'=$P(R,D,2) ?2,"FYS-ST  : ",$P(R,D,18) W ?27,"NORM VP  : ",$P(R,D,7),?53,$P("KORTING\CODEX  ",D,$P(R,D,16)+1)," : "
7 I $P(R,D,12) W $J($P(R,D,12),4,1)," %  " I $P(R,D,13) W $J($P(R,D,13),4,1)," %"
9 W !?2,"TOEL-ST : ",$P(R,D,3),?27,"GROOT VP : ",$P(R,D,8)
11 W ?53,$P("VERK \KAT",D,$P(R,D,14)+1)
13 W "PR",?61,": ",$P(R,D,15)," ",$P(R,D,9),"/",$P(R,D,20)
15 W !?2,"LEVEREN : ",$$EXTDATE^vhDTyp($P(R,D,5))
17 W ?27,"ONDERGR  : ",!?2,"M BST H : ",$P(R,D,4)," (",$P(R,D,17)," W)",?27,"BOVENGR  : "
 ;
YZ K R Q
 ;
%SCHERM(KLNr,PRNr,R) 
 New IDNr,KortTxt,sFL,KLRef,UitVerkoop
 Set sFL(1)=R,R=^KPR(PRNr,0),KortTxt=$P(R,D),UitVerkoop=$P(R,D,6),R=^KPR(PRNr,2),IDNr=$P(R,D,25)
 Set:UitVerkoop>$H UitVerkoop=""
 Set KLRef=$$DISP^PAKKET(KLNr,PRNr," & ",40)
 Set:$P(sFL(1),D,20)="" $P(sFL(1),D,20)=$P(sFL(1),D,10)
 Do DISPLAY^vhScherm("FLOWKF0268")
 Quit
 ;
INIT 
 New RemAttr,PutAttr
 Set (RemAttr,PutAttr)=""
 If 'IsProj,$L(KLRef) Set RemAttr=RemAttr_";KLREF"
 Set:IsProj ProjRef=$G(ProjRef),RemAttr=RemAttr_";PROJECT"
 Set:'$P(sFL(1),D) RemAttr=RemAttr_";NIETST"
 Set:$P(sFL(1),D) RemAttr=RemAttr_";PRAST"
 Set:$P(sFL(1),D,18)'=$P(sFL(1),D,2) RemAttr=RemAttr_";FYSST"
 Set:$G(UitVerkoop) RemAttr=RemAttr_";UITVERKOOP"
 Set RemAttr=RemAttr_";"_$P("VERKPR\KATPR",D,$P(sFL(1),D,14)+1)
 Set RemAttr=RemAttr_";"_$P("KORTING\CODEX",D,$P(sFL(1),D,16)+1)
 Set $E(RemAttr)="",$E(PutAttr)=""
 For I=1:1 Quit:'$L($P(RemAttr,";",I))  Do REMATTR^vhScherm($P(RemAttr,";",I),"HD","HD")
 For I=1:1 Quit:'$L($P(PutAttr,";",I))  Do PUTATTR^vhScherm($P(PutAttr,";",I),"HD","HD")
 Quit
 ;
T 
 Write @F11,@F1
 Set PRNr=$$SELECT^PRODUKT6()
 Do:PRNr
 .Set KLNr=1239,R="",%WK=$$EXTDATE^vhDTyp(,"W")
 .Set IsProj=1,ProjRef="Projectreferentie"
 .Set $P(R,D)=1 ; Stock of Niet-stock
 .Set $P(R,D,2)=5806 ; Pra stock
 .Set $P(R,D,3)=1000 ; Toel stock
 .Set $P(R,D,4)=500 ; Min bestelhoev
 .Set $P(R,D,5)="03/27" ; Levertermijn
 .Set $P(R,D,6)="" ; Kleinverpakking
 .Set $P(R,D,7)=50 ; Normverpakking
 .Set $P(R,D,8)=250 ; Grootverpakking
 .Set $P(R,D,9)="EUR" ; Munt
 .Set $P(R,D,10)="E" ; Eenheid
 .Set $P(R,D,11)="0.75" ; Lijstprijs
 .Set $P(R,D,12)=20 ; Korting1
 .Set $P(R,D,13)=19 ; Korting2
 .Set $P(R,D,14)=0 ; Verk- of Katprijs
 .Set $P(R,D,15)="0.75" ; Verk/Katprijs
 .Set $P(R,D,16)=1 ; Codex
 .Set $P(R,D,17)=2 ; Leverweken lev.
 .Set $P(R,D,18)=7498 ; Fys stock
 .Do %SCHERM(KLNr,PRNr,R)
 Quit
 ;