PVBLUMS3 ;Statistiek receptie ;[ 11/08/2003   8:27 PM ]
RECEPT Set Dev=0   
 Set Dev=$$OPEN^vhDEV(,"RCP.txt","W")
 Use Dev
 Do BLDCONTR^KPOSW
 Write $TR("LevNr;LevNm;PRNr;KortT;Klas;ABCVal;ABCRot;Stock;DefMag;LevTrm;MinBH;PalQty;ChkPal;Key;KreaDat;EndDat;CtrDat;StockDat;Qty;ChkPal;#VHPal;VHGemQty;VHPalLi;#BLPal;BLGemQty;BLPalLi",";",$C(9)),!
 Set Dat="",VolgNr=""
 Set (RCPNr,TOENr,TULNr,SULNr)=""
 For  Set RCPNr=$O(^RCP("D",RCPNr)) Quit:RCPNr=""  Do
 .Set RecHfd=^RCP("D",RCPNr)
 .Quit:$P(RecHfd,D,1)'="L"
 .Set LevNr=$P(RecHfd,D,2)
 .Quit:LevNr=6332  ; Halux
 .Quit:LevNr=6092  ; FolieTec
 .Quit:LevNr=5810  ; Burbidge
 .For  Set TOENr=$O(^RCP("D",RCPNr,"D",TOENr)) Quit:TOENr=""  Do
 ..For  Set TULNr=$O(^RCP("D",RCPNr,"D",TOENr,TULNr)) Quit:TULNr=""  Do
 ...Set (VHPalCnt,BLPalCnt,VHPalSom,BLPalSom)=0
 ...Set (VHPalLi,BLPalLi)=""
 ...Set (CtrDat,StockDat)=""
 ...Set RecOL=^RCP("D",RCPNr,"D",TOENr,TULNr)
 ...Set PRNr=$P(RecOL,D,1)
 ...For  Set SULNr=$O(^RCP("D",RCPNr,"D",TOENr,TULNr,SULNr)) Quit:SULNr=""  Do
 ....Set RecSOL=^RCP("D",RCPNr,"D",TOENr,TULNr,SULNr)
 ....Set:CtrDat<$P(RecSOL,D,6) CtrDat=$P(RecSOL,D,6)
 ....Set:StockDat<$P(RecSOL,D,7) StockDat=$P(RecSOL,D,7)
 ....If VHPalLi'[$P(RecSOL,D,5) Do 
 .....Set:$P(RecSOL,D,5) VHPalCnt=VHPalCnt+1
 ....Set VHPalLi=VHPalLi_"/"_$P(RecSOL,D,5)_";"_$P(RecSOL,D,4)
 ....Set VHPalSom=VHPalSom+$P(RecSOL,D,4)
 ....Quit:LevNr'=5005
 ....Set VervId=$P(RecHfd,D,3)
 ....Set FakNr=$P(RecSOL,D,10)
 ....Set VervLNr=$P(RecSOL,D,11)
 ....;Write VervId," ",FakNr," ",VervLNr,!
 ....Quit:VervId=""!(FakNr="")!(VervLNr="")
 ....Set Rec=$G(^Verv(LevNr,"D",VervId,FakNr,VervLNr,"V"))
 ....For I=1:1:$L(Rec,D) Do
 .....Set VRec=$P(Rec,D,I)
 .....Quit:$TR(VRec,"; ","")=""
 .....If BLPalLi'[$P(VRec,";",1) Do 
 ......Set:$P(VRec,";",2) BLPalCnt=BLPalCnt+1
 .....Set BLPalSom=BLPalSom+($P(VRec,";",2)*$P(VRec,";",3))
 .....Set BLPalLi=BLPalLi_"/"_$P(VRec,";",1)_";"_($P(VRec,";",2)*$P(VRec,";",3))
 ...Set $E(VHPalLi)=""
 ...Set $E(BLPalLi)=""
 ...If $D(^KPR(PRNr)) Do
 ....Set Rec0=^KPR(PRNr,0)
 ....Set Rec1=^KPR(PRNr,1)
 ....Set Rec2=^KPR(PRNr,2)
 ....Set RecI=$O(^KPR(PRNr,"I")),RecI=^KPR(PRNr,RecI)
 ....Set RecJ=$O(^KPR(PRNr,"J")),RecJ=^KPR(PRNr,RecJ)
 ....Set IDNr=$P(^KPR(PRNr,2),D,25)
 ...Else  If $D(^KPRO(PRNr)) Do
 ....Set Rec0=^KPRO(PRNr,0)
 ....Set Rec1=^KPRO(PRNr,1)
 ....Set Rec2=^KPRO(PRNr,2)
 ....Set RecI=$O(^KPRO(PRNr,"I")),RecI=^KPRO(PRNr,RecI)
 ....Set RecJ=$O(^KPRO(PRNr,"J")),RecJ=^KPRO(PRNr,RecJ)
 ...Else  Quit
 ...Set RecBL=""
 ...Set KortT=$P(Rec0,D,1)
 ...Set IDNr=$P(Rec2,D,25)
 ...If $P(RecJ,D,1)=5005 Do  ; Blum
 ....Set BLID="0"_$TR($E(IDNr,3,99),".","")
 ....Set RecBL=$G(^BLProd("D",$S(BLID="":"*",1:BLID)))
 ...Set NettoGew=$P(RecBL,D,26)/1000
 ...Set BrutoGew=$P(RecBL,D,9)/1000
 ...Set:'BrutoGew BrutoGew=$P(Rec1,D,13)/1000
 ...Set PalQty=$P(RecBL,D,18)
 ...Set Qty=$P(RecOL,D,5)
 ...Set NettoGew=Qty*NettoGew
 ...Set BrutoGew=Qty*BrutoGew
 ...Set VD2=$P(RecBL,D,19)
 ...Set Hoogte=$P(RecBL,D,23)
 ...Set Lengte=$P(RecBL,D,24)
 ...Set Breedte=$P(RecBL,D,25)
 ...Set BLVerp=$P(RecBL,D,6) Set:'BLVerp BLVerp=$P(RecJ,D,16)
 ...Set Vol=Hoogte*Lengte*Breedte*Qty/1000000/BLVerp
 ...Set Klas=$P(RecI,D,2)
 ...Set Klas=$$DISPLS^KLASS(Klas)
 ...Set ABCRot=$E($P($P(Rec0,D,8),"#"))
 ...Set ABCVal=$E($P($P(Rec0,D,8),"#",2))
 ...Set Stock=$P(Rec1,D,20)
 ...Set Stock=$S(Stock:"S",1:"N")
 ...Set:$D(ContrInd(PRNr)) Stock="C"
 ...Set DefMag=$P(Rec2,D,15)
 ...Set LevNm=$P($G(^KLE($G(^KL1(LevNr),"*"),0)),D,2)
 ...Set LevTrm=$P(RecJ,D,7)
 ...Set MinBH=$P(RecBL,D,14)
 ...Set:'MinBH MinBH=$P(RecJ,D,6)
 ...Set KreaDat=$TR($$EXTDATE^vhDTyp($P(RecHfd,D,22),"DKP"),".","-")
 ...Set EndDat=$TR($$EXTDATE^vhDTyp($P(RecHfd,D,23),"DKP"),".","-")
 ...Set CtrDat=$TR($$EXTDATE^vhDTyp(CtrDat,"DKP"),".","-")
 ...Set StockDat=$TR($$EXTDATE^vhDTyp(StockDat,"DKP"),".","-")
 ...Set ChkPal=""
 ...If PalQty,MinBH>PalQty,MinBH#PalQty Set ChkPal="*"
 ...Set ChkRcp=""
 ...Set VHPalGem=$S(VHPalCnt:$J(VHPalSom/VHPalCnt,0,2),1:"")
 ...Set BLPalGem=$S(BLPalCnt:$J(BLPalSom/BLPalCnt,0,2),1:"")
 ...Set:BLPalCnt&(BLPalGem'=VHPalGem) ChkRcp="*"
 ...Write LevNr,$C(9),LevNm,$C(9),PRNr,$C(9),KortT,$C(9),Klas,$C(9),ABCVal,$C(9),ABCRot,$C(9),Stock,$C(9),DefMag,$C(9),LevTrm,$C(9),MinBH,$C(9),PalQty,$C(9),ChkPal,$C(9),RCPNr,";",TOENr,";",TULNr,$C(9),KreaDat,$C(9),EndDat,$C(9),CtrDat,$C(9),StockDat,$C(9),Qty,$C(9),ChkRcp,$C(9),VHPalCnt,$C(9),$TR(VHPalGem,".",","),$C(9),VHPalLi,$C(9),BLPalCnt,$C(9),$TR(BLPalGem,".",","),$C(9),BLPalLi,!
 close:0'[Dev Dev
 Quit