KFCOL G 1 ;CONTRACT-ORDERLIJNEN; Go naar KFCOLA [ 08/05/2002  10:44 AM ]
 ;
M0 S FP=2403+F60 W @F,@F2,@F4,MSG," [] = OK ",@F5,@F0 R K G YZ
M1 S MSG="HET ORDER IS NOG NIET GESLOTEN" G M0
M3 S MSG="ER IS GEEN LEVERANCIER GEOPEND VOOR DIT PRODUKT" G M0
M4 S MSG="TOELEVERING IN GEBRUIK" G M0
M5 S MSG="PRODUKT IN GEBRUIK" G M0
 ;
1 S SW12=1,ULSV=UL K UZ S Q15="^(""W    0.0""_UOR_UOD_$J(UR,6,0)_$J((UVN-100),3,0))"
 S Q16="^(""W    0.0T""_UOD_$J(TR,6,0)_$J((TUZ-100),3,0))"
2 S X=^(1),UOD=$TR($$EXTDATE^vhDTyp($$INTDATE^vhDTyp($P(X,D,2)),"DS"),D,"")
 S UOR=$P("R\O",D,$P(X,D,17)+1),UAF=$P(X,D,22),UTYP=$P(X,D,25)
 I UTYP="L" G YZ
 I UTYP'="C" G ^KFCOLB
 G M1:'UAF
3 L @("^"_Q_UGL_"(KC,US,UR)")
4 K UA,UO,UEP,UBE,U30 S FP=$P(UD,D,2)+1*100+1 W @F,@F1
5 G 3:K?.E1C.E!(K="")!($P(K,"E",2)>29),43:K="-"!(K=",") S UVN=K+100
 S U2=@("^"_Q_UGL_"(KC,US,UR,UVN)") G YZ:'$P(U2,D,2)
9 S PR=$P(U2,D,2),TR=$P(U2,D,27) I TR S LC=$P(@("^"_Q_"TO1(TR)"),D) L +@("^"_Q_"TO(LC,TR)"):2 E  G M4
10 L +@("^"_Q_"PR(PR)"):2 E  G M5
11 S PK1=$P($P(U2,D,7),"#",1),PK2=$P($P(U2,D,7),"#",2)
112 S AFRR=$P(U2,D,21),AFA=$E(AFRR,1),AFR=$E(AFRR,2),AFE=$P("1\100\1000",D,$F("EHM",AFA)-1),UEP=$J($P(U2,D,9)/$P(U2,D,3)*AFE,1,2)
12 S X=@("^"_Q_"PR(PR,0)"),PC=$P(X,D,1),(PST,PPS)=$P(X,D,14),PY=$P(X,D,17),X=^(1),PSN=$P(X,D,20),X=^(2),PRE=$P(X,D,9),PID=$P(X,D,25),PPS=PPS-$P(PRE,"#",2) S:'$P(U2,D,27) PPS=PPS+$P(U2,D,3)
13 S FP=1903+F60 W @F,@F1,$C(13),?2,"IDENTNR : ",?12,PID,?27,"PRODUKT  : ",PC
17 S X=$N(^("J")) I $E(X,1,1)'="J" G M3
19 S X=^(X),PLL=$P(X,D,7)
 S R=$$KLANTPR^KPRIJS(KC,PR),UMC=$P(R,D,2),PLP=$P(R,D,4),CIFP=$P(R,D,13)*AFE
21 S UPAR=$$MUNT^vhRtn1(UMC,,12)
23 S ULT=$$INTDATE^vhDTyp(%WK,"DW") S:TR ULT=ULT+(PLL+1*7) S ULT=$$EXTDATE^vhDTyp(ULT,"DW")
 I $D(ULTD),$$INTDATE^vhDTyp(ULTD,"DW")>$$INTDATE^vhDTyp(ULT,"DW") S ULT=ULTD
27 S R=PSN_D_PPS_D_$P(PY,"#",2)_D_$P(X,D,6)_D_ULT_D_$P(X,D,14,16)_D_UMC_D_AFA_D_PLP_D_PK1_D_PK2_D_D_UEP_D_D_$P(X,D,7)_D_PST_D_D D ^KF0268
29 G 1^KFCOLA
43 S UL=ULSV S:K="," K="-"
 ;
YZ K ULSV,LC,TUZ,GR,AFA,AFE,AFR,AFRR,UMC,UPAR,MSG,PST,PPS,PC,PR,PLL,PLP,CIFP,PID,PRE,PSN,PY,PK1,PK2,PGV,PNV,PKV,S,Q15,Q16
 K UA,UE,UK,UEP,UBE,UOD,UOR,ULT,U26,UAF,X,U30,TR,%TC,%INT,%EXT L @("^"_Q_UGL_"(KC,US,UR)") Q
 Q
 ;
SCROL(UVN) 
 S K=UVN-100 G 1
 ;
 ; Verzenden van een mail indien bepaalde contractlijnen volledig opgenomen zijn
SendMiniMail(KLNr,EmptyContract)
 New J,R,From,To,ccTo,Subject,Body,Opties,ORDNr,OLNr,ContrRef,PRNr,Korttekst,KlantRef,Prijs,HuidPrijs,KlNaam,KlAanspr,KlAdres,KlPostCode,KlWoonpl,IsStock,LevTem,MinBestH,Taal
 Set From=$$USERNAME^vhUSER(,"@") Set:From="" From="Info@VanHoecke.be"
 Set Opties("CONNECT")="E", Opties("FILTER")=1,Opties("NOPOP")=1,Opties("PIECE")=6,Opties("VWBEPERK")="AK2" ; Aankoopverantwoordelijke
 Set To=$$SELECT^PERSS("K",KLNr,.Opties)
 Set:To="" Opties("VWBEPERK")="AB1",To=$$SELECT^PERSS("K",KLNr,.Opties) ; Algemeen beheerder indien geen AK2
 Set:To="" To=$p(^KKL(^KK1(KLNr),2),D,19) ; Algemeen E-mail adres indien geen AK2 en geen AB1
 Set ccTo=$$USERNAME^vhUSER($$USERID^vhUSER("CDV"),"@")
 Set:To="" To=ccTo,ccTo=""  Set:From="" From="Info@VanHoecke.be"
 Set Taal=$P(^KKL(^KK1(KLNr),0),D,9) Set:Taal="" Taal="N"
 Set Subject=$$TXT("Afname"),(Body,ORDNr)=""
 For  Set ORDNr=$O(EmptyContract(ORDNr)) Quit:ORDNr=""  Do
 . Set ContrRef=EmptyContract(ORDNr),Body=Body_$C(13)_$$TXT("Contr")_": "_ORDNr_" - "_ContrRef,OLNr=""
 . For  Set OLNr=$O(EmptyContract(ORDNr,OLNr)) Quit:OLNr=""  Do
 . . Set R=EmptyContract(ORDNr,OLNr),PRNr=$P(R,D,2),KortTekst=$P(^KPR(PRNr,0),D),KlantRef=$$DISP^PAKKET(KLNr,PRNr,,,"CE")
 . . Set Prijs=$$EXTNUM^vhDTyp($P(R,D,6),0,".",2)_$S($E($P(R,D,21))="H":"%",1:"")_" "_$P(R,D,22)
 . . Set Body=Body_$C(13)_$C(13)_KortTekst
 . . Set:$L(KlantRef) Body=Body_$C(13)_$$TXT("UwRef")_": "_KlantRef
 . . Set Body=Body_$C(13)_$$TXT("Prijs")_": "_Prijs
 . . Set R=$$KLANTPR^KPRIJS(KLNr,PRNr),HuidPrijs=$$EXTNUM^vhDTyp($P(R,D),0,".",2)_$S($E($P(R,D,10))="H":"%",1:"")_" "_$P(R,D,2)
 . . Set:Prijs'=HuidPrijs Body=Body_" - "_$$TXT("NPrijs")_": "_HuidPrijs
 . . Set AndereContr=$$AndereContr(KLNr,PRNr)
 . . If 'AndereContr Do
 . . . Set R=^KPR(PRNr,1),IsStock=$P(R,D,20)
 . . . Set J=$O(^KPR(PRNr,"J"))
 . . . If $E(J)="J" Set R=^KPR(PRNr,J),MinBestH=$P(R,D,6),LevTerm=$P(R,D,7)+1
 . . . Set Body=Body_$C(13)_$$TXT("GeenContr")
 . . . Set Body=Body_$C(13)_$$TXT("LevTerm")_": "_$S(IsStock:$$TXT("Stock"),1:LevTerm_$$TXT("Week",LevTerm'=1+2))
 . . . Set:MinBestH Body=Body_$C(13)_$$TXT("MinBestH")_": "_$$EXTNUM^vhDTyp(MinBestH,0,".",0)_$$TXT("Stuk",MinBestH'=1+2)
 . . Else  Set Body=Body_$C(13)_$$TXT("AndereContr")_": "_$$EXTNUM^vhDTyp(AndereContr,0,".",0)_$$TXT("Stuk",AndereContr'=1+2)
 Set $E(Body)=""
 Set Body=$$TXT($S($L(Body,$C(13)_$C(13))>2:"LijnenOp",1:"LijnOp"))_":"_$C(13)_$C(13)_Body
 Set R=^KKL(^KK1(KLNr),0),KlNaam=$P(R,D,2),KlAanspr=$P(R,D,4),KlAdres=$P(R,D,5),KlPostCode=$P(R,D,6),KlWoonpl=$P(R,D,7)
 Set Body=$S($L(KlAanspr):KlAanspr_" ",1:"")_KlNaam_$C(13)_KlAdres_$C(13)_KlPostCode_"   "_KlWoonpl_$C(13)_$C(13)_Body
 Set Body=Body_$C(13)_$C(13)_$$TXT("MVrGr")_$S(From["Info":"",1:$C(13)_$C(13)_$$USERNAME^vhUSER(,1))
 Set Body=Body_$C(13)_$C(13)_"VAN HOECKE nv - "_$$TXT("Expert")_$C(13)_"Europark Noord, 9"_$C(13)_"B-9100 Sint-Niklaas"
 Set Body=Body_$C(13)_"Tel.: 0032-(0)3/760 19 00"_$C(13)_"Fax.: 0032-(0)3/760 19 19"
 Set Body=Body_$C(13)_"http://www.vanhoecke.be"_$C(13)_"http://www.orgalux.be"
 Set:$L(ccTo) To=ccTo,ccTo="" ; Mail enkel naar CDV verzenden (aangepast op 30 mei 2007 CW)
 Do:$ZU(5)'["DEV" SendMiniMail^vhLib(From,$$PiecesToList^vhLib(To,";"),Subject,Body,,,,,,,$LB(ccTo))
 Quit
 ;
 ; Zijn er nog restanten in andere contracten?
AndereContr(KLNr,PRNr)
 New AndereContr,WIndex,ORDNr,OLNr
 Set AndereContr="",WIndex="W"
 For  Set WIndex=$O(^KPR(PRNr,WIndex)) Quit:$E(WIndex)'="W"  Do:$E(WIndex,9)="R"
 . Set ORDNr=$E(WIndex,18,23),OLNr=100+$TR($E(WIndex,24,26)," ","")
 . Quit:$P($G(^KO1(ORDNr,"F")),D)'=KLNr
 . Set R=$G(^KOD(KLNr,"F",ORDNr,1))
 . Quit:$P(R,D,25)'="C"
 . Set R=$G(^KOD(KLNr,"F",ORDNr,OLNr)),AndereContr=AndereContr+$P(R,D,3)
 Quit AndereContr
 ;
 ; Ophalen taalafhankelijke tekst
TXT(Ref,Piece) 
 If '$D(Piece) Set Piece=2
 Quit $P($P($T(@("T"_Ref)),U,Piece),D,$F("NFDE",Taal)-1)
 ;
TAfname ;Afname contractorders\Diminution du contrat\Afname contractorders\Afname contractorders
TContr ;Contract\Contrat\Contract\Contract
TUwRef ;Uw ref\Votre réf\Uw ref\Uw ref
TPrijs ;Prijs\Prix\Prijs\Prijs
TNPrijs ;Nieuwe prijs\Nouveaux prix\Nieuwe prijs\Nieuwe prijs
TGeenContr ;Geen stuks meer voorradig\Rien en stock\Geen stuks meer voorradig\Geen stuks meer voorradig
TLevTerm ;Levertermijn\Délai de livraison\Levertermijn\Levertermijn
TMinBestH ;Min. bestelhoeveelheid\Quantité de commande minimale\Min. bestelhoeveelheid\Min. bestelhoeveelheid
TAndereContr ;Aantal in andere contracten\Quantité dans autres contrats\Aantal in andere contracten\Aantal in andere contracten
TWeek ; week\ semaine\ week\ week; weken\ semaines\ weken\ weken
TStock ;Stock\Stock\Stock\Stock
TStuk ; stuk\ pièce\ stuk\ stuk; stuks\ pièces\ stuks\ stuks
TLijnOp ;Volgende contractlijn is volledig afgenomen\La position suivante du contrat a été prise dans sa totalité\Volgende contractlijn is volledig afgenomen\Volgende contractlijn is volledig afgenomen
TLijnenOp ;Volgende contractlijnen zijn volledig afgenomen\Les positions suivantes du contrat ont été prise dans leurs totalité\Volgende contractlijnen zijn volledig afgenomen\Volgende contractlijnen zijn volledig afgenomen
TMVrGr ;Met vriendelijke groeten,\Meilleurs salutations,\Met vriendelijke groeten,\Met vriendelijke groeten,
TExpert ;expert in functioneel meubelbeslag\expert en quincaillerie fonctionnelle pour meubles\expert in functioneel meubelbeslag\expert in functioneel meubelbeslag