UTILI3 ;UTILI Bepaalde klanten produkten of leveranciers[ 03/16/95  10:59 AM ]
 ;
BEPAALDE(Bestand,SelRef,Sort,Titel,Format,CallBack,RetKeys,Help) 
 Goto COMMAND
 
INIT Set FP=201 Write @F,@F1
 Set Bestand=$E(Bestand,1,2)
 Set RetKeys=";"_$G(RetKeys)_";" Set:$L(RetKeys)=2 RetKeys=";-;"
 Set:'$L($G(Titel)) Titel="UTILI - BEPAALDE"
 Do INIT^PROC("UTILIB"_Bestand,"UTILIB")
 If $L($G(Format)) Set UTILIB(2)=^LD("L",Format),UTILIB(8)=^LD("L",Format,"H")
 Do RESET^vhScherm,ADD^vhScherm(1,24)
 Set Bestand2=$P("Klanten;Produkten;Leveranciers",";",$F("KPL",$E(Bestand))-1)
 Quit
 
REFRESH If sRT=1 Write @F11,@FMTI," ",Titel," - ",QN," ",@FMTi,@F2 Set T="Bepaalde "_Bestand2,FP=180-$L(T)-1 W @F,@FMTB," ",T," ",@FMTb
 If sRB>1,sRT<21 Set DL(2)=sRT,DL(3)=sRB Do WL^PROC Kill DL(2),DL(3)
 If sRB>20 Set FP=2101 Write @F,@F1 Set FP=2401 Write @F,"N=Nieuw, I=Insert, ENTER=Wijzig, V=Verwijder, -=Exit, verder gaan"
 
 Do RESET^vhScherm
 Quit
 
NIEUWKL(Nr) For  Set KLNr=$$SELECT^KLANT6(1) Quit:'KLNr  Do ADD(KLNr,^KK1(KLNr),$G(Nr))
 Quit
NIEUWPR(Nr) For  Set PRNr=$$SELECT^PRODUKT6() Quit:'PRNr  Do ADD(PRNr,$$COMPR^PRODUKT(PRNr),$G(Nr))
 Quit
NIEUWLE(Nr) For  Set LEVNr=$$SELECT^LEVER() Quit:'LEVNr  Do ADD(LEVNr,^KL1(LEVNr),$G(Nr))
 Quit
 
ADD(Ref,Id,Nr)      
 Quit:$D(@SelRef@(Id))      
 Set R=""
 If $L($G(CallBack)) X "S R=$$"_CallBack_"(Ref)"
 If R=-1 Quit
 Set Rec=Id_D_Ref_D_R      
 Do:'Nr NIEUWV^PROC3(Rec)
 Do:Nr INSERTV^PROC3(Rec)
 Set @SelRef@(Id)=Rec
 Do EL^PROC
 Quit
 
DELETE(Nr) 
 Set Id=$P($G(@SelRef@(Nr)),D)
 Quit:'$L(Id)
 Kill @SelRef@(Id)
 Do DELETE^PROC3
 Quit
 
COMMAND New Input,R,DL,IsChanged,%SC
 Do INIT,REFRESH
 Do:$D(@SelRef)'>1 @("NIEUW"_Bestand_"()"),REFRESH
 Set Input=""
 Set IsChanged=0
 For  Quit:$L(Input)&(RetKeys[(";"_Input_";"))  Do
 .Set DL(3)=3
 .Do SL^PROC
 .If R="HELP" Do HELP
 .Set Input=R
 .If Input="ENTER" Do WIJZIG(UTILIB(6))
 .If Input="N"!(Input=$E(Bestand)) Do @("NIEUW"_Bestand_"()")
 .If Input="(" Do SWAP^PROC3("UP")
 .If Input=")" Do SWAP^PROC3("DO")
 .If Input="V" Do DELETE(UTILIB(6))
 .If Input="I" Do @("NIEUW"_Bestand_"(UTILIB(6))")
 .Do REFRESH
 .If "ENTER,N,(,),V,I"[Input Set IsChanged=1
 Quit Input
 
WIJZIG(Nr) 
 Set Rec=@SelRef@(Nr) 
 Set Ref=$P(Rec,D,2)
 Set Id=$P(Rec,D,1)
 Set R=$P(Rec,D,3,99)
 If $L($G(CallBack)) X "S R=$$"_CallBack_"(Ref,R)"
 Set Rec=Id_D_Ref_D_R
 Set @SelRef@(Nr)=Rec
 Set @SelRef@(Id)=Rec
 Do EL^PROC
 Quit
 
FETCHPR New PRNr
 Set PRNr=$P(FL(3),D,2)
 Set:'PRNr PRNr="*"
 For I=0:1:5 Set FL(3,I)=$G(^KPR(PRNr,I))
 For I="I","J" Set FL(3,I)="" Set:$E($O(^(I)))=I FL(3,I)=^($O(^(I)))
 Quit
HELP ; Oproep van Menu en HELP
 Set R=""
 Set:'$L($G(Help)) Help="UTILI3"
 Do POP^MN(Help)
 Set Input=R
 If Input'="HELP" Do REFRESH Quit
 New HLP
 Set HLP(1)=Help
 Set HLP(3)=9
 Do ^HELP
 Do ADD^vhScherm(9,24)
 Quit