KKBG2 ;BETALINGSGEDRAG KLANTEN ;KKBG1; [ 01/07/2003  10:51 AM ]
 ;
 Kill ^HULP($J),^($J+100)
 Read !!,"Klantnummer ? ",KC
 Set Count=0,Begin=(DJ-1)_"."_DM
 Set R=$$KLANT(KC,Begin,1)
 If $L(R) Set Count=Count+1,^HULP($J,Count)=R
 Kill ^HULP($J),^($J+100)
 Quit
 ;
KLANT(KC,Begin,MinGem,Doc,DagenVv) 
 Set Doc=$G(Doc),DagenVv=$G(DagenVv) Set:Doc="" Doc="DWFO"
 Set KI2=1_(Begin*100-1)_".99",BeginDte="01."_$E(Begin,6,7)_"."_$E(Begin,3,4)
 Set KI1=^KK1(KC),KN=$P(^KKL(KI1,0),D,2),KX=$P(^(0),D,18) If KX="" Set KX="Kontant"
 Do:Doc'="O"
 .For  Set KI2=$O(^KKL(KI1,KI2)) Quit:KI2'?7N1"."1.2N  Do
 ..Set HistStr=^(KI2)
 ..For  Set HistVer=$P(HistStr,D) Quit:HistVer=""  Do
 ...Set HistStr=$P(HistStr,D,2,99)
 ...If $E(HistVer,1,2)="BD" Do:Doc["D" DIVERS(KI1,$E(KI2,2,7),$E(HistVer,2,99)) Quit
 ...If $E(HistVer,1,2)="BW" Do:Doc["W" WISSEL(KI1,$E(KI2,2,7),$E(HistVer,2,99)) Quit
 ...If $E(HistVer)="B" Do:Doc["F" FINANC(KI1,$E(KI2,2,7),$E(HistVer,2,99)) Quit
 Do:Doc["O"
 .Set KI2=99999
 .For  Set KI2=$O(^KKL(KI1,KI2)) Quit:KI2'?5N.N!(KI2>999999)  Do OPENST(KI1,KI2)
 Set (AantFakt,VervFakt,GemDays,MaxDays)=0,FaktNr=""
 For  Set FaktNr=$O(^HULP($J+100,KI1,FaktNr)) Quit:FaktNr=""  Do
 .Set R=^(FaktNr,0,"F")
 .Set AantFakt=AantFakt+1
 .If $D(^("O")) Do ChkOVrv(R) Quit
 .do ChkFVrv(R)
 If 'AantFakt Quit ""
 If VervFakt Set GemDays=$J(GemDays/VervFakt,0,0)
 If $D(MinGem),GemDays<MinGem Kill ^HULP($J+100,KI1) Quit ""
 Set %Verv=0 If AantFakt Set %Verv=$J(VervFakt/AantFakt*100,0,0)
 Quit KI1_D_KC_D_KN_D_KX_D_AantFakt_D_VervFakt_D_%Verv_D_GemDays_D_MaxDays
 ;
ChkOVrv(R) 
 Set R=$$DIFFDATE^vhDTyp($P(R,D,3),DT) Quit:R'>0
 Set VervFakt=VervFakt+1
 Set GemDays=GemDays+R Set:MaxDays<R MaxDays=R
 Quit
 ;
ChkFVrv(R) 
 New BetDat,VolgNr,X
 Set BetDat=$O(^HULP($J+100,KI1,FaktNr,""),-1) Quit:BetDat=""
 Set VolgNr=$O(^HULP($J+100,KI1,FaktNr,BetDat,""),-1) Quit:VolgNr=""
 Set X=^(VolgNr)
 If $E($P(X,D,14))="W" Quit
 Set R=$$DIFFDATE^vhDTyp($P(R,D,3),$P(X,D,2)) Quit:R'>0
 Set VervFakt=VervFakt+1
 Set GemDays=GemDays+R Set:MaxDays<R MaxDays=R
 Quit
 ;
FAKTUUR(FaktNr,BeginDte,BetDat,DagenVv) 
 New I,R,IsEuro,VervDays,KLNr,KlantId,FaktKode,FaktDat,VervDat
 Set BetDat=$G(BetDat,+$H)
 If FaktNr="" Quit ""
 Set R=$G(^KFA("F",FaktNr,0,0)),KLNr=$P(R,D),FaktKode=$P(R,D,2),FaktDat=$P(R,D,6),VervDat=$P(R,D,3)
 ;If FaktKode'="F" Quit ""  ; kortgesloten op verzoek van HA op 15.06.05 CW
 If FaktKode'="F",FaktKode'="C" Quit ""
 If FaktKode="C" For I=7:1:14 Set $P(R,D,I)=-$P(R,D,I)
 Set KlantId=^KK1(KLNr)
 Do:$D(^KKL(KlantId,FaktNr))
 .New R
 .Set R=^KKL(KlantId,FaktNr)
 .Set FaktDat=$P(R,D,2),VervDat=$P(R,D,3)
 Set $P(R,D,3)=VervDat,VervDays=BetDat-$$INTDATE^vhDTyp(VervDat)
 If DagenVv,VervDays<DagenVv Quit ""
 If $$DIFFDATE^vhDTyp(BeginDte,FaktDat)<0 Quit ""
 Set IsEuro=$$CALCDATE^vhDTyp($$FADEF^vhRtn1(11,1),"M","FD")
 If IsEuro,$$INTDATE^vhDTyp(FaktDat)<IsEuro Set $P(R,D,14)=$J($P(R,D,14)*$$MUNT^vhRtn1(,,,,"BEF"),0,2)
 Quit R
 ;
DIVERS(KI1,Periode,Refer) 
 New FaktNr,JournNr,VolgNr,BetDat,FaktKode,FaktDat,IsEuro,I,R,X
 Set Periode=$E(Periode,1,4)_"."_$E(Periode,5,6)
 Set JournNr=$P(Refer,"#",1),VolgNr=$P(Refer,"#",2)
 Set X=^KFI(Periode,JournNr,VolgNr),FaktNr=$P(X,D,9)
 Set BetDat=$$INTDATE^vhDTyp($P(X,D,2))
 Set R=$$FAKTUUR(FaktNr,BeginDte,BetDat,DagenVv)
 If $L(R) Do
 .Set IsEuro=$$CALCDATE^vhDTyp($$FADEF^vhRtn1(11,1),"M","FD")
 .If IsEuro,BetDat<IsEuro Set $P(X,D,5)=$J($P(X,D,5)*$$MUNT^vhRtn1(,,,,"BEF"),0,2)
 .Set FaktKode=$P(R,D,2),FaktDat=$$INTDATE^vhDTyp($P(R,D,6))
 .If FaktKode="C" For I=5,11,25 Set $P(X,D,I)=-$P(X,D,I)
 .Set ^HULP($J+100,KI1,FaktDat_FaktNr,0,"F")=R
 .For  Quit:'$D(^HULP($J+100,KI1,FaktDat_FaktNr,BetDat,VolgNr))  Set VolgNr=VolgNr+.01
 .Set ^HULP($J+100,KI1,FaktDat_FaktNr,BetDat,VolgNr)=X_D_JournNr_D_VolgNr
 Quit
 ;
FINANC(KI1,Periode,Refer) 
 New FaktNr,JournNr,VolgNr,BetDat,FaktKode,FaktDat,IsEuro,I,R,X
 Set Periode=$E(Periode,1,4)_"."_$E(Periode,5,6)
 Set JournNr=$P(Refer,"#",1),VolgNr=$P(Refer,"#",2)
 Set X=^KFI(Periode,JournNr,VolgNr),FaktNr=$P(X,D,13)
 Set BetDat=$$INTDATE^vhDTyp($P(X,D,2))
 Set R=$$FAKTUUR(FaktNr,BeginDte,BetDat,DagenVv)
 If $L(R) Do
 .Set IsEuro=$$CALCDATE^vhDTyp($$FADEF^vhRtn1(11,1),"M","FD")
 .If IsEuro,BetDat<IsEuro Set $P(X,D,5)=$J($P(X,D,5)*$$MUNT^vhRtn1(,,,,"BEF"),0,2)
 .Set FaktKode=$P(R,D,2),FaktDat=$$INTDATE^vhDTyp($P(R,D,6))
 .If FaktKode="C" For I=5,11,25 Set $P(X,D,I)=-$P(X,D,I)
 .Set ^HULP($J+100,KI1,FaktDat_FaktNr,0,"F")=R
 .For  Quit:'$D(^HULP($J+100,KI1,FaktDat_FaktNr,BetDat,VolgNr))  Set VolgNr=VolgNr+.01
 .Set ^HULP($J+100,KI1,FaktDat_FaktNr,BetDat,VolgNr)=X_D_JournNr_D_VolgNr
 Quit
 ;
WISSEL(KI1,Periode,Refer) 
 New FaktNr,JournNr,VolgNr,BetDat,FaktKode,FaktDat,IsEuro,I,R,X
 Set Periode=$E(Periode,1,4)_"."_$E(Periode,5,6)
 Set JournNr=$P(Refer,"#",1),VolgNr=$P(Refer,"#",2)
 Set X=^KFI(Periode,JournNr,VolgNr),$P(X,D,2)=$P($P(X,D,9)," "),FaktNr=$P($P(X,D,9)," ",2)
 Set BetDat=$$INTDATE^vhDTyp($P(X,D,2))
 Set R=$$FAKTUUR(FaktNr,BeginDte,BetDat,DagenVv)
 If $L(R) Do
 .Set IsEuro=$$CALCDATE^vhDTyp($$FADEF^vhRtn1(11,1),"M","FD")
 .If IsEuro,BetDat<IsEuro Set $P(X,D,5)=$J($P(X,D,5)*$$MUNT^vhRtn1(,,,,"BEF"),0,2)
 .Set FaktKode=$P(R,D,2),FaktDat=$$INTDATE^vhDTyp($P(R,D,6))
 .If FaktKode="C" For I=5,11,25 Set $P(X,D,I)=-$P(X,D,I)
 .Set ^HULP($J+100,KI1,FaktDat_FaktNr,0,"F")=R
 .For  Quit:'$D(^HULP($J+100,KI1,FaktDat_FaktNr,BetDat,VolgNr))  Set VolgNr=VolgNr+.01
 .Set ^HULP($J+100,KI1,FaktDat_FaktNr,BetDat,VolgNr)=X_D_JournNr_D_VolgNr
 Quit
 ;
OPENST(KI1,KI2) 
 New FaktKode,FaktDat,I,R,X
 Set X=^KKL(KI1,KI2)
 Set R=$$FAKTUUR(KI2,BeginDte,,DagenVv)
 If $L(R) Do
 .Set FaktKode=$P(R,D,2),FaktDat=$$INTDATE^vhDTyp($P(R,D,6))
 .If FaktKode="C" For I=4,5,6,10 Set $P(X,D,I)=-$P(X,D,I)
 .Set ^HULP($J+100,KI1,FaktDat_KI2,0,"F")=R
 .Set ^HULP($J+100,KI1,FaktDat_KI2,0,"O")=X
 Quit
 ;