cT00A ;Algemene functies boekhouding ;%T00A ; [ 07/26/01  2:15 PM ]
 G YZ
 ;
T0 ;Algemene functies boekhouding ;
 ;
T0F ;Functions générales comptabilité ;
 ;
T0E ;General functions accounting ;
 ;
 ; ====================================================================
S1 S RZR=$ZR           ; onthouden last reference
S1Z Q
 ;
S2 I $O(@RZR)          ; terugzetten last reference
S2Z Q
 ;
 ; ====================================================================
 ; controle op IC-verkoopfactuur (0=neen <> 1=ja)
 ; condities: 1. eigen BTW-nummer
 ;            2. BTW-bedrag=0
 ;            3. aantal BTW-codes=1 (+ eventueel Z.B.)
 ;            4. BTW-code=0%
 ;            5. klant met IC-BTW-nummer
ICVE(Q,BP,FNR) 
 S $ZT="TRAP^cAN000" N RZR D S1
 N R,A,BA39,BTW,H,I,KC,V11
 S R=0
 I $G(Q)="" G ICVEZ
 I $G(BP)="" G ICVEZ
 I $G(FNR)="" G ICVEZ
 I '$D(@("^"_Q_"VE")@(BP,FNR)) G ICVEZ
 S H=^(FNR),KC=$P(H,D,4),BTW=$P(H,D,8),V11=$P(H,D,11)
 I $L($P(H,D,36)) G ICVEZ        ; ander BTW-nummer
 I BTW G ICVEZ                   ; BTW-bedrag
 I '$D(PBTW) N PBTW,PTXT D S1^cA305
 S A=0 F I=1:3 S H=$P(V11,"#",I) Q:H=""  I $G(PBTW(H))'="Z.B." S A=A+1
 I A>1 G ICVEZ                   ; meerdere BTW-codes
 S H=$P(V11,"#") I H="" G ICVEZ  ; geen BTW-code
 I $G(PBTW(H))'="0%" G ICVEZ     ; andere BTW-code
 S H=$$SG^cAFA1("KL",KC,116),BA39=@("^"_Q_"BA(39)")
 I $L(H) S H=$E(H,1,2) I H?2U,$D(^BA(5,H)),H'=$P(BA39,D,4) S R=1
ICVEZ D S2 Q R
 ;         
YZ Q
 ;
ZZ ; 06.08.01 - 17 u 28 * V7.87