cICHKA(S) ;AUTOMATISCH COPIEREN BESTANDEN ;%ICHKA; [ 02/04/98  11:54 AM ]
 ;
T0 ;Automatisch copieren bestanden ;
 ;
T0F ;Copie automatique des fichiers ;
 ;
1 S $ZT="^cA406",D="\",%LOG="^cLOG(boot,""CHANGE"",""G"",S)"
 S LOG="^|home|ZZLOG(""CHANGE"",""G"",S)"
 S LOGC="^|home|ZZLOG(""GCOPY"",""G"",S)"
 ;
 S UCS=$ZU(5) D MASTER^cQ5,IN^cQMSMSW("MGR,"_boot)
 S home=$G(@%LOG@(0,"HOME")) G YZ:'$L(home) S sys=$G(@%LOG@(0,"SYS"))
 I $L(sys) S:$E(sys)'=D sys=D_sys S:$E(sys,$L(sys))'=D sys=sys_D S sys=D_boot_sys
 S cys=$G(@%LOG@(0,"CLIENT"))
 I $L(cys) S:$E(cys)'=D cys=D_cys S:$E(cys,$L(cys))'=D cys=cys_D
 L +@LOG@(0,UCS):15 E  G YZ
 D ^cA105,^cA106 S G=0,@LOG@(0,UCS)=DT_D_TD_D
 ;
 F  S G=$O(@%LOG@(G)) Q:G=""  D
 . S N=@%LOG@(G) S:$E(G)'="^" G="^"_G
 . S %T=$$CHECK(G,N),%L=$E(%T_D_%1_D,1,253),NEW=0
 . I '$D(@LOG@(G,UCS))#10 S @LOG@(G,UCS)=%L,NEW=1
 . S %LO=@LOG@(G,UCS) I NEW!(%L'=%LO) D
 .. S @LOGC@(G,0,0)=DT_D_TD,@LOG@(G,UCS)=%L
 ;
 K SYS D ^cQDDPCIR(.SYS,1)
 S SYS="" F  S SYS=$O(SYS(SYS)) Q:SYS=""  S K=$P(SYS(SYS),D,2) I $P(K,",")="Dis"!($P(K,",",2)="Unr") K SYS(SYS)
 S SYS="" F  S SYS=$O(SYS(SYS)) Q:SYS=""  D
 . I $L(sys),sys'[(D_SYS_D) Q
 . S K=$P(SYS(SYS),D,5) F I=1:1:$L(K,",") S TU("MGR,"_$P(K,",",I))=SYS
 I $L(cys) F I=2:1:$L(cys,D)-1 D
 . I '$D(TU("MGR,"_boot)) S TU("MGR,"_boot)=$P(cys,D,I)
 . E  S TU("MGR,"_boot)=TU("MGR,"_boot)_D_$P(cys,D,I)
 . I boot=master,master'=slave D
 .. I '$D(TU("MGR,"_slave)) S TU("MGR,"_slave)=$P(cys,D,I)
 .. E  S TU("MGR,"_slave)=TU("MGR,"_slave)_D_$P(cys,D,I)
 ;
 S G=0
 F  S G=$O(@LOGC@(G)) Q:G=""  D
 . S TU="",T=$G(@LOGC@(G,0,0)) S:'$L(T) T=DT_D_TD
 . F  S TU=$O(TU(TU)) Q:TU=""  D
 .. F I=1:1:$L(TU(TU),D) S TUI=$P(TU(TU),D,I) I $G(@LOGC@(G,TU,TUI))'=T D
 ... I G["^SYS",TUI'=$P(TU,",",2)!(TU=$ZU(5)) Q
 ... I G'["^SYS",TU=$ZU(5),TUI=boot Q
 ... S NA=@%LOG@(G),$ZT="ERRT",(GF,GT)=G
 ... I G["boot" D
 .... S GF=$P(G,"boot",1)_""""_$P($ZU(5),",",2)_""""_$P(G,"boot",2,$L(G,"boot"))
 .... S GT=$P(G,"boot",1)_""""_TUI_""""_$P(G,"boot",2,$L(G,"boot"))
 ... S GX=GF S:$E(GT)="^" GT=$E(GT,2,$L(GT))
 ... F  S GX=$Q(@GX) Q:GX=""  Q:$NA(@GX,NA)'=$NA(@GF,NA)  D
 .... I GF["^SYS(0,""DDB""",$P(@GX,",")'="LATP" Q
 .... S @("^|TU|"_$E(GT,1,$L(GT)-1)_$E(GX,$L(GT)+1,$L(GX)))=@GX
 ... S @LOGC@(G,TU,TUI)=T
 ;
 S G=0
 F  S G=$O(@LOGC@(G)) Q:G=""  S TU=0 D
 . F  S TU=$O(@LOGC@(G,TU)) Q:TU=""  I '$D(TU(TU)),'$L($G(@%LOG@(0,"FILE",$P(TU,",",2)))) K @LOGC@(G,TU)
 ;
 D ^cA105,^cA106 S $P(@LOG@(0,UCS),D,3)=DT,$P(@LOG@(0,UCS),D,4)=TD
 L -@LOG@(0,UCS):1
 ;
YZ D IN^cQMSMSW(UCS) Q
 ;
CHECK(%GN,%N) S (%T,%1)=0 S:$E(%GN)'="^" %GN="^"_%GN S (%GN,%GO)=$NA(@%GN)
 I $D(@%GN)=1 S %T=%T+$$CRC(%GN),%1=1
 F %1=%1:1 S %GN=$Q(@%GN) Q:%GN=""  Q:$NA(@%GN,%N)'=%GO  S %T=%T+$$CRC(%GN)
 Q %T
 ;
CRC(%GR) S %GD=@%GR
 I $E(%GR,2)="[" S %GR="^"_$P(%GR,"]",2,$L(%GR,"]"))
 I $E(%GR,2)="|" S %GR="^"_$P(%GR,"|",3,$L(%GR,"|"))
 S %X=$ZCRC(%GR,1)+$ZCRC(%GD,1)
 Q %X
 ;
ERRT S @LOGC@(G,TU,TUI)=DT_D_TD_D_$ZE
 Q
 ;
ZZ ; 04.02.98 - 16 u 38 * V6.5.01