cQLBUV ;Controle Backup ;cQLBUV; [ 06/22/01  1:40 PM ]
 ;
T0 ;Controle Backup ;
T1 ;Backup succesvol! Beëindigd: ;
T2 ;Geen backup-logfile gevonden!;
T3 ;Geen backup gestart op vorige werkdag!;
T4 ;Backup heeft abnormale duur: ;
 ;
T0F ;Contrôle copide de sauvegarde ;
T1F ;Copie de sauvegarde succedé! Fini: ;
T2F ;Pas de journal de copie de sauvegarde trouvé!;
T3F ;Pas de copie de sauvegarde le jour avant!;
T4F ;Copie de sauvegarde a une durée abnormale: ;
 ;
1 D INI^cQ6 S QU="SU" D MASTER^cQ5 I workst!client G YZ
 S SUCCES=$G(SUCCES,1)
 ;
2 S LOGB="^cLOG(cs,""BACKUP"",""LOGBOEK"",TYPE)",TYPE="",ERR=0
 F  S TYPE=$O(^cLOG(0,"BACKUP","TYPE",TYPE)) Q:TYPE=""  S TYPEN=$G(^(TYPE)) I $D(@LOGB)#11 D
 . S LBU="",(LBUHD,LBUHT)=0,NOW="\\"_$TR($ZD($H,4),"/",".")_"\"_$ZT($H,2)_"\\",NOWHD=+$H,NOWHT=$P($H,",",2)
 . S K=$O(@LOGB@("@"),-1) I K'="" S L=$O(@LOGB@(K,"@"),-1) I L'="" S LBU=^(L),LBUHD=K,LBUHT=L
 . S R=0,LBUD=$P(LBU,D,3),LBUT=$P(LBU,D,4),LBUTI=$P(LBU,D,6) D AVER
 . I SUCCES,$L(LBU) S ERR=0,R=R+1,R(R)=TYPEN_" "_$P($T(@("T1"_QT)),";",2)_$G(LBUD)_" @ "_$G(LBUT)_" # "_LBUTI_" min."
 . I 'SUCCES D
 .. ;geen logboek?
 .. I LBUHD=0!(LBUHT=0) S ERR=1,R=R+1,R(R)=$P($T(@("T2"_QT)),";",2) Q
 .. ;niet vandaag en niet vorige werkdag?
 .. I '(LBUHD#7=($H#7))+(LBUHD#7=$TR($H#7,"0123456","6011145")) S ERR=2,R=R+1,R(R)=$P($T(@("T3"_QT)),";",2) Q
 .. ;duur?
 .. I LBUTI<(100-DELTA/100*AVER)!(LBUTI>(100+DELTA/100*AVER)) S ERR=3,R=R+1,R(R)=$P($T(@("T4"_QT)),";",2)_LBUTI_" min. ("_AVER_" min.)"
 ;
6 S PG=$T(+0),PN=$P($T(@("T0"_QT)),";",2)
 I SUCCES,'ERR D D1013^cANEM0(PG,PN,.R)
 I 'SUCCES,ERR D D1014^cANEM0(PG,PN,.R)
 ;
YZ Q
 ;
AVER N AL,I,J S AVER=0,DELTA=20,(AL,I)=0
 F  S I=$O(^cLOG(cs,"BACKUP","LOGBOEK",TYPE,I)) Q:I=""  S J=0 D
 . F  S J=$O(^cLOG(cs,"BACKUP","LOGBOEK",TYPE,I,J)) Q:J=""  S K=^(J) I $E(K)="B" S AVER=AVER+$P(K,D,6),AL=AL+1
 I AVER S AVER=AVER\AL
 I 'AVER S AVER=+$P($G(^cLOG(cs,"BACKUP","TIME",TYPE)),D,3)
AVERZ Q
 ;
ZZ ; 24.08.01 -  9 u 19 * Cache-r3.1.8