#Include BL.Derde.LevSpecifiek
TRANSPC ;Verwerking expediteur (sluiten) [ 03/05/2003  9:12 AM ]  ; Compiled June 30, 2009 17:02:36
 ;
CLOSE(TranspNr,VervRef)
 Do DISPLAY^vhScherm("TRANSPCLO")
 If '$G(TranspNr),$G(VervRef) Set TranspNr=$P(^TRANSP("D",VervRef),D)
 Do:'$G(TranspNr)
 .If $G(io) Set TranspNr=$P($G(^TRANSP("U",io,"T")),D)
 .Set TranspNr=$$TRANSP^LEVER(,$G(TranspNr),"Transportoverzicht voor","Allen")
 Do:TranspNr'="CANC" DISPLAY^vhScherm("TRANSPCLO"),FIELD^vhScherm("TRANSPCLO","CLOSLIST")
 Quit
 ;
CLOSEDIT(TranspNr,Beperk,VervRef) 
 New R,SelClose,%J,Input,Status
 Set %J=$$%J^vhRtn1()
 Set TranspNr=$G(TranspNr),Beperk=$G(Beperk,1),Detail=0
 Set Status=$S(Beperk:"",1:"A")
 Do FETCH(TranspNr,%J,Status,,$G(VervRef))
 If $O(^HULP(%J,""),-1) Do
 .Do STORE^vhTERMINA()
 .Do INIT^vhLIST("TRANSP","SELCLOSE",.SelClose)
 .Do WRITE^vhLIST(.SelClose)
 .For  Set Input=$$SCROLL^vhLIST(.SelClose) Do  Quit:Input="CANC"
 ..Do:Input="COM" CALL^vhMenu("TRANSPCLO")
 ..Do EXEC^vhMenu("TRANSPCLO",.Input)
 .Do REFRESH^vhTERMINA()
 Else  Do
 .Set R=$$^vhTXTPOP("TRANSP",$S('$D(^TRANSP("D")):"NOTRANSP",1:"NOOPEN"))
 .Do:R="A" CLOSEDIT(TranspNr,0)
 Kill ^HULP(%J)
 Quit
 ;
FETCH(TranspNr,%J,Status,Detail,OneVervRef) 
 New R,VervRef,Count,Verpak,ColTyp,Index,GroepNr
 Set TranspNr=$G(TranspNr),Status=$G(Status),Detail=$G(Detail)
 Set VervRef="",Count=0,Index=$S(Status="":"IO",1:"D")
 Kill ^HULP(%J)
 For  Set VervRef=$O(^TRANSP(Index,VervRef),-1) Quit:VervRef=""  Do
 .If $G(OneVervRef),VervRef'=OneVervRef Quit
 .If TranspNr Set R=^TRANSP("D",VervRef) Quit:$P(R,D)'=TranspNr
 .Kill Verpak
 .Set (ColTyp,Verpak)=""
 .For  Set ColTyp=$O(^TRANSP("D",VervRef,"Q",ColTyp)) Quit:ColTyp=""  Do
 ..Set R=^TRANSP("D",VervRef,"Q",ColTyp)
 ..Set Verpak($P(^RES("EWBON","PI","COLLIETYPE","D",ColTyp),"`"))=ColTyp_$P(R,D)
 .Set (ColTyp,Verpak)=""
 .For  Set ColTyp=$O(Verpak(ColTyp)) Quit:ColTyp=""  Set Verpak=Verpak_";"_Verpak(ColTyp)
 .Set $E(Verpak)=""
 .Set R=^TRANSP("D",VervRef),$P(R,D,21,99)=VervRef_D_D_Verpak_"\L\"_Detail_D_D
 .Set Count=Count+1,^HULP(%J,Count)=R
 .Do:Detail
 ..Set GroepNr=""
 ..For  Set GroepNr=$O(^TRANSP("D",VervRef,"D",GroepNr)) Quit:GroepNr=""  Do
 ...S xTransport=^TRANSP("D",VervRef,"D",GroepNr),KlantNr=$P(xTransport,"\")
 ...Kill Verpak
 ...Set (ColTyp,Verpak)=""
 ...For  Set ColTyp=$O(^TRANSP("D",VervRef,"D",GroepNr,"Q",ColTyp)) Quit:ColTyp=""  Do
 ....Set R=^TRANSP("D",VervRef,"D",GroepNr,"Q",ColTyp)
 ....Set Verpak($P(^RES("EWBON","PI","COLLIETYPE","D",ColTyp),"`"))=ColTyp_$P(R,D)
 ...Set (ColTyp,Verpak)=""
 ...For  Set ColTyp=$O(Verpak(ColTyp)) Quit:ColTyp=""  Set Verpak=Verpak_";"_Verpak(ColTyp)
 ...Set $E(Verpak)=""
 ...Set R=^TRANSP("D",VervRef,"D",GroepNr),$P(R,D,21,99)=VervRef_D_GroepNr_D_Verpak_"\K\\"_$P(R,D,6)_D
 ...Set Count=Count+1,^HULP(%J,Count)=R
 ;if Count=0 D FETCH(TranspNr,%J,$G(Status),0,"")
 Quit
 ;
BEPERK(TranspNr,%J,SelClose,Beperk) 
 New Status,OldSel
 Set OldSel=$G(^HULP(%J,SelClose("SELECT"))),Beperk='$G(Beperk)
 If 'Beperk S Detail=0
 Set Status=$S(Beperk:"",1:"A")
 Set Tekst=$Select(Beperk:"Openstaande transporten",1:"Volledig overzicht")
 Set FP=201
 Write @F,$J("                             "_Tekst,79)
 Do FETCH(TranspNr,%J,Status,$G(Detail)) 
 Set SelClose("MAX")=$O(^HULP(%J,""),-1)
 Set:SelClose("SELECT")>SelClose("MAX") SelClose("SELECT")=SelClose("MAX")
 Kill SelClose("OFFSET")
 For SelClose("SELECT")=1:1:SelClose("MAX") Quit:^HULP(%J,SelClose("SELECT"))=OldSel
 Set:$G(^HULP(%J,SelClose("SELECT")))'=OldSel SelClose("SELECT")=1
 ;Do DISPLAY^vhScherm("TRANSPCLO","","","","CLOSVIEW")
 Do WRITE^vhLIST(.SelClose)
 Quit
 ;
DETAIL(TranspNr,%J,SelClose,Beperk,Detail) 
 New Status,OldSel,Tekst
 Set OldSel=$G(^HULP(%J,SelClose("SELECT"))),Beperk=$G(Beperk),Detail='$G(Detail)
 Set Status=$S(Beperk:"",1:"A")
 I Detail Do
 . Set VervNr=$Piece(OldSel,"\",21)
 . Set Tekst=$Select(VervNr'="":"Detail transport "_VervNr,1:"Detail transporten")
 Else  Do
 . Set VervNr=""
 . Set Tekst=$Select(Beperk:"Openstaande transporten",1:"Volledig overzicht")
 Set FP=201
 Write @F,$J("                              "_Tekst,79)
 Do FETCH(TranspNr,%J,Status,Detail,VervNr) 
 Set SelClose("MAX")=$O(^HULP(%J,""),-1)
 Set:SelClose("SELECT")>SelClose("MAX") SelClose("SELECT")=SelClose("MAX")
 Kill SelClose("OFFSET")
 For SelClose("SELECT")=1:1:SelClose("MAX") Quit:^HULP(%J,SelClose("SELECT"))=OldSel
 Set:$G(^HULP(%J,SelClose("SELECT")))'=OldSel SelClose("SELECT")=1
 Do WRITE^vhLIST(.SelClose)
 Quit
 ;
ZKKLANT(%J) ;toont het detail voor een bepaalde klant
 Set KNr=$$SELECT^KLANT6()
 If '$D(^KK1(KNr)) Do  Quit
 . ;Do WARN^vhTXTPOP("Er bestaat geen klant met het nummer "_KNr)
 . Set FP=401 Write @F,@F1 D FETCHZOEKLIJST(%J,,"")
 Set FP=201
 Write @F,$J("         Leveringsbons van Klant "_$P(^KK1(KNr)," "),79)
 ;Set %J=$$%J^vhRtn1()
 Set FP=401 
 Write @F,@F1
 Do FETCHZOEKLIJST(%J,KNr) 
 Quit
 ;
ZKBONNR(%J) ;toont het detail voor bepaalde bonnen
 Kill BonLijst
 Do VANTOT^DCSELECT
 If K="" Set FP=401 Write @F,@F1 D FETCHZOEKLIJST(%J,,"") Quit
 Set BonLijst=""
 For I=1:1:$L(K,",") Do
 . Set Reeks=$Piece(K,",",I)
 . I Reeks["-" Do
 . . Set Begin=$Piece(Reeks,"-"),Einde=$Piece(Reeks,"-",2)
 . . For J=Begin:1:Einde Set BonLijst(J)=""
 . E  S BonLijst(Reeks)=""
 Set FP=201
 Write @F,$J("        Lijst met leveringsbons "_K,79)
 Set FP=401 
 Write @F,@F1
 Do FETCHZOEKLIJST(%J,,.BonLijst) 
 Quit
 ;
ZKTRANSP(%J) ;toont het detail van een bepaald transport
 S VervNr=$$ASK^vhINP("Vervoernummer : ",20,"","")
 If VervNr="" Set FP=401 Write @F,@F1 D FETCHZOEKLIJST(%J,,"") Quit
 If '$D(^TRANSP("D",VervNr)) Do
 . Set FP=401 Write @F,@F1 
 . D FETCHZOEKLIJST(%J,,"")
 Else  Do
 . Set FP=201
 . Write @F,$J("                              Detail vervoer "_TranspNr,79)
 . Set FP=401 
 . Write @F,@F1
 . Set Detail=1
 . Do FETCH(,%J,1,Detail,VervNr)
 . Set SelClose("MAX")=$O(^HULP(%J,""),-1)
 . Set:SelClose("SELECT")>SelClose("MAX") SelClose("SELECT")=SelClose("MAX")
 . Kill SelClose("OFFSET")
 . ;For SelClose("SELECT")=1:1:SelClose("MAX") Quit:^HULP(%J,SelClose("SELECT"))=OldSel
 . Set SelClose("SELECT")=1
 . Do WRITE^vhLIST(.SelClose)
 Quit
 
 ;
 ;lijst tonen op basis van een klantnumer of een lijst met bonnummers
FETCHZOEKLIJST(%J,KNr,BonLijst) 
 ;Do WLIP^vhDBG(127,"TranspNr: "_$J(TranspNr,10))
 ;Do WLIP^vhDBG(127,"%J: "_$J(%J,10))
 New R,VervRef,Count,Verpak,TotVerpak,ColTyp,GroepNr
 New Status,OldSel
 Kill ^HULP(%J)
 Set OldSel=$G(^HULP(%J,SelClose("SELECT")))
 Set VervRef="",Count=0,AantBonnen=0,Detail=1
 For  Set VervRef=$O(^TRANSP("D",VervRef),-1) Quit:VervRef=""  Do
 . Set xHeader=^TRANSP("D",VervRef),$P(xHeader,D,21,99)=VervRef_D_D_"\L\1"
 . Set (HeaderNr,Count)=Count+1
 . Kill TotVerpak
 . Set GroepNr="",TotGewicht=0,Gevonden=0
 . For  Set GroepNr=$O(^TRANSP("D",VervRef,"D",GroepNr)) Quit:GroepNr=""  Do
 . . If $D(BonLijst) Do
 . . . Set BonNr="",InBonLijst=0
 . . . For  Set BonNr=$O(^TRANSP("D",VervRef,"D",GroepNr,"B",BonNr)) Quit:BonNr=""!InBonLijst  Do
 . . . . If $D(BonLijst(BonNr)) Set InBonLijst=1
 . . Else  Set InBonLijst=1
 . . Quit:'InBonLijst
 . . Set xTransport=^TRANSP("D",VervRef,"D",GroepNr),KlantNr=$P(xTransport,"\")
 . . If $G(KNr)'="" Quit:KNr'=KlantNr
 . . Set Gevonden=1,AantBonnen=AantBonnen+1          ;we hebben een bon gevonden die aan de voorwaarde(n) voldoet
 . . Kill Verpak
 . . Set (ColTyp,Verpak)=""
 . . For  Set ColTyp=$O(^TRANSP("D",VervRef,"D",GroepNr,"Q",ColTyp)) Quit:ColTyp=""  Do
 . . . Set R=^TRANSP("D",VervRef,"D",GroepNr,"Q",ColTyp)
 . . . Set ColId=$P(^RES("EWBON","PI","COLLIETYPE","D",ColTyp),"`")
 . . . Set Verpak(ColId)=ColTyp_$P(R,D)
 . . . If $D(TotVerpak(ColId)) Do
 . . . . Set $P(TotVerpak(ColId),D,2)=$P(TotVerpak(ColId),D,2)+$P(R,D)
 . . . Else  Set TotVerpak(ColId)=ColTyp_D_$P(R,D)
 . . Set (ColTyp,Verpak)=""
 . . For  Set ColTyp=$O(Verpak(ColTyp)) Quit:ColTyp=""  Set Verpak=Verpak_";"_Verpak(ColTyp)
 . . Set $E(Verpak)=""
 . . Set R=^TRANSP("D",VervRef,"D",GroepNr),$P(R,D,21,99)=VervRef_D_GroepNr_D_Verpak_"\K\\"_$P(R,D,6)_D
 . . Set TotGewicht=TotGewicht+$Piece(R,D,3)
 . . Set Count=Count+1,^HULP(%J,Count)=R
 . If Gevonden D              ;headerlijn wordt alleen getoond als er voor het transport bonnen gevonden zijn die aan de voorwaarden voldoen
 . . Set $P(xHeader,"\",3)=TotGewicht
 . . Set TotVerpak="",ColId=""
 . . For  Set ColId=$O(TotVerpak(ColId)) Quit:ColId=""  Set TotVerpak=TotVerpak_";"_$P(TotVerpak(ColId),D)_$P(TotVerpak(ColId),D,2)
 . . Set $E(TotVerpak)=""
 . . Set $P(xHeader,"\",23)=TotVerpak
 . . Set ^HULP(%J,HeaderNr)=xHeader
 . Else  Set Count=Count-1   ;headerlijn wordt alleen getoond als er voor het transport bonnen gevonden zijn die aan de voorwaarden voldoen
 If AantBonnen=0 Do
 . Set Tekst=$Select($G(KNr)'="":"Er zijn geen bonnen van deze klant",$D(BonLijst)>1:"De geselecteerde bonnummers komen niet voor in een transport",1:"Niets gevonden")
 . Do WARN^vhTXTPOP(Tekst)
 . Do DETAIL("",%J,.SelClose,.Beperk,1) 
 Else  Do
 . Set Beperk=1
 . Set SelClose("MAX")=$O(^HULP(%J,""),-1)
 . Set:SelClose("SELECT")>SelClose("MAX") SelClose("SELECT")=SelClose("MAX")
 . Kill SelClose("OFFSET")
 . For SelClose("SELECT")=1:1:SelClose("MAX") Quit:^HULP(%J,SelClose("SELECT"))=OldSel
 . Set:$G(^HULP(%J,SelClose("SELECT")))'=OldSel SelClose("SELECT")=1
 . Set Detail=1
 . Do WRITE^vhLIST(.SelClose)
 Quit
 
DETCOLLI(%J) ;toont detailinfo voor een colli
 New R,VervRef,GroepNr,Modify
 Set BarCode=$$BCSELECT^TRANSP($G(BarCode))
 Do:BarCode
 . Set R=$G(^TRANSP("L",BarCode_" ")),VervRef=$P(R,D,2),GroepNr=$P(R,D,3)
 . If VervRef,GroepNr Do
 . . Set Modify='$D(^TRANSP("D",VervRef,"D",GroepNr,"Q"))
 . . If '$D(^KU1(GroepNr,"F")) D
 . . . Do WARN^vhTXTPOP("Detailinfo niet beschikbaar voor transport "_VervRef_" en groep "_GroepNr,"")
 . . Else  Do
 . . . Do STORE^vhTERMINA()
 . . . Set FP=162
 . . . Write @F,@F1
 . . . Do @($S(Modify:"MODGRP",1:"RPLGRP")_"^TRANSP(VervRef,GroepNr)"),REFRESH^vhTERMINA()
 . . Set FP=2201
 . . Write @F,@F1
 Quit
 
DETGROEP(%J,SelClose) 
 New R,VervRef,GroepNr,Modify
 Set R=^HULP(%J,SelClose("SELECT")),VervRef=$P(R,D,21),GroepNr=$P(R,D,22)
 Set Modify='$D(^TRANSP("D",VervRef,"D",GroepNr,"Q"))
 If '$D(^KU1(GroepNr,"F")) D
 . Do WARN^vhTXTPOP("Detailinfo niet beschikbaar voor transport "_VervRef_" en groep "_GroepNr,"")
 Else  Do
 . Do STORE^vhTERMINA()
 . Set FP=162
 . Write @F,@F1
 . Do @($S(Modify:"MODGRP",1:"RPLGRP")_"^TRANSP(VervRef,GroepNr)"),REFRESH^vhTERMINA()
 Quit
 ;
 
 ; Verwijder een lijn
LDELETE(VervRef,WachtWOk,BackGrnd) 
 New R,TranspNr
 Set WachtWOk=$G(WachtWOk),BackGrnd=$G(BackGrnd)
 Do
 .If 'BackGrnd Quit:'$$ASK^vhWACHTW("MANAGER",,,$S(WachtWOk:"",1:0))
 .Set VerwijderOK=$S(BackGrnd:1,1:$$^vhTXTPOP("SYSTEM","JANEEN","","Wil je dit transport verwijderen?"))
 .Quit:'VerwijderOK
 .Set R=^TRANSP("D",VervRef),TranspNr=$P(R,D)
 .Kill ^TRANSP("D",VervRef)
 .Quit:BackGrnd
 .Do:'WachtWOk DELETE^vhLISTE(.SelClose)
 .Do DETAIL(TranspNr,%J,.SelClose,$G(Beperk),'$G(Detail)),WRITE^vhLIST(.SelClose)
 Quit
 ;
 ; Verwijder alles tot een bepaalde datum
DELETE(TranspNr,BackGrnd) 
 New %SC,R,VrevRef,VervDat,DelDat
 Set TranspNr=$G(TranspNr),BackGrnd=$G(BackGrnd)
 Do
 .Set DelDat=$$CALCDATE^vhDTyp(,"M",-12,"LD")
 .If 'BackGrnd Quit:'$$ASK^vhWACHTW("MANAGER",,,0)  Do  Quit:'%SC  Quit:'DelDat
 ..Do STORE^vhTERMINA(),FIELD^vhScherm("TRANSPCLO","DELDAT"),REFRESH^vhTERMINA()
 .Set VervRef=""
 .For  Set VervRef=$O(^TRANSP("D",VervRef)) Quit:VervRef=""  Do
 ..Quit:$D(^TRANSP("IO",VervRef))
 ..Set R=^TRANSP("D",VervRef),VervDat=$P(R,D,10)
 ..Set:$P(R,D,11)>VervDat VervDat=$P(R,D,11)
 ..Set:$P(R,D,12)>VervDat VervDat=$P(R,D,12)
 ..Quit:VervDat>DelDat
 ..If TranspNr Quit:$P(R,D)'=TranspNr
 ..Do LDELETE(VervRef,1,BackGrnd)
 .Do DELLOG(DelDat) Do:'BackGrnd BEPERK(TranspNr,%J,.SelClose,'$G(Beperk)),WRITE^vhLIST(.SelClose)
 Quit
 ;
 ; Nachtelijke opkuis
NDELETE 
 Set $ZT="^cA406",Q="K"
 Do ^cA604,INIT^vhTERMINA,DELETE(,1)
 Quit
 ;
 ; Opkuisen van de barcode log
DELLOG(DelDat) 
 New R,BarCode,LogDat
 Set BarCode=""
 For  Set BarCode=$O(^TRANSP("L",BarCode)) Quit:BarCode=""  Do
 .Set R=^TRANSP("L",BarCode),LogDat=$P(R,D,4)
 .Kill:LogDat'>DelDat ^TRANSP("L",BarCode)
 Quit
 ;
 ; Het sluiten van een transport
CLOSVERV(%J,SelClose,Modify,CheckAll) 
 New zb,%SC,I,R,sFL,VervRef,Closed,Count,TranspNr,Items,TransDat,Paletten
 Quit:$$BevatOrders($P(^HULP(%J,SelClose("SELECT")),D,21))
 Quit:$$BevatGeenVerpakking($P(^HULP(%J,SelClose("SELECT")),D,21))
 Set Modify=$G(Modify),CheckAll=$G(CheckAll,1)
 Do:Modify=""
 .Set Count=0
 .For I="O","T","E" Do
 ..Quit:'$$CHKMENU^TRANSP("CLOSE","",I)
 ..Set Count=Count+1,Modify(Count)=I_"`"_$P("Ophalen\Transfert\Etiketten",D,$F("OTE",I)-1)
 .Set Modify=$O(Modify(""),-1)
 .Set Modify=$$WILD^vhPOPUP("C;C","O1-A","",.Modify)
 Do:$L(Modify)
 .Set R=^HULP(%J,SelClose("SELECT")),TranspNr=$P(R,D),VervRef=$P(R,D,21)
 .If TranspNr=$$$LevGLS,CheckAll,'$$CHECKALL^TRANSP("DI1 ") Quit  ; Controle GLS - leveringen niet opgenomen
 .Quit:'$$LOCK^TRANSP(VervRef)
 .If Modify="E" Do LABEL^TRANSPL(VervRef),UNLOCK^TRANSP(VervRef) Quit
 .Set sFL(1)=^HULP(%J,SelClose("SELECT")),VervRef=$P(sFL(1),D,21)
 .If Modify="OT" Do
 ..Do CLOSVERV(%J,.SelClose,"O",0)
 ..Set VervRef=$P(sFL(1),D,21),R=^TRANSP("D",VervRef)
 ..Do:$P(R,D,11) CLOSVERV(%J,.SelClose,"T",0)
 ..Set %SC=0
 .Else  If Modify="O" Do
 ..Set Paletten=$P($$CalcPalet^TRANSP(VervRef),D)
 ..Do STORE^vhTERMINA()
 ..Do NIEUW^vhScherm("TRANSPCLOE")
 ..Do REFRESH^vhTERMINA()
 .Else  Do
 ..Set TransDat=$H,VervRef=$P(sFL(1),D,21)
 ..Set %SC=$$^vhTXTPOP("TRANSP","TRANSFERT","",VervRef,$$EXTDATE^vhDTyp(TransDat),$$EXTTIME^vhDTyp(TransDat))
 ..Set:%SC $P(sFL(1),D,12)=TransDat
 .Do:%SC
 ..For I=11,12 Set:$TR($P(sFL(1),D,I),",0","")="" $P(sFL(1),D,I)=""
 ..Set TranspNr=$P(sFL(1),D),R=$G(^TRANSP("T",TranspNr)),Items=$P(R,D,4)
 ..Set:Items="" Items="O#T#E" Set Items="#"_Items_"#"
 ..Set:Items'["#T#" $P(sFL(1),D,12)=$P(sFL(1),D,11) Set:Items'["#O#" $P(sFL(1),D,11)=$P(sFL(1),D,12)
 ..Set ^HULP(%J,SelClose("SELECT"))=sFL(1)
 ..Set VervRef=$P(sFL(1),D,21),R=^TRANSP("D",VervRef),$P(R,D,11,15)=$P(sFL(1),D,11,15)
 ..Set Closed=$P(R,D,11)&$P(R,D,12)
 ..Set:Closed $P(R,D,2)="T" Set ^TRANSP("D",VervRef)=R
 ..Do:Closed
 ...Kill ^TRANSP("IO",VervRef)
 ...Do MarkBulkFact(VervRef)
 ..If TranspNr=$$$LevGLS Do  ; Enkel voor ABX
 ...Do LABEL^TRANSPL(VervRef)
 ...Do:Modify="O" PRINT^DCABXVD(VervRef)
 ..Else  Do
 ...Do:Modify="O" EXTERN^DCPRINT("E",VervRef,,,1)
 ..Do:Modify="T" VERWERK^TRANSPE(VervRef),STORE^LOG("TRP",VervRef,"S")
 ..Do REFRESH^vhLIST(.SelClose,"L",SelClose("SELECT"))
 .Do UNLOCK^TRANSP(VervRef)
 Quit
 ;
 ; Invullen van de bulkreferentie (voor facturatie)
MarkBulkFact(VervRef)
 New %TC,R,GroepNr,KLNr,BONNr,FactGroep
 Set FactGroep=$$FactGroep(VervRef),GroepNr=""
 For  Set GroepNr=$O(^TRANSP("D",VervRef,"D",GroepNr)) Quit:GroepNr=""  Do
 . Set KLNr=$P(^TRANSP("D",VervRef,"D",GroepNr),D),BONNr=""
 . For  Set BONNr=$O(^TRANSP("D",VervRef,"D",GroepNr,"B",BONNr)) Quit:BONNr=""  Do
 . . Quit:'$D(^KUL(KLNr,"F",BONNr))
 . . For  Do  Quit:%TC
 . . . Do ADD^vhLock("^KUL(KLNr,""F"",BONNr)")
 . . . Do:'%TC LDISP^vhLock("^KUL(KLNr,""F"",BONNr)","Bon "_BONNr)
 . . Set R=^KUL(KLNr,"F",BONNr,1)
 . . Set $P(R,D,38)=FactGroep
 . . Set ^KUL(KLNr,"F",BONNr,1)=R
 . . Do REMOVE^vhLock("^KUL(KLNr,""F"",BONNr)")
 Quit
 ;
 ; De factratiegroep bepalen op basis van de vervoersreferentie
FactGroep(VervRef)
 New R,FactGroep,TranspNr,TempVRef,Opgehaald,EDIVerzonden,TranspType,GroepNr,FANr
 Set FactGroep=""
 Set R=^TRANSP("D",VervRef),TranspNr=$P(R,D),TranspType=$P(R,D,5),Opgehaald=$P(R,D,11),EDIVerzonden=$P(R,D,12)
 If TranspNr=$$$LevGLS {
	 Set TempVRef=""
	 For  {
		 Set TempVRef=$O(^TRANSP("D",TempVRef))
		 Quit:TempVRef=""
		 Continue:TempVRef=VervRef ; Zichzelf
		 Set R=^TRANSP("D",TempVRef)
		 Continue:$P(R,D)'=TranspNr ; Andere transporteur
		 Continue:$P(R,D,5)'=TranspType ; Beiden zijn levering of terugname
		 Continue:+$P(R,D,11)'=+Opgehaald ; Niet dezelfde dag of niet gesloten
		 Continue:+$P(R,D,12)'=+EDIVerzonden ; Niet dezelfde dag of niet gesloten
		 Set GroepNr=""
		 For  {
			 Set GroepNr=$O(^TRANSP("D",VervRef,"D",GroepNr))
			 Quit:'GroepNr
			 Set BONNr=""
			 Set FANr=$P($G(^KU1(GroepNr,"F")),D,2)
			 Quit:FANr  ; Groep reeds gefactureerd
		 }
		 Continue:$G(FANr) ; Indien een groep gefactureerd, dan transport reeds gefactureerd
		 Set FactGroep="TP"_TempVRef
		 Quit:$L(FactGroep)
	 }
 }
 Set:FactGroep="" FactGroep="TP"_VervRef
 Quit FactGroep
 ;
 ; Controle of een transport nog orders bevat, indien ja dan kan het transport niet gesloten worden.
BevatOrders(VervRef)
 New R,BevatOrders,GroepNr,TranspDate
 Set BevatOrders=0,GroepNr=""
 For  Set GroepNr=$O(^TRANSP("D",VervRef,"D",GroepNr)) Quit:GroepNr=""  Do  Quit:BevatOrders
 . Set BevatOrders=$D(^TRANSP("D",VervRef,"D",GroepNr,"O"))
 Do:BevatOrders
 . Set Transporteur=$$TRANSPORTEUR^TRANSP(VervRef,1)
 . Set R=^TRANSP("D",VervRef),TranspDate=$$EXTDATE^vhDTyp($P(R,D,10))
 . Set BevatOrders=$$^vhTXTPOP("TRANSP","BEVATORDERS","",Transporteur,TranspDate)
 Quit BevatOrders
 ;
 ; Controle of voor elke zending verpakking is ingevuld
BevatGeenVerpakking(VervRef)
 New R,BevatGeenVerpakking,GroepNr,TranspDate,TpObj,KLNr,Klanten
 Set GroepNr="",TpObj=##class(Flow.Cons.Transport).%OpenId(VervRef)
 If $IsObject(TpObj),TpObj.VerpakkingNietVerplicht
 Else  Do
 . For  Set GroepNr=$O(^TRANSP("D",VervRef,"D",GroepNr)) Quit:GroepNr=""  Do
 . . Quit:'$D(^TRANSP("D",VervRef,"D",GroepNr,"B"))
 . . Quit:$D(^TRANSP("D",VervRef,"D",GroepNr,"Q"))
 . . Set BevatGeenVerpakking(GroepNr)=""
 . Do:$D(BevatGeenVerpakking)
 . . Set Transporteur=$$TRANSPORTEUR^TRANSP(VervRef,1)
 . . Set R=^TRANSP("D",VervRef),TranspDate=$$EXTDATE^vhDTyp($P(R,D,10)),GroepNr=""
 . . For  Set GroepNr=$O(BevatGeenVerpakking(GroepNr)) Quit:GroepNr=""  Do
 . . . Set KLNr=$P(^TRANSP("D",VervRef,"D",GroepNr),D),R=^KKL(^KK1(KLNr),0)
 . . . ;Set KLNr=$P(^KU1(GroepNr,"F"),D),R=$G(^KUL(KLNr,"F",3)) Set:'$P(R,D) R=^KKL(^KK1(KLNr),0)
 . . . Set Klanten($O(Klanten(""),-1)+1)=$E($P(R,D,2)_", "_$P(R,D,5)_", "_$P(R,D,7),1,72)
 . . Set Klanten="Klanten",BevatGeenVerpakking=$$^vhTXTPOP("TRANSP","BEVATGEENVERPAKKING","",Transporteur,TranspDate,$S($O(Klanten(""),-1)>1:"en",1:""))
 Quit $D(BevatGeenVerpakking)
 ;