cTN1211	; Verkoop : Inschrijven documenten; cTN1211;
	;
T1	;Mst ; munt;
	;
T1F	;Base ; dev.;
	;
T1E	;Basis ; Cur.;
	;
YZ	Q
	;
BTWMST(DB,QQ)	; Geeft BTW-maatstaven weer van één verkoopdocument
	; Input: DB: Dagboek
	;        QQ: Vennootschap
	; Output: Maatstafstrings, gescheiden door "\"
	;         
	;         Eén maatstafstring bestaat uit: (gescheiden door "#")
	;         1. UI1 BTW-code
	;         2. Maatstaf in firmamunt
	;         3. Maatstaf in munt document 
	;         
	N MST,BTWT,UI1
	S $ZT="^dmERROR"
	S D="\",U=";"
	;
BTWMST1	S MST="" I $E($G(DB))'="V" G BTWMSTZ
	D BTWT("",.BTWT,QQ)
	;
BTWMST2	S UREF="^DBH(""EA"",""DB.BTW"",UI1)"
	S UI1=DB_" "
BTWMST3	S UI1=$O(@UREF) I $P(UI1," ",1,2)'=DB G BTWMSTY
	S N=^(UI1,0) I '$D(BTWT($P(N,D,2))) G BTWMST3
	S BTWT($P(N,D,2))=$P(N,D,3)_"#"_$P(N,D,4)
	G BTWMST3
	;
BTWMSTY	S UI1="" F  S UI1=$O(BTWT(UI1)) Q:'$L(UI1)  S MST=$S($L(MST):MST_D,1:"")_UI1_"#"_BTWT(UI1)
BTWMSTZ	Q MST
	;
BTWT(SW,TAB,QQ)	; Geeft de UI1's of %'s van alle BTW-types terug
	; Input: SW: output-switch
	; 	   "" of 0: UI1's
	; 	   1: titels
	; 	   2: titels munt
	; 	 TAB: doorgeven als referentie
	; 	 QQ: Vennootschap
	;
	; Output: afhankelijk van SW: UI1's of titels (gescheiden door "\")
	N R,UI1,UREF,LND,IREF,CODE,N0
	S $ZT="^dmERROR"
	;
BTWT1	D QT^cAFVBO01 
	S SW=$G(SW),R="",D="\"
	;
BTWT2	S LND=$$SIG^cAFA1("Q",QQ,206) I '$L(LND) G BTWTZ
	S IREF="^IND(0,""CODE.9011"",""M1"",LND,CODE)",CODE=""
	S UREF="^DKODE(0,""CODE.9011"",UI1)"
	;
BTWT3	S CODE=$O(@IREF) G:'$L(CODE) BTWTY S IUI1=""
BTWT4	S IUI1=$O(@IREF@(IUI1)) G:'$L(IUI1) BTWT3
	S UI1=$P(^(IUI1),D),N0=@UREF@(0) I $P(N0,D,30)=2 G BTWT4
	S TAB(UI1)=$S('SW:UI1,1:$P($T(@("T1"_QT)),U,2)_$P(N0,D)_$S(SW=2:$P($T(@("T1"_QT)),U,3),1:"")_"#"_$P(N0,D,30))
	G BTWT3	
	;
BTWTY	S UI1="" F  S UI1=$O(TAB(UI1)) Q:'$L(UI1)  S R=$S($L(R):R_D,1:"")_TAB(UI1) I 'SW S TAB(UI1)=""
BTWTZ	Q R
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09