cAB30 ;Beheer menu ;%AB30 [ 12/29/00  12:17 PM ]
 G 1
 ;
T0 ; Beheer menu;
 ;
T0E ; Beheer menu;
 ;
 ;   Bestaande menu's in ^HULP steken
1 N TOOL,QM S $ZT="TRAP^cAN000"
 ;  Vernietigen van alle te gebruiken ^HULP's
11 F TOOL="MENU","MENU.DET" K ^HULP(boot,$J,TOOL)      
 L +@("^"_Q_"BA(""MENU"")"):2 E  D TXT^cAFA1(14) G YZ
13 S TOOL="MENU"
15 S QM=""
17 F  S QM=$O(@("^"_Q_"BA(""MENU"",QM)")) Q:QM=""  D
 . I '$D(^(QM,0)) Q
 . S STRING=^(0)
 . S $P(STRING,D,15)=QM
 . S ^HULP(boot,$J,TOOL,QM)=STRING
 ;  Oproepen van de DMH
19 D BS^cAN210("MENU","DAM","DAM","0","")
 B
 ; 
2 D BEWAAR
 ;  Vernietigen van alle gebruikte ^HULP's
21 F TOOL="MENU","MENU.DET" K ^HULP(boot,$J,TOOL)
 ;
YZ L -@("^"_Q_"BA(""MENU"")") Q
 ;
BEWAAR ;  Terugzetten van de menu-lijnen 
 N QM S $ZT="TRAP^cAN000"
 S TOOL="MENU"
 S QM=""
 F  S QM=$O(^HULP(boot,$J,TOOL,QM)) Q:QM=""  D
 . S STRING=^(QM)
 . S $P(STRING,D,15)="",$P(STRING,D,30)=""
 . S $P(STRING,D,28)="",$P(STRING,D,29)=""
 . F  Q:$E(STRING,$L(STRING))'=D  S STRING=$E(STRING,1,$L(STRING)-1)
 . S @("^"_Q_"BA(""MENU"",QM,0)")=STRING
BEWAARZ Q
 ;
 ;  Oproepen details gekozen menu
DET(QM,TIT) 
 N TOOL,I1,STRING S $ZT="TRAP^cAN000"
 D BEWAAR
 S TOOL="MENU.DET"
 S I1=""
 F  S I1=$O(@("^"_Q_"BA(""MENU"",QM,I1)")) Q:I1=""  D
 . S STRING=^(I1)
 . I I1=0 S $P(STRING,D,15)=QM
 . I I1'=0 S $P(STRING,D,22)=I1
 . I $P(STRING,D,8)="-" S $P(STRING,D,8)=1
 . S ^HULP(boot,$J,TOOL,I1)=STRING
 D BS^cAN210("MENU.DET","DAM","DAM","0","")
 ;  0-Node wegschrijven in ^HULP
 S ^HULP(boot,$J,"MENU",QM)=^HULP(boot,$J,"MENU.DET",0)
 ;  Terugzetten van de detail-lijnen
 S TOOL="MENU.DET"
 S I1=0
 F  S I1=$O(^HULP(boot,$J,TOOL,I1)) Q:I1=""  D
 . S STRING=^(I1)
 . S $P(STRING,D,22)="",$P(STRING,D,30)=""
 . S $P(STRING,D,28)="",$P(STRING,D,29)=""
 . I $P(STRING,D,8)=1 S $P(STRING,D,8)="-"
 . F  Q:$E(STRING,$L(STRING))'=D  S STRING=$E(STRING,1,$L(STRING)-1)
 . S ^HULP(boot,$J,TOOL,I1)=STRING
 ;  Vernietigen van de oude lijnen en terugzetten van de nieuwe lijnen
 S I1=0
 F  S I1=$O(@("^"_Q_"BA(""MENU"",QM,I1)")) Q:I1=""  K ^(I1)
 M @("^"_Q_"BA(""MENU"",QM)")=^HULP(boot,$J,TOOL)
 ;  Vernietigen van de opgezette ^HULP
 K ^HULP(boot,$J,TOOL)
 ;  Heropbouwen van de eerste DMH
 S REFRESH=2
DETZ Q
 ;
R0 S $P(R,D,12)=$T(+0) D ^cAN1000 Q
 ;
 ;  Opzetten van de TOP in de DMH van de details
TOPDET S UTOP(1)="MENU"
 S UTOP(1.1)=QM_" "_TIT
TOPDETZ Q
 ;
 ;  Verwijderen van een menu
V K @("^"_Q_"BA(""MENU"",UI1)")
 Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84