KLPUTZ8 ;Prijsuitzonderingen (Log) [ 09/24/2003  11:51 AM ]
 
 ; Wegschrijven van de logging voor RPLKL
LOG(%J,KLNr,NoSa)
 New R,Rubriek
 If $G(NoSa)="" Set NoSa="N"
 Kill ^HULP(%J,"LOG")
 Merge ^HULP(%J,"LOG")=^HULP(%J,"OLD"),^HULP(%J,"LOG")=^HULP(%J,"NEW")
 Set Rubriek=$S(NoSa="N":"",1:NoSa)_"Utz"
 Do CompNew2Old(%J),SaveLog(%J,KLNr,Rubriek)
 Kill ^HULP(%J,"LOG")
 Quit
 
 ; Vergelijken van de nieuwe- met de oude situatie
CompNew2Old(%J)
 New HoofdGr,Groep,SubGroep,PRNr,Next,OldValue,NewValue
 Set HoofdGr=""
 For  Set HoofdGr=$O(^HULP(%J,"LOG",HoofdGr)) Quit:HoofdGr=""  Do
 . Set Groep=""
 . For  Set Groep=$O(^HULP(%J,"LOG",HoofdGr,Groep)) Quit:Groep=""  Do
 . . Set SubGroep=""
 . . For  Set SubGroep=$O(^HULP(%J,"LOG",HoofdGr,Groep,SubGroep)) Quit:SubGroep=""  Do
 . . . Set PRNr=""
 . . . For  Set PRNr=$O(^HULP(%J,"LOG",HoofdGr,Groep,SubGroep,PRNr)) Quit:PRNr=""  Do
 . . . . Set Next=""
 . . . . For  Set Next=$O(^HULP(%J,"LOG",HoofdGr,Groep,SubGroep,PRNr,Next)) Quit:Next=""  Do
 . . . . . Set OldValue=$G(^HULP(%J,"OLD",HoofdGr,Groep,SubGroep,PRNr,Next))
 . . . . . Set NewValue=$G(^HULP(%J,"NEW",HoofdGr,Groep,SubGroep,PRNr,Next))
 . . . . . If NewValue=OldValue Kill ^HULP(%J,"LOG",HoofdGr,Groep,SubGroep,PRNr,Next) Quit  ; Niet gewijzigd
 . . . . . Set:OldValue="" OldValue="N" ; Nieuwe uitzondering
 . . . . . Set:NewValue="" NewValue="D" ; Verwijderde uitzondering
 . . . . . Set ^HULP(%J,"LOG",HoofdGr,Groep,SubGroep,PRNr,Next)=$LB(OldValue,NewValue)
 Quit
 
 ; Loggen van de nieuwe-, gewijzigde- en verwijderde uitzonderingen
SaveLog(%J,KLNr,Rubriek)
 New R,Klas,HoofdGr,Groep,SubGroep,PRNr,Next,OldValue,NewValue,Korting1,Korting2,MinAant,MinVerp,FromDate,ToDate,Prijs
 Set HoofdGr=""
 For  Set HoofdGr=$O(^HULP(%J,"LOG",HoofdGr)) Quit:HoofdGr=""  Do
 . Set Klas=$$DISPLS^KLASS(HoofdGr),Groep=""
 . For  Set Groep=$O(^HULP(%J,"LOG",HoofdGr,Groep)) Quit:Groep=""  Do
 . . Set:Groep'=0 Klas=$$DISPLS^KLASS(Groep) Set SubGroep=""
 . . For  Set SubGroep=$O(^HULP(%J,"LOG",HoofdGr,Groep,SubGroep)) Quit:SubGroep=""  Do
 . . . Set:SubGroep'=0 Klas=$$DISPLS^KLASS(SubGroep) Set PRNr=""
 . . . For  Set PRNr=$O(^HULP(%J,"LOG",HoofdGr,Groep,SubGroep,PRNr)) Quit:PRNr=""  Do
 . . . . Set:PRNr Klas=Klas_"-"_$P(^KPR(PRNr,0),D) Set Next=""
 . . . . For  Set Next=$O(^HULP(%J,"LOG",HoofdGr,Groep,SubGroep,PRNr,Next)) Quit:Next=""  Do
 . . . . . Set R=^HULP(%J,"LOG",HoofdGr,Groep,SubGroep,PRNr,Next),OldValue=$LI(R,1),NewValue=$LI(R,2)
 . . . . . Set:OldValue="N" OldValue="*Nieuw*"
 . . . . . Set:NewValue="D" NewValue="*Delete*"
 . . . . . Else  
 . . . . . Do:OldValue[D
 . . . . . . Set Korting1=$P(OldValue,D),Korting2=$P(OldValue,D,2),Prijs=$P($P(OldValue,D,4),"#",2)
 . . . . . . Set MinAant=$P(OldValue,D,5),MinVerp=$P(OldValue,D,12)
 . . . . . . Set FromDate=$P(OldValue,D,7),ToDate=$P(OldValue,D,8)
 . . . . . . Set OldValue=""
 . . . . . . If Korting1 Set OldValue="K1:"_Korting1_"%"
 . . . . . . If Korting2 Set:$L(OldValue) OldValue=OldValue_"," Set OldValue=OldValue_"K2:"_Korting2_"%"
 . . . . . . If Prijs Set:$L(OldValue) OldValue=OldValue_"," Set OldValue=OldValue_"Pr:"_Prijs
 . . . . . . If MinAant Set:$L(OldValue) OldValue=OldValue_"," Set OldValue=OldValue_"MinAant:"_MinAant
 . . . . . . If MinVerp Set:$L(OldValue) OldValue=OldValue_"," Set OldValue=OldValue_"MinVerp:"_MinVerp
 . . . . . . If FromDate Set:$L(OldValue) OldValue=OldValue_"," Set OldValue=OldValue_"Start:"_$$EXTDATE^vhDTyp(FromDate)
 . . . . . . If ToDate Set:$L(OldValue) OldValue=OldValue_"," Set OldValue=OldValue_"Einde:"_$$EXTDATE^vhDTyp(ToDate)
 . . . . . Do:NewValue[D
 . . . . . . Set Korting1=$P(NewValue,D),Korting2=$P(NewValue,D,2),Prijs=$P($P(NewValue,D,4),"#",2)
 . . . . . . Set MinAant=$P(NewValue,D,5),MinVerp=$P(NewValue,D,12)
 . . . . . . Set FromDate=$P(NewValue,D,7),ToDate=$P(NewValue,D,8)
 . . . . . . Set NewValue=""
 . . . . . . If Korting1 Set NewValue="K1:"_Korting1_"%"
 . . . . . . If Korting2 Set:$L(NewValue) NewValue=NewValue_"," Set NewValue=NewValue_"K2:"_Korting2_"%"
 . . . . . . If Prijs Set:$L(NewValue) NewValue=NewValue_"," Set NewValue=NewValue_"Pr:"_Prijs
 . . . . . . If MinAant Set:$L(NewValue) NewValue=NewValue_"," Set NewValue=NewValue_"MinAant:"_MinAant
 . . . . . . If MinVerp Set:$L(NewValue) NewValue=NewValue_"," Set NewValue=NewValue_"MinVerp:"_MinVerp
 . . . . . . If FromDate Set:$L(NewValue) NewValue=NewValue_"," Set NewValue=NewValue_"Start:"_$$EXTDATE^vhDTyp(FromDate)
 . . . . . . If ToDate Set:$L(NewValue) NewValue=NewValue_"," Set NewValue=NewValue_"Einde:"_$$EXTDATE^vhDTyp(ToDate)
 . . . . . Do DLOGMOD^LOG("KL",KLNr,,OldValue,NewValue,Rubriek_":"_Klas)
 Quit