cTR1	;Ingave recyclagebijdragen via 5.1; cTR1
	;
T0	;Ingave recyclagebijdragen via 5.1;
T1	;Ingave recyclagebijdragen;
T2	;Boekingsmaand\"jjjj.mm[] = bepaalde maand";
T3	;Boekingsmaand;
T4	;Factuur;Datum;Boekingsmaand;Lev.;
	;
T0F	;Contribution recyclage par 5.1;
T1F	;Contribution recyclage;
T2F	;Mois comptable\"aaaa.mm[] = mois spécifique";
T3F	;Mois comptable;
T4F	;Facture;Date;Mois comptable;Four.;
	;
1	D P^cA612(2,1,20,80,1,0,0,1,$P($T(@("T1"_QT)),U,2),0,0,7,1,1)
	; Vraagstelling boekingsmaand
11	S BP=DJ_"."_DM
13	S R="BP\22\3\"_$P($T(@("T2"_QT)),U,2)_"\7\\K?4N1"".""2N&($P(K,""."",2)<13&$P(K,""."",2))!(K=""-"")\\\\\1" D R0 I K="-" G YZ
	;
	;  Opbouwen ^TEMP met alle ingeschreven facturen van buitenlandse leveranciers binnen deze BP
2	K ^TEMP(boot,$J)
21	S FNR=""
23	F  S FNR=$O(@("^"_Q_"AA(BP,FNR)")) Q:FNR=""  D
	. ; Enkel facturen beschouwen
	. I FNR#1 Q
	. S INH=^(FNR)
	. S KC=$P(INH,D,4)
	. ; Kijken of landcode van de leverancier afwijkt van deze van de firma
	. I $$SIG^cAFA1("ISO.LAND",$$SG^cAFA1("LE",KC,108),101)=$P(@("^"_Q_"BA(39)"),D,3) Q
	. S ^TEMP(boot,$J,FNR)=FNR_D_BP_D_$P(INH,D,2)_D_KC_D_$P(INH,D,18)
	;
	;  Tonen ^DMH met facturen
3	D BS^cAN210("AA.REC_FAC",0,0,0,"")
	;
Y	K ^TEMP(boot,$J)
YZ	D C^cA612 Q
	;
OPREC(FNR)	; Testen of er bij de factuur reeds recyclagebijdragen werden ingegeven
	N SWREC,I1
	S $ZT="TRAP^cAN000"
	S SWREC=0
	S I1=FNR_" "
	F  S I1=$O(^INDEX(Q,"AA.REC",101,I1)) Q:($P(I1," ")'=FNR)  D  Q:SWREC
	. S UI1=^(I1)
	. I '$P(^DATA(Q,"AA.REC",UI1,0),D,30) S SWREC=1
OPRECZ	Q SWREC
	;
REC(SWBH)	; Oproepen scherm met recyclagebijdragen voor deze factuur
	D P^cA612(2,1,20,80,1,0,0,1,$P($T(@("T1"_QT)),U,2),0,0,7,1,1)
	W /CUP(2,2),@F6,$P($T(@("T4"_QT)),U,2),@F9,":",/CUP(2,13),FNR
	W /CUP(2,27),@F6,$P($T(@("T4"_QT)),U,3),@F9,":",/CUP(2,36),FDT
	W /CUP(2,50),@F6,$P($T(@("T4"_QT)),U,4),@F9,":",/CUP(2,67),BP
	W /CUP(3,2),@F6,$P($T(@("T4"_QT)),U,5),@F9,":",/CUP(3,10),$$KL^cAFO1("LE",KC)
	; ; Continue openen recyclagebijdragen
	I $G(SWBH) D P^cAN200("AA.REC","","","")
	; Tonen overzicht geopende recyclagebijdragen
	D BS^cAN210("AA.REC",0,0,0,"")
RECZ	D C^cA612 Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q
	;
ZZ	; 24.02.06 -  9 u 54 * V8.06