cAFE3 ;Functies ivm EURO : facturatie ; %AFE3 [ 12/21/00  9:50 AM ]
 ;
CNVC(Q,BE,VM,SP)   ; conversie bedrag naar EURO
 ; BE = Bedrag
 ; VM = muntcode
 ; SP = soort par (A=Aankoop/V=Verkoop)
 N BA11,BA11E,R,RP
 S $ZT="TRAP^cAFE1"
 D S1^cAFE1
 I VM="EUR" S R=BE G CNVCZ
 ; indien periode P4 of P5
 I $P(@("^"_Q_"BA(39)"),D,11),DT'<$P(^(39),D,11) S R=$$CNVNC^cAFE1(Q,$$BJ^cAFE1(Q,DJ_"."_DM),BE,VM,SP,2) G CNVCZ
 ; indien periode P1...P3
 S BA11=@("^"_Q_"BA(11,VM)")
 S BA11E=@("^"_Q_"BA(11,""EUR"")")
 S RP=$F("AVF",SP)+2
 S R=BE*$P(BA11,D,RP)/$P(BA11,D,3)     ; naar BEF
 S R=$J(R/$P(BA11E,D,RP),0,2)          ; naar EUR
CNVCZ D S2^cAFE1 Q R
 ;
DCNTRL(R) ; datum-controle afprinten beschrijving EURO
 ; R = datum doc
 Q $$DC^cAFD1(R)>19981231
 ;
S11 ; gebruikt bij het printen via nodes 1100
 ; indien enkel totaal
 I $P(UPM,D,13)=1 D S19($S('$P(U1,D,5):NET,1:TTB)-BTLD*(FC="C"*-2+1),$P(U1,D,18)) Q
 D S19(TTB-BTLD-$G(KKT),$P(U1,D,18))
 Q
 ;
S19(BE,MI) ; gebruikt bij het printen via nodes 1900 in Q_UGL
 S K=$$OMREK^cAFE1(Q,BE,MI,$S($$IDEU(UPM)=2:$$OLD(Q),1:"EUR"),"V","")
 Q
 ;
S198 ; gebruikt bij het printen via nodes 1900 in Q_UGL
 S R=K_D_($P(U8,U,9)-2-3)_D_($P(U8,U,6)+V-3)_D_$$DECVM^cAFE5($S($$IDEU(UPM)=2:$$OLD(Q),1:"EUR")) D ^cA103 W $S($$IDEU(UPM)=2:$$OLD(Q),1:"EUR")
 Q
 ;
INDIC(BE,MI,DAT,UPM)   ; printen indicatief in EURO/BEF
 N R,OMS
 ; bedrag, munt bon, datum bon, "ULNT" of "LNT"
 S R=$$IND^cANR201(BE,$G(MI),$G(DAT),$G(UPM))
 ; truuk special om omschrijving te wijzigen
 I '$D(U8)!$S('$G(U9):1,1:'$D(C(U9))) G INDICZ
 S OMS=$P(U8,U)
 I '$L(R) S OMS=""
 I $L(R) F  Q:OMS'["XXX"  S OMS=$P(OMS,"XXX")_$S($P(R," ",2)="EUR":"euro",1:$P(R," ",2))_$P(OMS,"XXX",2,99)
 S $P(U8,U)=OMS,$P(C(U9),U)=OMS
INDICZ Q R
 ;
INDICB() ; help voor het ophalen van het bedrag
 ; indien enkel totaal
 I $P(UPM,D,13)=1 S R=$S('$P(U1,D,5):NET,1:TTB)-BTLD*(FC="C"*-2+1)      
 E  S R=TTB-BTLD-$G(KKT)  
 Q R
 ;
INDICP(K)          ; help bij het printen van indicatief
 I '$L(K) Q
 S R=$P(K," ")_D_($P(U8,U,9)-2-3)_D_($P(U8,U,6)+V-3)_D_$$DECVM^cAFE5($P(K," ",2)) D ^cA103 W $P(K," ",2)
 Q
 ;
IDEU(UPM) ; gebruikt bij het printen via nodes 1100 in ^BIB(UGL,...
 N OKEUR,MNT
 ; S OKEUR=1 I $P(UPM,D,99)!($P(UPM,D,13)=1)!($P(U1,D,18)="EUR") S OKEUR=0
 S MNT=$P($S(UGB'="FB":U1,1:U6),D,18)
 S OKEUR=0
 ; nooit indicatief afprinten
 I $P(UPM,D,99)=1 G IDEUZ
 ; indien mnt verschillend van BEF en EUR steeds EUR printen
 I MNT'="EUR"&(MNT'="BEF") S OKEUR=1 G IDEUZ
 ; indien nog niet geconverteerd naar EUR : ind. in EUR
 I '$P(UPM,D,99),MNT'="EUR" S OKEUR=1 G IDEUZ
 ; reeds in EUR : eventueel ind. in BEF of EUR
 I $P(UPM,D,99)=2 S OKEUR=1+(MNT'=$$OLD(Q)) G IDEUZ
IDEUZ Q OKEUR
 ;
JN ; vraagstelling met omkering van input
 S R="JN\22\3\Bedrag in euro ?\""[] = neen   1[] = ja   2[] = bedrag indicatief in BEF""\1\\""12-""[K" D R0
 I "1"[K S K='JN
JNZ Q
 ;
OLD(Q) N R
 S R=$P($G(@("^"_Q_"BA(39)")),D,9)
 I '$L(R) S R="BEF"
 Q R
 ;
YZ Q
 ;
R0 S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84