cT850 ;Fin & div: beheer repetitieve boekingsreeksen ;%T80 ; [ 01/12/01  10:03 AM ]
 G 1
 ;
T0 ;Repetitieve boekingsreeksen;
T1 ;Saldo;Muntcode;
T2 ;Saldo fin.;Saldo DV;
T3 ;Bevestiging\".[] = conversie naar euro";
T4 ;Verwijderen\"[] = enkel detaillijnen   .[] = volledig verwijderen";
T5 ;Bevestiging\".[] = alles omdraaien";
 ;
T0F ;Série d'écritures répétitives;
T1F ;Solde;Code mon.;
T2F ;Solde fin.;Solde OD;
T3F ;Confirmation\".[] = conversion en euro";
T4F ;Annuler\"[] = seulement lignes dét.   .[] = annuler complètement";
T5F ;Confirmation\".[] = tous inverter";
 ;
T0E ;Repetitive automatic registrations;
T1E ;Balance;Currency;
T2E ;Balance fin.;Balance MT;
T3E ;Confirmation\".[] = conversion to euro";
T4E ;Remove\"[] = only detail lines   .[] = remove completely";
T5E ;Confirmation\".[] = invert all";
 ;
 ; initialisatie
1 S SWFI=$P(R,U,2),SAFI=$P(R,U,3),HBF=$P(R,U,4),HQD=$P(R,U,5) I SWFI S ^HULP("PAS",$J+.01)="-"
11 ;D O^cA612(2,1,20,80,1,0,0,0),T^cA612($P($T(@("T0"_QT)),U,2),0,0,7,1,1) ;10.03.00
 D P^cA612(2,1,20,80,1,0,0,0,$P($T(@("T0"_QT)),U,2),0,0,7,1,1)
13 D ^cT164 G YZ:'OK S BJ=$$BJ^cAFE1(Q,DJ_"."_DM),K=$$MNTC^cAFE1(Q,BJ),BF=$P(K,D),QD=$P(K,D,2)
15 D DMS^cAN000("UQC","USC","FIA") G YZ:UQC=""!(USC="")
17 S UREF=^DMC(UQC,USC,"DATA","REF")
 ;
 ; synoniemen
2 S UI1=$$^cANSYN("FIA") G YZ:K="-"
21 L +@UREF:2 E  D BUSY^cAFA1 G 2
23 S UI1FIA=UI1 D BS^cAN210("FIA.DET",0,0,0,0)
25 L -@UREF I 'SWFI G 2
 ;
YZ D C^cA612 Q
 ;
 ; verwerken boekingen
B S ^HULP("PAS",$J+.01)=UI1FIA
BZ Q
 ;
 ; conversie naar euro
C S R="K\22\3\"_$P($T(@("T3"_QT)),U,2)_"\1\\K="".""!(K=""-"")" D R0 G CZ:K="-"
CA D W^cAN220("FIA",0,UI1FIA,111,"EUR") I K="-" G CZ
CB N I,J S UI1=0 F  S UI1=$O(@UREF) Q:UI1=""  D
 . S J=^(UI1),I=$P(J,D,2) I I["-" S I=-I
 . S I=$$OMREK^cAFE1(Q,I,MNT,"EUR","F","") I I<0 S I=-I_"-"
 . S $P(^(UI1),D,2)=I
CC D TOP S (REFRESH,REFTOP)=1
CZ Q
 ;
 ; registratie detaillijn
DET I 'UI1 S UI1=$O(@UREF,-1)+1
DETA I $D(@UREF) D
 . N I,J,K S J=UI1 N UI1
 . S I=J F UI1=I:1 Q:'$D(@UREF)
 . S I=UI1 F UI1=I:-1:J+1 S UI1=UI1-1,K=@UREF,UI1=UI1+1,@UREF=K
DETB S @UREF=B(1)
DETZ S OK=1 Q
 ;
 ; wijzigen hoofding
H D W^cAN200("FIA",0,"","",$$IDEM^cAFA1,102)        ; wijzigen hoofding
HA D TOP S REFTOP=1                                  ; TOP opnieuw tonen
HZ Q
 ;
 ; verwijderen
V S R="K\22\3\"_$P($T(@("T4"_QT)),U,2)_"\1\\""-.""[K" D R0 G VZ:K="-"
VA I K="" F  S UI1=0,UI1=$O(@UREF) Q:UI1=""  K ^(UI1)
VB I K="" D TOP S (REFRESH,REFTOP)=1 G VZ
VC S UI1=UI1FIA D X^cAN200("FIA",0,"","",$$IDEM^cAFA1) I $G(KILL) S EXIT=1 K KILL
VZ Q
 ;
 ; alles omdraaien
X S R="K\22\3\"_$P($T(@("T5"_QT)),U,2)_"\1\\K="".""!(K=""-"")" D R0 G XZ:K="-"
XB N I,J S UI1=0 F  S UI1=$O(@UREF) Q:UI1=""  D
 . S J=^(UI1),I=$P(J,D,2),I=$S(I["-":+I,1:I_"-"),$P(^(UI1),D,2)=I
XC D TOP S (REFRESH,REFTOP)=1
XZ Q
 ;
 ; TOP updaten
TOP N UQC,USC,UI1 D DMS^cAN000("UQC","USC","FIA")
 S UI1=UI1FIA X ^DMC(UQC,USC,"LOGGING","TOP") S UTOP(1.1)=UTOP(1.1)_$J("",30)
 S MNT=$$SIG^cAFA1("FIA",UI1,111)
 I MNT="" S MNT=$P(@("^"_Q_"BA(39)"),D,9) I MNT="" S MNT=$P(^(39),D)
 S DEC=$$DEC^cAFA1(MNT)
 S UTOP(103)=3_D_61_D_$P($T(@("T1"_QT)),U,3)_D_4,UTOP(103.1)=3_D_70_D_": "_MNT_D_0
 S UTOP(2)=$P($T(@("T1"_QT)),U,2),UTOP(2.1)=0,UI1=0
 F  S UI1=$O(@UREF) Q:UI1=""  S K=$P(^(UI1),D,2),UTOP(2.1)=UTOP(2.1)+$S(K["-":-K,1:K)
 S UTOP(2.1)=$$IP^cAFA1(UTOP(2.1),DEC,0)_$J("",30)
 I SWFI S UTOP(3)=$P($T(@("T2"_QT)),U,1+SWFI),UTOP(3.1)=$$IP^cAFA1(SAFI,HQD,0)_HBF
TOPZ D TOP^cAN210 Q
 ;
 ; berekenen saldo
SAL(I1) N UI1,IND,BED,INH S SALDO=0,UI1=0
SALA S UI1=$O(@UREF) G SALZ:UI1=""
 S INH=^(UI1),BED=$P(INH,D,2) I BED["-" S BED=-BED
SALB S SALDO=SALDO+BED G SALA
SALZ Q -SALDO
 ;
R0 S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84