ZBCHKWN ;Nazicht link produkten met order en toeleveringen ;[ 09/02/1999  9:29 AM ]
 ;
 Do
 .New Check
 .Set Q="K"
 .Do ^cA604
 If '$D(Check) Do
 .Quit
 .Xecute F70
 .Write @F80
 Do PR,OD:$G(Check)'=0,TO:$G(Check)'=0
 If '$D(Check) Do
 .Quit
 .Xecute F71
 Quit
 ;
PR ;Quit
 If '$D(Check) Write !!,"*** Produkten ***"
 Set PRNr=0
 For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  Do
 .Set KortTxt=$P(^KPR(PRNr,0),D)
 .Set TotToel=$P(^KPR(PRNr,0),D,17),TotRes=$P(^KPR(PRNr,2),D,9)
 .If $P(TotToel,"#",2)+$P(TotToel,"#",3)'=+TotToel Do
 ..If $D(Check) Set Check=0 Quit
 ..Do KORTTXT
 ..Write !,$ZR,?40,"TotToel = ",TotToel
 .If $P(TotRes,"#",2)+$P(TotRes,"#",3)'=+TotRes Do
 ..If $D(Check) Set Check=0 Quit
 ..Do KORTTXT
 ..Write !,$ZR,?40," TotRes = ",TotRes
 .Set W="W",(Toel,ToelS,ToelK,Res,ResS,ResK)=0
 .For  Set W=$O(^KPR(PRNr,W)) Quit:$E(W)'="W"  Do
 ..Set Rec=^KPR(PRNr,W),Ref=$E(W,18,23),LijnNr=$TR($E(W,24,26)," ","")+100,ZR=$ZR
 ..If $E(W,9)="T" Do
 ...If '$D(^KTO1(Ref)) Do  Quit
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,ZR,?40,"   Toel = onbekend"
 ...Set LEVNr=$P(^KTO1(Ref),D)
 ...If '$D(^KTO(LEVNr,Ref,LijnNr)) Do
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,ZR,?40,"  TLijn = onbekend"
 ...Set Toel=Toel+$P(Rec,D,5),@("Toel"_$P("S\K",D,$P(Rec,D,7)+1))=@("Toel"_$P("S\K",D,$P(Rec,D,7)+1))+$P(Rec,D,5)
 ..If $E(W,9)="R" Do
 ...If '$D(^KO1(Ref)) Do  Quit
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,ZR,?40,"    Ord = onbekend"
 ...If $P(^KO1(Ref,"F"),D,2) Do
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,ZR,?40,"    Ord = uitgeleverd"
 ...Set KLNr=$P(^KO1(Ref,"F"),D)
 ...If '$D(^KOD(KLNr,"F",Ref,LijnNr)) Do  Quit
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,ZR,?40,"  OLijn = onbekend"
 ...Set OrdTyp=$P(^KOD(KLNr,"F",Ref,1),D,25)
 ...Set R=^KOD(KLNr,"F",Ref,LijnNr)
 ...Quit:$P(R,D,14)["S"  Quit:$P(R,D,14)["Z"
 ...Set LevTerm=$P(R,D,25)
 ...If OrdTyp="A",$$INTDATE^vhDTyp(LevTerm,"DW")>$$LEVWK^PRODUKT4(PRNr,KLNr) Quit
 ...Set Res=Res+$P(Rec,D),@("Res"_$P("S\K",D,$P(Rec,D,3)+1))=@("Res"_$P("S\K",D,$P(Rec,D,3)+1))+$P(Rec,D)
 .If Toel'=+TotToel Do
 ..If $D(Check) Set Check=0 Quit
 ..Do KORTTXT
 ..Write !,"^KPR(",PRNr,",0)",?40,"   Toel = ",Toel,?55,+TotToel
 .If ToelS'=+$P(TotToel,"#",2) Do
 ..If $D(Check) Set Check=0 Quit
 ..Do KORTTXT
 ..Write !,"^KPR(",PRNr,",0)",?40,"  ToelS = ",ToelS,?55,+$P(TotToel,"#",2)
 .If ToelK'=+$P(TotToel,"#",3) Do
 ..If $D(Check) Set Check=0 Quit
 ..Do KORTTXT
 ..Write !,"^KPR(",PRNr,",0)",?40,"  ToelK = ",ToelK,?55,+$P(TotToel,"#",3)
 .If Res'=+TotRes Do
 ..If $D(Check) Set Check=0 Quit
 ..Do KORTTXT
 ..Write !,"^KPR(",PRNr,",2)",?40,"    Res = ",Res,?55,+TotRes
 .If ResS'=+$P(TotRes,"#",2) Do
 ..If $D(Check) Set Check=0 Quit
 ..Do KORTTXT
 ..Write !,"^KPR(",PRNr,",2)",?40,"   ResS = ",ResS,?55,+$P(TotRes,"#",2)
 .If ResK'=+$P(TotRes,"#",3) Do
 ..If $D(Check) Set Check=0 Quit
 ..Do KORTTXT
 ..Write !,"^KPR(",PRNr,",2)",?40,"   ResK = ",ResK,?55,+$P(TotRes,"#",3)
 Quit
 ;
OD ;Quit
 If '$D(Check) Write !!,"*** Orders ***"
 Set KLNr=0
 For  Set KLNr=$O(^KOD(KLNr)) Quit:KLNr=""  Do
 .Set ORDNr=""
 .For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:ORDNr=""  Do
 ..Set R=$P(^KOD(KLNr,"F",ORDNr,1),D,2),OrdDat=$$CONVDATE^vhDTyp(R,,"DSN")
 ..Set LijnNr=100
 ..For  Set LijnNr=$O(^KOD(KLNr,"F",ORDNr,LijnNr)) Quit:LijnNr=""  Do
 ...Set R=^KOD(KLNr,"F",ORDNr,LijnNr),PRNr=$P(R,D,2) Quit:'PRNr
 ...Set KortTxt=$P(^KPR(PRNr,0),D)
 ...If '$D(^KPR(PRNr,"W    0.0R"_OrdDat_ORDNr_$J(LijnNr-100,3))) Do  Quit
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,$ZR,"Onbekend"
 ...If $P(^KPR(PRNr,"W    0.0R"_OrdDat_ORDNr_$J(LijnNr-100,3)),D)'=$P(R,D,3) Do
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,$ZR,?45,"Aantal verschillend"
 ...If $P(^KPR(PRNr,"W    0.0R"_OrdDat_ORDNr_$J(LijnNr-100,3)),D,2)'=$P(R,D,25) Do
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,$ZR,?45,"Levert verschillend"
 ...If $P(^KPR(PRNr,"W    0.0R"_OrdDat_ORDNr_$J(LijnNr-100,3)),D,3),'$P(R,D,27) Do
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,$ZR,?45,"Type reservatie verschillend"
 ...If '$P(^KPR(PRNr,"W    0.0R"_OrdDat_ORDNr_$J(LijnNr-100,3)),D,3),$P(R,D,27) Do
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,$ZR,?45,"Type reservatie verschillend"
 Quit
 ;
TO ;Quit
 If '$D(Check) Write !!,"*** Toeleveringen ***"
 Set LEVNr=0
 For  Set LEVNr=$O(^KTO(LEVNr)) Quit:LEVNr=""  Do
 .Set TOENr=""
 .For  Set TOENr=$O(^KTO(LEVNr,TOENr)) Quit:TOENr=""  Do
 ..Set R=$P(^KTO(LEVNr,TOENr,1),D,2),ToeDat=$$CONVDATE^vhDTyp(R,,"DSN")
 ..Set LijnNr=100
 ..For  Set LijnNr=$O(^KTO(LEVNr,TOENr,LijnNr)) Quit:LijnNr=""  Do
 ...Set R=^KTO(LEVNr,TOENr,LijnNr),PRNr=$P(R,D,2) Quit:'PRNr
 ...Set KortTxt=$P(^KPR(PRNr,0),D)
 ...If '$D(^KPR(PRNr,"W    0.0T"_ToeDat_TOENr_$J(LijnNr-100,3))) Do  Quit
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,$ZR,"Onbekend"
 ...If $P(^KPR(PRNr,"W    0.0T"_ToeDat_TOENr_$J(LijnNr-100,3)),D,5)'=$P(R,D,3) Do
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,$ZR,?45,"Aantal verschillend"
 ...If $P(^KPR(PRNr,"W    0.0T"_ToeDat_TOENr_$J(LijnNr-100,3)),D,6)'=$P(R,D,25) Do
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,$ZR,?45,"Levert verschillend"
 ...If $P(^KPR(PRNr,"W    0.0T"_ToeDat_TOENr_$J(LijnNr-100,3)),D,7),'$P(R,D,27) Do
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,$ZR,?45,"Type Toelevering verschillend"
 ...If '$P(^KPR(PRNr,"W    0.0T"_ToeDat_TOENr_$J(LijnNr-100,3)),D,7),$P(R,D,27) Do
 ....If $D(Check) Set Check=0 Quit
 ....Do KORTTXT
 ....Write !,$ZR,?45,"Type Toelevering verschillend"
 Quit
 ;
KORTTXT 
 If $L(KortTxt) Write !!,KortTxt Set KortTxt=""
 Quit
 ;
CHECK() 
 New
 Set Check=1
 Do ZBCHKWN
 Quit Check
 ;