VERVID ;BLUM Vervoerlijst selectie ;VERVOER; Do naar PROC [ 03/15/99  2:46 PM ]
 G BEGIN
 ;
T1 ;16;C;L;16;;| \2;C;C;7;;|\3;C;C;10;;|\7;C;C;3;;| ;;$S(X=1:"I",X=2:"F",1:$S($L(X):X,$$BevatFactuur^VERVID(LC,VRF):"+f",1:""))\8;C;L;53;;
T2 ; Identif    |    Datum | V | Paletten
T3 ;Onbekend;;Pakket;Euro-pallet;Blum-pallet;Zak
T4 ; Het vervoerbestand is leeg 
 ;
O1 S K=$P($T(T4),U,2) G OY
OY S FP=2403 W @F,@F1,@FMTI,K,@FMTi,@F0
OZ Q
 ;
 ; Palet
PAL S K="" F I=8:1:12 I $L($P(R,D,I)) S K=K_$P($T(T3),U,$F("PEBS",$P($P(R,D,I),U,1))+2)_"="_$P($P(R,D,I),U,2)_"  ",$P(R,D,I)=""
 S $P(R,D,8)=K
 Q
Select(Multi,SelLC,SoDo,Status)
	New VRF
	Do SELECT($G(Multi),.SelLC,.SoDo,.Status)
	Quit VRF
 ;
 ; Vervoeridentificatie
SELECT(Multi,SelLC,SoDo,Status)
 New Y,X,VNR,FL,ChkDate,RCPNr
 S DL(1)="VID" S (VNR,VRF)=0,ChkDate=""
 Set Multi=$G(Multi)
 Set LC=$G(SelLC)
 Set SoDo=$G(SoDo)
 ; Selecteren van de leverancier
 Do:LC=""  Quit:'LC
 .Set Y=0
 .For  Set LC=$O(^Verv(LC)) Quit:LC=""  Do
 ..Set Y=Y+1,Y(Y)=LC_D_$P($P(^KLE(^KL1(LC),0),D,2)," ")
 .Set LC=$$WILD^vhPOPUP("C;C","KOA2b-","Selecteer Leverancier",.Y)
 .Quit:'LC
 .Set FP=160 Write @F,LC," ",$P($P(^KLE(^KL1(LC),0),D,2)," ")
 ; Tonen van de vervoerlijsten van een bep. leverancier
 Kill Y
 For  Set VRF=$O(^Verv(LC,"D",VRF)) Quit:VRF=""  Do
 .Set R=^(VRF)
 .If $P(R,D,15)="DO",$L($P(R,D,7)),$$INTDATE^vhDTyp($P(R,D,3),"DK")<($H-30) Do  Quit
 ..Kill ^Verv(LC,"D",VRF) ; Verwijder overgeboekt DO's na 30 dagen
 .If $L(SoDo) Quit:SoDo'=$P(R,D,15)
 .If $D(Status) Quit:Status'=$P(R,D,7)
 .Set $P(R,D,3)="("_$P(R,D,3)_")",RCPNr=$P(R,D,16)
 .If RCPNr,$D(^RCP("D",RCPNr)) Set $P(R,D,3)=$$EXTDATE^vhDTyp($P(^RCP("D",RCPNr),D,4))
 .Do PAL Set VNR=VNR+1
 .;Set $P(R,D,2)=$P(R,D,2)_$J($S($P(R,D,15)="DO":"",1:$S($P(R,D,16):" - "_$P(R,D,16),1:"")),9)
 .Set $P(R,D,16)=" - std - "_$P(R,D,16)
 .Set:$P(R,D,15)="DO" Klant=$P(R,D,4),Klant=$P($G(^BLBeri("K",Klant),Klant),D),$P(R,D,16)=Klant
 .Set FL(2)="",FL(1)=$P($T(T1),U,2,999),FL(3)=R Do FL^PROC
 .S Y(VNR)=R_D_VRF
 S Y(0)=VNR
 S:$L(Multi) Y="4\BM\Selecteer een of meerdere vervoerlijsten (- = Exit)\CB^"_$ZN
 S:'$L(Multi) Y="4\B\Selecteer vervoerlijst (- = Exit)"
 Set X=""
 Do ^POP
 Set VRF=""
 Quit:'+X
 For I=1:1:$L(X,";") Set VRF=VRF_";"_$P(Y($P(X,";",I)),D,2)
 Set $E(VRF)=""
 Q
 ;
CB
 New R,VervNr,RCPNr,RCPDate
 If X=""  Set ChkDate=""
 Else  If ";"_X_";"'[(";"_sLD(6)_";")
 Else  Do
 .Set R=Y(sLD(6)),VervNr=$P(R,D,2)
 .Set R=$G(^Verv(LC,"D",VervNr)),RCPNr=$P(R,D,16)
 .Do:RCPNr
 ..Set R=$G(^RCP("D",RCPNr))
 ..Quit:R=""
 ..Set:ChkDate="" ChkDate=$P(R,D,4)
 ..Quit:$$EXTDATE^vhDTyp(ChkDate,"DM4")=$$EXTDATE^vhDTyp($P(R,D,4),"DM4")
 ..Set R=$$^vhTXTPOP("BLCSBFAK","DATUM","",$$EXTDATE^vhDTyp($P(R,D,4)),$$EXTDATE^vhDTyp(ChkDate,"DM4"))
 ..Do DISABLE^POP(sLD(6))
 Quit 
 ;
 ; Bevat een vervoersreferentie facturen?
BevatFactuur(LEVNr,VervRef) 
 New R,LevFANr,Count
 Set LevFANr="",Count=0
 For  Set LevFANr=$O(^Verv(LEVNr,"D",VervRef,LevFANr)) Quit:LevFANr=""  Do
 .Set R=^Verv(LEVNr,"D",VervRef,LevFANr)
 .Set:$P(R,D)="01" Count=Count+1
 Quit Count
 ;
MULTI D SELECT("M") Q
BEGIN D SELECT("")
END Q
 ;