cT764	; Update bestanden ;cT764 ; [ 06/15/2000  5:16 PM ]
	G 1
	;
T0	;Update bestanden;
T1	;Verwijderen\",[] = hernemen   V[] = verwijderen"
	;
T0F	;Update fichiers ;
T1F	;Annulation\",[] = reprendre   V[] = annulation"
	;
T0E	;Update bestanden;
T1E	;Verwijderen\",[] = hernemen   V[] = verwijderen"
	;
	; signaletiek ongewijzigd, alleen wegschrijven maandbedragen in ^_Q_AFS
1	I $D(OINH),$D(NINH),OINH=NINH D UPD1 G YZ
	;
	; is er gedesinvesteerd ?
2	I $D(OINH),$D(NINH),$P(OINH,D,9)'=$P(NINH,D,9) D UPD4 G YZ
	;
	; check welke velden er gewijzigd zijn in signaletiek
3	I $D(OINH),$D(NINH) S SLEUTEL=$$CHECK(OINH,NINH) D:'SLEUTEL UPD2 D:SLEUTEL UPD3
	;
	; uit te voeren bij openen via F2
4	I '$D(OINH),$D(LIJNUI1),$D(^TEMP(boot,$J,LIJNUI1)) D UPD3
	;
YZ	K OINH,NINH Q
	;
CHECK(OUD,NIEUW)	; check op sleutelvelden gewijzigd zijn
	N OEB,NEB
	S $ZT="TRAP^cAN000"
	S SLEUTEL=0
	S OEB=$$EBD^cT76($P(OUD,D,3),$P(OUD,D,8),$P(OUD,D,5))       ; vorige 1e boekingsdatum
	S NEB=$$EBD^cT76($P(NIEUW,D,3),$P(NIEUW,D,8),$P(NIEUW,D,5)) ; nieuwe 1e boekingsdatum
	I OEB'=NEB S SLEUTEL=1 G CHECKZ
	F I=2,3,4,5,8 I $P(OUD,D,I)'=$P(NIEUW,D,I) S SLEUTEL=1 Q
CHECKZ	Q SLEUTEL
	;
UPD1	; alleen wegschrijven maandbedragen in ^_Q_AFS
	N I3,INV,CAT,LN,MND,BEDR
	S $ZT="TRAP^cAN000"
	S I3=$O(^TEMP(boot,$J+.02,"")) G UPD1Z:I3=""
	S INV=$P(I3," "),CAT=$P(I3," ",2)_" ",LN=$P(I3," ",3)_" "
	S MND="" F  S MND=$O(@("^"_Q_"AFS(INV,CAT,LN,MND)")) Q:MND=""  K ^(MND)
	S I3=""
	F  S I3=$O(^TEMP(boot,$J+.02,I3)) Q:I3=""  S BEDR=^(I3,0) D
	. S INV=$P(I3," ")         ; investeringsjaar
	. S CAT=$P(I3," ",2)_" "   ; categorie
	. S LN=$P(I3," ",3)_" "    ; lijnnummer
	. S MND=$P(I3," ",4)       ; maand
	. S @("^"_Q_"AFS(INV,CAT,LN,MND)")=BEDR
UPD1Z	Q
	;
UPD2	; signaletiek gewijzigd, maar sleutelvelden niet -> niet herrekenen
	N I,INV,CAT,LN,BEE,UREF,UQC,USC,UI1
	S $ZT="TRAP^cAN000"
	G UPD2Z:'$D(NINH)
	D UPD1   ; aanpassen maandbedragen die eventueel gewijzigd zijn
	F I=1:1:30 S BEE(100+I)=$P(NINH,D,I)
	S BEE(124)="",$P(NINH,D,24)=""
	S BEEO(1)=NINH,$P(BEEO(1),D,24)=""
	S INV=$P(LIJNUI1," ")        ; investeringsjaar
	S CAT=$P(LIJNUI1," ",2)_" "  ; code categorie
	S LN=$P(LIJNUI1," ",3)_" "   ; lijnnummer
	D DMS^cAN000("UQC","USC","AFS")
	S UREF=^DMC(UQC,USC,"DATA","REF"),UI1=LIJNUI1
	I $D(OINH) D
	. F I=1:1:30 S BEE(I+100)=$P(NINH,D,I)
	. ; D B^cAN220("AFS",0,UI1,"BEE")
	. S @UREF@(0)=NINH
	I '$D(OINH) D P^cAN220("AFS",0,LIJNUI1,"BEEO","") ; openen in ^DATA(Q,"AFS"
	S @("^"_Q_"AFS(INV,CAT,LN)")=NINH
UPD2Z	Q
	;
UPD3	; herrekenen maandbedragen + wegschrijven wijzigingen
	D ^cT763
	D UPD2
UPD3Z	Q
	;
UPD4	; desinvesteren
	S TBL=$P(NINH,D,24)
	I '$D(^TEMP(boot,$J+.02)) S I4=0 D
	. F  S I4=$O(@("^"_Q_"AFS(INV,CAT,TBL_"" "",I4)")) Q:I4=""  D
	..  S BED=^(I4),^TEMP(boot,$J+.02,INV_" "_CAT_TBL_" "_I4,0)=BED
	;
	D S5^cT762
	D UPD2
UPD4Z	Q
	;
DEL(UI1)	; verwijderen via "del" toets
	N INV,CAT,LN
	S $ZT="TRAP^cAN000"
	S R="K\22\3\"_$P($T(@("T1"_QT)),U,2)_"\1\\""-,V""[K&$L(K)" S $P(R,D,11)=1 D R0
	I K'="V" G DELZ
	D X^cAN220("AFS",0,UI1)        ; ^DATA(Q,AFS verwijderen
	S INV=$P(UI1," ")  
	S CAT=$P(UI1," ",2)_" "
	S LN=$P(UI1," ",3)_" "
	K @("^"_Q_"AFS(INV,CAT,LN)")   ; verwijderen ^_Q_AFS
	K ^TEMP(boot,$J,UI1)           ; verwijderen uit ^TEMP
	K ^DLOG(Q,"AFS.LN",UI1)        ; verwijderen logging
DELZ	Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
ZZ	; 15.12.05 - 12 u 16 * V8.05