cT661 ;Betalingsvoorstel leveranciers ;%T66 ; [ 03/13/01  4:36 PM ]
 G 1
 ;
T0 ;Betalingsvoorstel leveranciers ;
T1 ;Omschrijving;
T2 ;Journaal;allemaal;
T3 ;Muntcode;allemaal;
T4 ;Subtotaal;
T5 ;Factuurnummer; komt reeds voor op dit voorstel; reeds betaald;
T6 ;Definitief;
 ;
T0F ;Proposition de paiement ;
T1F ;Description;
T2F ;Journal;tous;
T3F ;Code mon.;tous;
T4F ;Sous-total;
T5F ;N° de facture; existe déjà pour cette proposition; déjà payé;
T6F ;Définitif;
 ;
T0E ;Betalingsvoorstel leveranciers ;
T1E ;Omschrijving;
T2E ;Journaal;allemaal;
T3E ;Muntcode;allemaal;
T4E ;Subtotaal;
T5E ;Factuurnummer; komt reeds voor op dit voorstel; reeds betaald;
T6E ;Definitief;
 ;
 ; opbouw betalingsvoorstel : Xecute NA openen BVS
 ; B(1) = BVS
 ; UREF = BVS
1 D EG^cAFA1
11 S SRT=$P(B(1),D,5) I $L(SRT) S SRT=" "_SRT_" "    ; journalen
13 S BF=$$BF^cAFA1 D VM(BF)
15 S VM=$P(B(1),D,4) D VM(VM)                        ; evt. muntcode
17 S VV=$$DC^cAFA1($P(B(1),D,6))                     ; vervaldatum
18 S VNR=$P(B(1),D,8) I 'VNR S VNR=1                 ; volgnr. lev.
19 S BVSNR=$P(B(1),D,12) I 'BVSNR S BVSNR=1          ; volgnr. BVS.NR
 ;
 ; leveranciers aflopen
2 S I1="",TOT=0
21 D ^cAN004("I1","LE") I I1="" G Y
23 S KC=$P(@("^"_Q_"LE(I1,0)"),D)                    ; leveranciersnummer
25 ; I $$SIG^cAFA1("LE.BT",$P(^(0),D,12),104) G 21 ; VJ-06.11.98
27 S I2=99999,VNR=VNR+1
 ;
 ; per leverancier openstaande facturen
3 S I2=$O(@("^"_Q_"LE(I1,I2)")) I I2'?6N G 21
31 S OF=^(I2) I $P(OF,D,8) G 3                  ; niet opnemen op BVS
33 I $L(SRT) D  I 'SW G 3
 . S SW=1,K=$P(OF,D,16) I $L(K) D S1 Q        ; journaal bij openst.f.
 . S BP=$P($G(@("^"_Q_"AF(I2)")),D,2)         ; journaal via dagboek
 . I 'BP F  S BP=$O(@("^"_Q_"AA(BP)")) Q:BP=""  I $D(^(BP,I2)) Q
 . I BP,$D(@("^"_Q_"AA(BP,I2)")) S K=$P(^(I2),D,21) I $L(K) D S1 Q
 . I $D(@("^"_Q_"BA")@("%T",10)) X ^(10)      ; er is geen journaal
35 S K=$P(OF,D,5)-$P(OF,D,6)-$P(OF,D,12) I K'>0 G 3       ; bedrag
37 I $L(VM) S R=$P(OF,D,9) D VM(R) I VM(R)'=VM(VM) G 3    ; muntcode
39 I $$DC^cAFA1($P(OF,D,3))>VV G 3              ; te ver in de toekomst
 ;
 ; factuur op voorstel
4 I $P(OF,D)="C" S K=-K ;-$P(OF,D,6) ; VJ 13.03.01 (Molto)
41 S R=$$OMREK^cAFA1(K,$P(OF,D,9),BF,"A",1)
43 S @UREF@(VNR*1E6+I2+1E12)=KC_D_I2_D_K_D_R_D_VNR_D_$P(OF,D,9)_D_BVSNR_D
45 S TOT=TOT+R,$P(^(0),D,7)=TOT,$P(^(0),D,8)=VNR+1,$P(^(0),D,12)=BVSNR+1
47 S ^DATA(Q,"BVS.NR",UI1,BVSNR)=VNR*1E6+I2+1E12,BVSNR=BVSNR+1
49 W /CUP(1,41),BVSNR-1 G 3
 ;
 ; einde
Y K KC,SRT,VM,VV,VNR,BVSNR,I1,I2,TOT
YZ D C^cA612 Q
 ;
R0 S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
 ;
 ; test op journaal
S1 I SRT'[(" "_K_" ") S SW=0
S1Z Q
 ;
B() ; test op bedrag
 N M,R
 S M=$P(OF,D,5)-$P(OF,D,12)
 S R=1 I $P(OF,D)="C"&(K'["-")!(K>M) S R=0
BZ Q R
 ;
CUM ; berekenen cumul = som detaillijnen; UREF = BVS.DET
 S (K,UI1)=0 F  S UI1=$O(@UREF) Q:UI1=""  S K=K+$P(^(UI1),D,4)
 S $P(^(0),D,7)=K
CUMZ Q
 ;
D(K) ; definitief verklaren
DA D W^cAN220("BVS",0,BVS,109,K),REF
DZ Q
 ;
F ; manueel factuur ingeven
FA S R="FNR\22\3\"_$P($T(@("T5"_QT)),U,2)_"\\6\\K?6N!(K=""-"")" D R0 G FZ:'K
FB I '$D(@("^"_Q_"AF(FNR)")) S K=$P($T(@("T5"_QT)),U,2)_" "_FNR_$P($T(@("T5"_QT)),U,4) D TXT^cAFA1(250) G FA
FC S KC=$P(^(FNR),D) I KC[" " S KC=$P(KC," ",2)
FD S I1=$$UI1^cAFA1("LE",101,KC),OF=$G(@("^"_Q_"LE(I1,FNR)"))
FE S K=$P(OF,D,5)-$P(OF,D,6)-$P(OF,D,12) I $P(OF,D)="C" S K=-K ;-$P(OF,D,6)
FF S R=$$OMREK^cAFA1(K,$P(OF,D,9),BF,"A",1),UI1=0,VNR=0
FG S UI1=$O(@UREF) I UI1="" D  G FZ
 . S UI1=0,BVSNR=$P(@UREF,D,12),$P(@UREF,D,12)=BVSNR+1
 . I 'BVSNR S BVSNR=BVSNR+1,$P(@UREF,D,12)=BVSNR+1
 . I 'VNR S VNR=$P(@UREF,D,8),$P(@UREF,D,8)=VNR+1
 . I 'VNR S VNR=VNR+1,$P(@UREF,D,8)=VNR+1
 . S UI1=VNR*1E6+FNR+1E12,@UREF=KC_D_FNR_D_K_D_R_D_VNR_D_$P(OF,D,9)_D_BVSNR
 . S NUI1=UI1,^DATA(Q,"BVS.NR",BVS,BVSNR)=UI1
FH I $P(^(UI1),D)=KC S VNR=$P(^(UI1),D,5)
FI I $P(^(UI1),D,2)'=FNR G FG
FJ S K=$P($T(@("T5"_QT)),U,2)_" "_FNR_$P($T(@("T5"_QT)),U,3) D TXT^cAFA1(250) G FA
FZ Q
 ;
REF ; refresh TOP van BVS
 S B(1)=$$SIGN^cAFA1("BVS",BVS,0) D TOP
REFZ S OK=1 Q
 ;
TOP ; opzetten top ; B(1) = BVS
 N R
 S UTOP(1)="1\1\"_$P($T(@("T1"_QT)),U,2)_"\4"      ; omschrijving
 S UTOP(1.1)="1\14\: "_$P(B(1),D,2)_D_0
 S UTOP(2)="2\1\"_$P($T(@("T2"_QT)),U,2)_"\4"      ; journaal
 S K=$P(B(1),D,5)
 S UTOP(2.1)="2\14\: "_$S($L(K):K,1:$P($T(@("T2"_QT)),U,3))_D_0
 S UTOP(3)="3\1\"_$P($T(@("T3"_QT)),U,2)_"\4"      ; muntcode
 S K=$P(B(1),D,4)
 S UTOP(3.1)="3\14\: "_$S($L(K):K,1:$P($T(@("T3"_QT)),U,3))_D_0
 S UTOP(4)="3\49\"_$P($T(@("T4"_QT)),U,2)_"\4"     ; subtotaal
 S UTOP(4.1)="3\59\: "_$$IP^cAFA1($P(B(1),D,7),QD,13)_" "_BF
 S UTOP(5)="1\60\"_$J($P($T(@("T6"_QT)),U,3-$P(B(1),D,9)),18)_"\1"
 S OK=0    ; niet meer converteren
TOPZ S REFTOP=1 Q
 ;
 ; officiële muntcode
VM(K) I K="" S K=BF
 I '$D(VM(K)) S VM(K)=K I $D(@("^"_Q_"BA(11,K)")) S VM(K)=$P(^(K),D)
VMZ Q
 ;
ZZ ; 30.03.01 - 13 u 39 * V7.85