cT52 ;EINDBALANS ;%T52 ; [ 01/03/01  11:21 AM ]
 G YZ
 ;
T0 ;Eindbalans ;
T1 ;Welke ;
T2 ;"[] = enkel deze met bedragen   .[] = allemaal";
T3 ;Enkel ; met bedragen;alle ;
T4 ;Boekjaar\"jjjj[] = bepaald boekjaar";
T5 ;Informatie\"[] = op het scherm   .[] = op de printer";
T6 ; Nummer\ Naam\Eindsaldo ;2;
T7 ; Overdracht; Eindtotaal ;
 ;
T0F ;Bilan de l'année passée ;
T1F ;Quels ;
T2F ;"[] = suelement ceux avec montants   .[] = tous";
T3F ;Seulement ; avec montants;tous ;
T4F ;Année comptable\"aaaa[] = année spécifique";
T5F ;Info\"[] = à l'écran   .[] = sur l'imprimante";
T6F ; Numéro\ Nom\Solde final ;2;
T7F ; Transfert; Total final ;
 ;
T0E ;Final balance ;
T1E ;Which ;
T2E ;"[] = only those with amounts   .[] = all";
T3E ;Only ; with amounts;all ;
T4E ;Fiscal year\"yyyy[] = particular fiscal year";
T5E ;Information\"[] = on screen   .[] = on printer";
T6E ; Number\ Name\Final balance ;2;
T7E ; Transfer  ; Final total  ;
 ;
AR S Q1="AR" G 1
KL S Q1="KL" G 1
LE S Q1="LE" G 1
 ;
1 D DMS^cAN000("UQC","USC",Q1) G YZ:UQC=""!(USC="")
11 S OM=$P(^DMC(UQC,USC,"TAAL",$E(QT_"N")),D,2) I 'QP S SWA=PP(1),BJ=PP(2) G 5
13 S FP=202 W @F11,@F1,@F,@F4,$P($T(@("T0"_QT)),U,2),OM," ",QN," ",@F5,@F1
 ;
 ; bijkomende selektie
2 S R="K\22\3\"_$P($T(@("T1"_QT)),U,2)_OM_D_$P($T(@("T2"_QT)),U,2)_"\1\\""-,.""[K" D R0 G YZ:K="-"!(K=",") S SWA=$L(K)
21 S FP=403 W @F,@F1
23 I 'SWA W $P($T(@("T3"_QT)),U,2),OM,$P($T(@("T3"_QT)),U,3)
25 I SWA W $P($T(@("T3"_QT)),U,4),OM
 ;
 ; boekjaar
3 D ^cT489
31 S R="BJ\22\3\"_$P($T(@("T4"_QT)),U,2)_"\4\\K?4N&(K'<J1)&(K'>J4)!(K=""-"")!(K="","")\\\\\1" D R0 G 2:K="-"!(K=","),31:'K
33 S FP=603 W @F,@F1,$P($P($T(@("T4"_QT)),U,2),D)," : ",BJ
 ;
 ; smal papier / scherm
4 S R="K\22\3\"_$P($T(@("T5"_QT)),U,2)_"\1\\""-,.""[K" D R0 G 31:K="-",2:K="," I '$L(K) S PTS=1 G 5
41 S R=0 D ^cA345 G 4:K="-",2:K=","
43 I K="." S PP(1)=SWA,PP(2)=BJ,QPT=Q1_"^"_$T(+0) D ^cA109 G YZ
 ;
 ; drukken listing
5 S HD(1)=D,HD(2)=D_$P($T(@("T0"_QT)),U,2)_OM_";C",HD(3)=D_$P($P($T(@("T4"_QT)),U,2),D)_" "_BJ_";C"
51 S TAB="11\62\79",TIT(1)=$P($T(@("T6"_QT)),U,2,99),AFS(1,2)=$P($T(@("T7"_QT)),U,2)
 ;
6 S I1=0 F  S I1=$O(@("^"_Q_Q1_"(I1)")) Q:I1=""  I $D(^(I1,0)) S B(1)=^(0) D
 . I Q1="AR",$P(B(1),D,13)=1 Q      ; geen tekstrekeningen
 . S DC=$G(^(BJ)),CC=$G(^(BJ+.02)),TXT(3)=$P(DC,D)
 . F I=2:1:24 S TXT(3)=TXT(3)+$P(DC,D,I)-$P(CC,D,I)
 . I TXT(3)!SWA D
 .. S TXT(1)=$P(B(1),D)_D_1_D_D_1,TXT(2)=$P(B(1),D,2)_D_D_1_D_1
 .. S TXT(3)=TXT(3)_D_D_D_D_1_D_QD_D_D_1
 .. I Q1="AR" S I=$P(B(1),D),TXT(1)=$E(I,1,3) S:$L(I)>3 TXT(1)=TXT(1)_"."_$E(I,4,9) S TXT(1)=TXT(1)_D_D_1
 .. D ^cA334
61 S AFS(1,2)=$P($T(@("T7"_QT)),U,3)_OM,END=1 D ^cA334
 ;
YZ Q
 ;
R0 S R0=$P(R,D,5) I $L(R0),R0'["""" S $P(R,D,5)=R0_"^"_$T(+0)
R0A S R0=$P(R,D,7) I $L(R0),R0'="DCTR" S $P(R,D,7)="",R1=$P(R,D,8),R0=$P($T(@R0),U,2,99) S:$L(R1) R0=R0_"&("_R1_")" S $P(R,D,8)=R0
R0Z S $P(R,D,12)=$T(+0) K R0,R1 D ^cA100 Q  ; v11 30.05.94
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84