cI30 ;VJ;GLOBAL EDITOR [ 07/27/00  12:39 PM ]
 ;COPYRIGHT DATA-M N.V.
 I $ZV'["MSM" G ^cQI30 ; aangepaste versie voor Caché
 S $ZT="ERROR^cI30"
 D X^cA612 S %PR=$I
 W !?10,"Full Screen Global Editor Utility"
 I $ZV'["MSM" G EXIT
 S (%GSREF,%G1)=1
GL1 S $ZT="ERROR^cI30"
 S %RSC="" U 0 D INT^cGSEL,0^cGPROC G:'$D(%GN) EXIT S %GSREF=1
GL5 S %R=$I,(%SC,$Y,%I30)=0 K ^ZUT($I) W !
 S %GPR="FILE^cI30",%GUD="UNDEF^cI30",%GNV="NOVAL^cI30",%GBR="DUM^cGPROC"
 S $ZT="ERROR1^cI30" D 1^cGPROC
 S $Y=0 G GL1:'$D(^ZUT($I)),EDIT
 ;
FILE S %GX=@%GV I %GX?.E1C.E D CC
 I $L(%GX)<510 S ^ZUT($I,%I30)="~"_%GT,^(%I30+1)=%GX,%I30=%I30+2 W "." Q
 E  W !,%GT,"=""",%GX,""" is te lang !",$C(7),! H 1 Q
 ;
CC ; handle control characters
 S %TEMP="" F %I=1:1:$L(%GX) S:$E(%GX,%I)'?1C %TEMP=%TEMP_$E(%GX,%I) I $E(%GX,%I)?1C S %TEMP=%TEMP_"["_$E($A(%GX,%I)+1000,2,4)_"]"
 S %GX=%TEMP K %TEMP Q
 ;
EDIT D ^cA338 ;I $ZV["MSM" S %K=128 D INT^cPARTSIZ
 S X="ZR  X X1 ZL @P X ^cE D MASTER^cQ5 S Y1=^HULP(boot,$J,""Y1"") X Y1,Y2 ZR  ZS @P K ^HULP(boot,$J)"
 S X1="S LN="""",L=P_"" ;"" ZI L X X2 ZS @P"
 S X2="F  S LN=$O(^ZUT($I,LN)) Q:'$L(LN)  S L="" ;""_^(LN) ZI L"
 ;
 S Y1="F I=""P"",""Y2"",""Y3"",""Y4"" S @I=^(I)"
 S Y2="W !,""."" ZL @P K ^ZUT($I) S ^($I,0)=$P($T(+2),"";"",2,999) X Y3"
 S Y3="F I=3:1 S L=$T(+I) Q:'$L(L)  X Y4 S ^(I-2)=$P(L,"";"",2,999) W ""."""
 S Y4="S J=0 F  S J=$F(L,""["",J) Q:'J  I $E(L,J,J+2)?3N,$E(L,J+3)=""]"" S L=$E(L,1,J-2)_$C(+$E(L,J,J+2))_$E(L,J+4,$L(L))"
 D MASTER^cQ5 S P="Z"_$I,^HULP(boot,$J,"P")=P,^("Y1")=Y1,^("Y2")=Y2,^("Y3")=Y3,^("Y4")=Y4
 ;
 X X I $ZV["MSM" S %K=^|"MGR"|SYS(0,"PSIZE")\1024 D INT^cPARTSIZ:%K
 D ^cA339
 ;
 S (A,B,I)="" 
NEXT S I=$O(^ZUT($I,I)) I $L(I) S A=^(I) G NEXT:"~^"'[$E(A)!'$L(A)
 I $L(I) S I=$O(^(I)) I $L(I) S B=^(I) D  G NEXT
 . I $E(A)'="~" D KILL Q
 . S A=$E(A,2,999) S K="" F %I=1:1:$L(B) S:$E(B,%I)'?1C K=K_$E(B,%I) I $E(B,%I)?1C S K=K_"["_$E($A(B,%I)+1000,2,4)_"]"
 . W !,A,"=""",K,"""" S @A=B
 K A,B,I W ! G cI30
 ;
KILL I '($D(@A)\10) K @A W !,A," gekilled." Q
 E  W !,A," zou beter niet gekilled worden.",$C(7) H 1 Q
 ;
EXIT I $D(%R),%R,%R'=$I C %R
 K %GN,%G1,%GPR,%GPRQ,%GSN,%PR,%GUD,%GNV,%GBR,%R,%SC,%RSC,%GX,%I
 K %I30 B 1 D W^cA612
 Q
 ;
UNDEF W !,"...Subnode of global is undefined." Q
NOVAL W !,"...Subnode of global has no value." Q
ERROR1 U 0
 I $F($ZE,"<PROT >") W !!,"...Protected." G GL1
 I $F($ZE,"<INTERRUPT>") W !!,"...Aborted." G GL1
 ZQ
ERROR ;
 I $F($ZE,"<INTERRUPT>") U 0 W !!,"...Aborted." D EXIT ; V 0:$J:$ZB($V(0,$J,2),#0400,7):2
 ZQ
 ;
ZZ ; 29.08.00 - 16 u 38 * V7.41