cT58 ;BEHEER UITSPLITSING AANKOOPFAKT. & C.N. ;%T58 ; [ 01/03/01  7:34 PM ]
 G 1
 ;
T0 ;Beheer uitsplitsing netto-bedrag inkomende doc. ;
T1 ;Nr. document;"-[] = einde programma";
T2 ;Leverancier;
T3 ;Totaal bedrag;
T4 ;Totaal netto;
T5 ;Korting contant;
T6 ;Totaal maatstaf;
T7 ;Netto        Maatstaf;
T8 ;Goederen;Diensten;Investeringen;Andere;
T9 ;bedrag in ;Maatstaf ;Netto ;
T10 ;Document niet teruggevonden in het aankoopdagboek ;
T11 ;Bevestiging\".[] = ok   ,[] = hernemen";
T12 ;Uitsplitsing netto's klopt niet ;
T13 ;Boekingsmaand ; is reeds afgesloten ;
 ;
T0F ;Gestion répartition montant net doc. d'entrée ;
T1F ;N° du document;"-[] = fin du programme";
T2F ;Fournisseur;
T3F ;Montant total;
T4F ;Montant net;
T5F ;Esc. au comptant;
T6F ;Base taxable tot.;
T7F ;Net          Mesure;
T8F ;Marchandises;Services;Investissements;Autres;
T9F ;montant en ;Base ;Net ;
T10F ;Ce n° de document ne se trouve pas dans le facturier d'achat ;
T11F ;Confirmation\".[] = ok   ,[] = reprendre";
T12F ;Répartition des montants nets incorrecte ;
T13F ;Mois comptable ; est déjà clôturé ;
 ;
T0E ;Categorization net amount incoming doc. ;
T1E ;Document nr;"-[] = end program";
T2E ;Supplier;
T3E ;Total amount;
T4E ;Total net;
T5E ;In cash discount;
T6E ;Total VAT basis;
T7E ;Net         VAT basis;
T8E ;Goods;Services;Investments;Other;
T9E ;amount in ;VAT basis ;Net ;
T10E ;Document not found in the purchase journal ;
T11E ;Confirmation\".[] = ok   ,[] = retry";
T12E ;Categorization net amounts is not correct ;
T13E ;Fiscal month  ; has already been closed   ;
 ;
S1 S FP=I-1\2+13*100+23+(I-1#2*13) W @F,$J("",10) I X(I) W @F,$J($S(X(I)<0:-X(I),1:X(I)),10,DEC) I X(I)<0 W "-"
S1Z Q
 ;
S2 S S1=0,S2="NETG"
S2A F S3=1:1:4 S S4=$P("NETG\NETD\NETI\NETA",D,S3) I @S4>S1 S S1=@S4,S2=S4
S2B S @S2=@S2+VNET
S2Z K S1,S2,S3,S4 Q
 ;
1 S K=$P($T(@("T0"_QT)),U,2)_QN_" ",FP=203+$L(K) W @F61,@F11,@F1,@F,@F5 S FP=202 W @F,@F4,K,@F5
11 F I=1:1:6 S FP=I+3*100+2 W @F,@F6,$P($T(@("T"_I_QT)),U,2),@F9 S FP=FP+19 W @F,":"
13 S FP=1123 W @F,$P($T(@("T7"_QT)),U,2),! F I=2:1:5 W !?2,$P($T(@("T8"_QT)),U,I)
15 S RH="1203#1245",RV="1121#1621\1134#1634" D ^cA319
17 S BF=$P(@("^"_Q_"BA(39)"),D),VM(BF)=QD,BPA=^(7) S:$G(^(7,0))>BPA BPA=^(0) I BPA<1993 S BPA=1993
 ;
2 S BP="",R="FNR\22\3\"_$P($T(@("T1"_QT)),U,2)_D_$P($T(@("T1"_QT)),U,3)_"\6\\K=""-""!(K?6N)" D R0 G YZ:K="-"
21 S BP=$O(@("^"_Q_"AA(BP)")) I BP="" S K=$P($T(@("T10"_QT)),U,2) D F1 G 2
23 G 21:'$D(^(BP,FNR)) S N=^(FNR),FP=423 W @F,$P(N,D)," ",FNR,@F2
25 S KC=$P(N,D,4),KN=$P(N,D,5) I $D(@("^"_Q_"L1(KC)")),$D(@("^"_Q_"LE(^(KC),0)")) S KN=$P(^(0),D,2)
27 S FP=523 W @F,KC," ",KN,@F2 S FP=623 W @F,@F2 S VM=$P(N,D,24) S:VM="" VM=BF
29 I '$D(VM(VM)) S VM(VM)=2 I $D(@("^"_Q_"BA(11,VM)")) S VM(VM)=+$P(^(VM),D,7)
 ;
3 S DEC=VM(VM),I=$P(N,D,25),PAR=$P(N,D,26) S:'$L(I) I=$P(N,D,6),VM=BF,DEC=QD,PAR=1 W $J(I,1,DEC)
31 S FP=1103 W @F,$J("",13),@F,VM I VM'=BF W " : ",$J(PAR,7,4) I 'PAR G 2
33 S NETG=+$P(N,D,7),NETD=+$P(N,D,14),NETI=+$P(N,D,13),NETA=+$P(N,D,15),NET=NETG+NETD+NETI+NETA,KKB=$P(N,D,10)
35 S MSTG=+$P($P(N,D,7),"#",2),MSTD=+$P($P(N,D,14),"#",2),MSTI=+$P($P(N,D,13),"#",2),MSTA=+$P($P(N,D,15),"#",2),MST=+$P($P(N,D,6),"#",2)
37 F I=1:1:11 S J=$P("NETG\MSTG\NETD\MSTD\NETI\MSTI\NETA\MSTA\NET\KKB\MST",D,I),X(I)=$J(@J/PAR,0,DEC)
38 F I=1:1:7 D S1 I I<4 S FP=I+6*100+23 W @F,@F2 I X(I+8) W $J(X(I+8),1,DEC)
39 I BP'>BPA S K=$P($T(@("T13"_QT)),U,2)_BP_$P($T(@("T13"_QT)),U,3) D F1 G 2
 ;
4 S I=1 L @("^"_Q_"AA(BP,FNR)"):2 E  S R=14 D F2 G 2
41 S R="K\22\3\"_$P($T(@("T9"_QT)),U,I#2+3)_$P($T(@("T8"_QT)),U,I-1\2+2)_"\C1\10\INCTR" D R0 G 4:K=","
43 I K="-" S I=I-1 G 41:I L  G 1
45 S X(I)=$S(K="":A,1:K) S:X(I)["-" X(I)=-X(I) D S1
47 S I=I+1 I I<8 G 41
49 S R="K\22\3\"_$P($T(@("T11"_QT)),U,2)_"\1\\""-,.""[K&$L(K)" D R0 G 4:K=",",43:K="-"
 ;
5 I X(9)-X(1)-X(3)-X(5)-X(7)'=0 S K=$P($T(@("T12"_QT)),U,2) D F1 G 49
53 F I=1:1:7 S J=$P("NETG\MSTG\NETD\MSTD\NETI\MSTI\NETA",D,I),@J=$J(X(I)*PAR,0,QD)
55 S VNET=NET-NETG-NETD-NETI-NETA,MST=MSTG+MSTD+MSTI I VNET D S2
 ;
6 S @%Q1=0,I=$G(@("^"_Q_"AALOG(BP,FNR)"),1),^(FNR)=I+1,^(FNR,I)=N
61 S $P(N,D,6)=+$P(N,D,6)_"#"_MST,$P(N,D,7)=NETG_"#"_MSTG,$P(N,D,14)=NETD_"#"_MSTD,$P(N,D,13)=NETI_"#"_MSTI,$P(N,D,15)=NETA_"#"_NETA
63 S @("^"_Q_"AA(BP,FNR)")=N,@("^"_Q_"BA(BP,111)")=$H,@%Q1=1 L  G 2
 ;
YZ Q
 ;
R0 S R0=$P(R,D,5) I $L(R0),R0'["""" S $P(R,D,5)=R0_"^"_$T(+0)
R0A S R0=$P(R,D,7) I $L(R0),R0'="DCTR" S $P(R,D,7)="",R1=$P(R,D,8),R0=$P($T(@R0),U,2,99) S:$L(R1) R0=R0_"&("_R1_")" S $P(R,D,8)=R0
R0Z S $P(R,D,12)=$T(+0) K R0,R1 D ^cA100 Q  ; v11 30.05.94
 ;
F1 S R=250
F2 D TXT^cAFA1(R)
FZ K R Q
 ;
C1 S A=$J(X(I-1\2*2+1),0,DEC) S:A<0 A=$E(A,2,999)_"-" W !?2,$P($T(@("T9"_QT)),U,2),VM,"   [] = ",A Q
 ;
INCTR ;K?.N!(K?.N1"-")!(K?.N1".".N!(K?.N1".".N1"-")&DEC&($L(K#1)-1'>DEC))!(K="-")!(K=",")
 ;
Z X ^cZ Q
ZZ ; 05.02.01 - 16 u 23 * V7.84