cAFVBC02	; functies historiek calls ; cAFVBC02
	;
T1	;'Tot datum' voor 'Van datum'.;
T2	;Max. 3 maanden tussen 'Van datum' en 'Tot datum'.;
	;
T1E	;'Till Date' before 'From Date'.;
T2E	;Max. 3 months between 'From Delivery' and 'Till Delivery'.;
	;
YZ	Q
	;
BTEMP(GRIDID,DMS,TYPE,KEUID,VANDT,TOTDT)	
	; INPUT:
	;   GRIDID    : volgnr van de grid : indien "" : volgnummer ophalen
	;   TYPE      : 0 = zowel calls en taken
	;               1 = enkel calls
	;               2 = enkel taken
	;   KEUID:    Ofwel: GridId van de ^mtemp99 met geselecteerde UI1's
	;             Ofwel: Geselecteerd ID (begint met $$)
	;   VANDT     : van datum
	;   TOTDT     : tot datum
	;   DMS       : CALL.KL
	;               CALL.LE
	;               CALL.NP
	;   
	; OUTPUT:
	;   0\foutboodschap
	;   GRIDID
	;   
BTEMPA	S $ZT="ERR^cAFVBF01"
	N @$$INITVAR^cAFVBA01("GRIDID,TYPE,KEUID,VANDT,TOTDT,DMS")
	F i="GRIDID","TYPE","UI1KL","VANDT","TOTDT","DMS" S @i=$G(@i)
	I '$L(GRIDID) S GRIDID=$$GRIDID^cAFVBF01()
	K ^mtemp99(GRIDID,"COMMON")
	S OK=GRIDID
	; voor VB.TEMP bestaat er geen Q(49), de Q(49) moet zelf opgezet worden
	K oQ m oQ=Q
	K Q(49)
	S Q(49)=$$Q49^cAFVBA03(Q,DMS) 
	;
	I VANDT'?2N1"."2N1"."2N,VANDT'?2N1"."2N1"."4N S VANDT=$$HD^cAFD1(VANDT)
	S VANDT=$$DC^cAFD1(VANDT)
	I '$L($G(TOTDT)) S TOTDT=+$H
	I TOTDT'?2N1"."2N1"."2N,TOTDT'?2N1"."2N1"."4N S TOTDT=$$HD^cAFD1(TOTDT)
	S TOTDT=$$DC^cAFD1(TOTDT)
	;
	S REF=$$REPL^cAFA10($P($$REF^cAFA10(.Q,DMS),D),",UI1",",$P(UI1,"" "")")           ; databestand van de call
	S REFHIS=$P($$REF^cAFA10(.Q,DMS_".HIS"),D) ; databestand van de historiek
	S IREF=$P($$REF^cAFA10(.Q,DMS,102),D,3)  ; indexbestand op klant, leverancier of prospect
	;
	I $E(KEUID,1,2)="$$" S I1=$P(KEUID,"$$",2)  S (I2,KEUID)="" G BTEMPC2
	I $L(KEUID),'$D(^mtemp99(KEUID,"COMMON")) S I1="" G BTEMPD
	;
	; geen klant, leverancier of prospect doorgegeven
BTEMPB	I '$L(KEUID) G BTEMPD
	;
	; doorlopen grid met geselecteerde klanten, leveranciers of prospecten
BTEMPC	S I1=""
BTEMPC1	I $L(KEUID) S I1=$O(^mtemp99(KEUID,"COMMON",I1)) G:I1="" BTEMPZ 
	;
	; klant,leverancier of prospect doorgegeven : index doorlopen
	S I2=""
BTEMPC2	S I2=$O(@IREF@(I1,I2)) I '$L(I2) G:'$L(KEUID) BTEMPZ G BTEMPC1
	S CALLID=^(I2)
	S UI1=CALLID_" "     ; historieken ophalen
BTEMPC3	S UI1=$O(@REFHIS) G:$P(UI1," ")'=CALLID BTEMPC2
	S DATHIS=$P(^(UI1,0),D,2)
	I $$DC^cAFD1(DATHIS)<VANDT G BTEMPC3
	I $$DC^cAFD1(DATHIS)>TOTDT G BTEMPC3
	D FILL(GRIDID,REF,REFHIS,UI1,TYPE)
	G BTEMPC3
	;
BTEMPD	; geen ids doorgegeven : index op datum van de historiek doorlopen
	S IREF=$P($$REF^cAFA10(.Q,DMS_".HIS",102),D,3)  ; indexbestand op klant, leverancier of prospect
	S I1=VANDT-1
	F  S I1=$O(@IREF@(I1)) Q:I1>TOTDT!'$L(I1)  D
	. S I2=""
	. F  S I2=$O(@IREF@(I1,I2)) Q:'$L(I2)  D 
	.. D FILL(GRIDID,REF,REFHIS,I2,TYPE) 
	;
BTEMPZ	K Q M Q=oQ Q GRIDID
	;
FILL(GRIDID,REF,REFHIS,UI1,TYPE)	
	N VNR,I1
	S $ZT="TRAP^cAN000"
	;
	I $P(@REFHIS@(0),D,6)=2 G FILLZ       ; Aard
	; Op de basis bestaat er geen node 1 om onderscheid te maken tussen call of taak
	I $D(@REF@(1)),'TYPE,'$P(^(1),D,15),'$P(^(1),D,16) G FILLZ     ; Call en taak
	I $D(^(1)),TYPE=1,'$P(^(1),D,15) G FILLZ     ; Al of niet call
	I $D(^(1)),TYPE=2,'$P(^(1),D,16) G FILLZ     ; Al of niet taak
	;
	S VNR=1000
	S I1=0
	F  S I1=$O(@REFHIS@(I1)) Q:'$L(I1)  D
	. I '$L($TR($P(^(I1),D,2)," ")) Q  ; blanco lijnen niet meenemen
	. S ^mtemp99(GRIDID,"COMMON",UI1_" "_VNR,2)=$P(^(I1),D,2)
	. S ^mtemp99(GRIDID,"COMMON",UI1_" "_VNR,0)=$P(UI1," ")
	. S ^mtemp99(GRIDID,"COMMON",UI1_" "_VNR,1)=UI1
	. S VNR=VNR+1
FILLZ	Q
	;
VANDT()	
	; defaultwaarde Van Datum
	; output dagdatum - 3 maand in formaat dd.mm.jj
	S $ZT="^dmERROR"
	S D="\",U=";" D ^cA106
VANDTZ	Q $$PAST^cAFD1(DT,"3M")
	
	;
VANTOT(VANDT,TOTDT)	
	; validatie Van datum en Tot datum
	; input VANDT en TOTDT in $H of dd.mm.jj formaat
	; output OK=1 of OK=0\foutboodschap
	S $ZT="^dmERROR"
	N @$$INITVAR^cAFVBA01("VANDT,TOTDT")
	;
	S OK=1 I VANDT?2N1"."2N1"."2N S VANDT=$$DH^cAFD1(VANDT)
	I VANDT>+$H,'$L($G(TOTDT)) G VANTOTZ
	S:'$L($G(TOTDT)) TOTDT=+$H
	I TOTDT?2N1"."2N1"."2N S TOTDT=$$DH^cAFD1(TOTDT)
	I TOTDT<VANDT S OK=0_D_$P($T(@("T1"_QT)),U,2) Q OK
	S R=$$HD^cAFD1(VANDT)_"\3M" D ^cA104 S DATELIM=$$DH^cAFD1(R)
	I TOTDT>DATELIM S OK=0_D_$P($T(@("T2"_QT)),U,2)
VANTOTZ	Q OK
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09