ATK ; Afstand-toegang voor klanten [ 05/31/2002  9:42 AM ]
 ;
 Set $ZT="ERROR^ATKERROR"
 New
 Do INIT
 Do VT520(2,0)
 Set FP=101
 Write @F,@F1,@FCH
 Do TITEL
 If $$LOGON^ATKLOGON() Do
 .Do TITEL
 .Set KLNr=$$WACHTW^ATKLOGON(Taal)
 .If KLNr Do
NEWKLNR ..If '$$KLINIT^ATKCUST(KLNr) Do NOJOB Quit
 ..Kill NewKLNr
 ..If '$G(^HULP(%J,"KLINIT","A")) Do  Quit
 ...Hang 1
 ...Do LOGOFF^ATKLOGOF(),NOLOGON^ATKLOGON
 ..If $L($P(WachtW,".",2)),$P("+\-",D,$$NOPRICE()+1)'=$P(WachtW,".",2) Set WachtW=$P(WachtW,".")
 ..Set FP=201
 ..Write @F,@F1
 ..Kill sRT,sRB
 ..Do ADD^vhScherm(1,23),COMMAND
 ..Do SCRNTYP("",Taal)
 ..Set FP=201
 ..Write @F,@F1
 ..Do LOGOFF^ATKLOGOF()
 ..If '$D(NewKLNr) Do WRITETXT("ATK","LOGOFF",Taal,13) Quit
 ..Do CLEAN
 ..Kill (sJC,NewKLNr,UserName,WachtW,DefInput)
 ..Do INIT
 ..Set KLNr=NewKLNr
 ..Goto NEWKLNR
 Else  Do NOJOB
 Do CLEAN
 Do VT520()
 Quit
 ;
COMMAND 
 New R,IK,Input
 For  Do  If Input="-" Do CLOSE^ATKMB(Input),REFRESH If $$EXIT($G(SuperV)) Do ASKTRANS^ATKPROD Quit
 .Set Input=$G(DefInput)
 .Do REFRESH
 .If $D(DefInput) Set Input=DefInput Kill DefInput
 .Else  Do
 ..Kill zb
 ..Set DL(3)=-STimeOut Set:$G(DL(1))="LEVADR" DL(3)=0
 ..If $D(DL(1)),$D(@DL(1)@(1)) Do
 ...If DL(1)="MOEDERB" Do COMMAND^ATKMB Set R=Input Quit
 ...If DL(1)="OFFERTE" Do COMMAND^ATKOFF Set R=Input Quit
 ...Do SL
 ..Else  Do
 ...New IK
 ...Set IK(2)=-DL(3)
 ...Do IK^PROC
 ..If R="",$G(DL(1))="LEVADR" Do DISPLEVA^ATKCUST
 ..Kill DL(3)
 ..If $G(zb)="",$G(R)="" Set R="-"
 ..Set Input=R
 .If "\-\?\+\*\ENTER\"'[(D_Input_D) Set Input=$$ITRANSL^ATKMENU(Input,Taal)
 .If Input="?" Do MENU^ATKMENU(Input) Set:Input="?" Input=""
 .If Input="+",$L($$MAKTIE^ATKMENU($G(DL(1)))) Do MENU^ATKMENU(Input)
 .If Input="?" Do MENU^ATKMENU(Input)
 .If Input="*" Do SCREENS(Input),LEGEND
 .If '$$CHKMENU^ATKMENU(Menu) Quit
 .If $L(Input) Do SCREENS(Input)
 .If Input="W" Do LVHKLREF
 .If Input="P" Do RPLPR^ATKPROD
 .If Input="U" Do OWNREF^ATKPROD
 .If Input="R" Do KLREF^ATKPROD
 .If "\O\C\A\T\"[(D_Input_D) Do ORDER(Input,$G(WInput))
 .If Input="B" Do BON
 .If Input="S" Do OFAKT
 .If Input="V" Do VERKAN
 .If Input="K" Do RPLKL^ATKCUST Set:$G(NewKLNr) Input="-"
 .If Input="M" Do MOEDERB^ATKMB
 .If Input="Q" Do AANVRAAG^ATKOFF
 .If Input="E" Do INTRAST
 .If Input="Y" Do LEVADR^ATKCUST
 .If Input="=" Do FIND
 .If Input=">" Do FAX($G(FaxNr))
 .If Input="!" Do SWPRICE
 .If Input="@" Do CALLBACK
 .Kill WInput
 Quit
 ;
CB(Ref,Rec) 
 Set @DL(1)@(9)=$O(@(@DL(1)@(1)_"""A"")"),-1),$P(DLse,D)=@DL(1)@(9)
 If '$G(WriteLst) Do
 .If "\KLSEL\LESEL\PRSEL\LEVADR\"'[(D_$G(DL(1))_D) Do MENU^ATKMENU(1)
 Quit ""
 ;
REFRESH 
 New R
 If $G(sRT)<5 Do
 .Do TITEL:$G(sRT)=1
 .Do KLDISP^ATKCUST
 .Set FP=501 Write @F,@F1
 Do TEXT^ATKCUST
 If $D(DL(1)),$D(@DL(1)@(1)) Do
 .Quit:$G(sRB)<(@DL(1)@(3)-1)
 .Set DL(2)=sRT,DL(3)=sRB
 .If DL(1)="LEVADR",sRT<(LEVADR(3)-1),sRT>4 Set FP=sRT*100+1 Write @F,@F1
 .Do WL
 .If $G(DL(1))="LEVADR" Do DISPLEVA^ATKCUST
 .Kill DL(2),DL(3)
 .If $G(sRB)=24,$G(Input)'="?" Do MENU^ATKMENU(1)
 Else  Do
 .If $G(sRT)>4 Set FP=sRT*100+1 Write @F,@F1
 .If $G(sRB)=24,$G(Input)'="?" Do MENU^ATKMENU(1)
 Do RESET^vhScherm
 Quit
 ;
LVHKLREF 
 If LvhKlRef Set LvhKlRef=$S(LvhKlRef>1:1,1:2) Do
 .Quit:'$D(DL(1))
 .Set WInput=1
 .Set Input=$$LDINPUT(DL(1)) Set:Input'="R" DL(1)=""
 Quit
 ;
LEGEND 
 New Ref,LEGEND,TTab,zb
 Set Ref=$$LDGLOB^ATK($$LDINPUT^ATK(DL(1)))
 Quit:'$D(DL(1))  Quit:'$O(@("^LD(""L"",""ATK"_Ref_""",""H"",Taal,"""")"))
 Merge TTab=@DL(1)
 Set @DL(1)@(7)=@DL(1)@(6),@DL(1)@(4)=1
 Do WL
 Do
 .New DL
 .Do LDINIT(Input,Taal)
LEGEND1 .Do WL
 .Do
 ..New DL
 ..Do MENU^ATKMENU(1)
 .Set DL(3)=-STimeOut
 .Do SL
 .Kill DL(3)
 .If $G(zb)="",$G(R)="" Set R="-"
 .Set Input=R
 .If Input'="-",Input'="?" Set Input=$$ITRANSL^ATKMENU(Input,Taal)
 .If Input="?" Do MENU^ATKMENU() Set DL(2)=sRT Goto LEGEND1:Input="?"
 Merge @DL(1)=TTab
 Do ADD^vhScherm(LEGEND(3)-2,24)
 Quit
 ;
ORDER(Input,WInput) 
 New R,Ref,InitList,LEVNr,LevNaam
 If Input="T",'$G(WInput) Do  If 'LEVNr Do LDINIT(Input,Taal) Quit
 .Set R=$$SELECT^ATKSUPPL(UserName,1),LEVNr=$P(R,D)
 .Quit:'LEVNr
 .Set LevNaam=$P(R,D,2),^HULP(%J,"FAXPAR",Input,"LevNaam")=LevNaam
 .Kill ^HULP(%J,"TORDER"),DL
 Set Ref=$$LDLOC(Input)
 Quit:$G(DL(1))=Ref
 Do LDINIT(Input,Taal)
 If '$D(^HULP(%J,Ref)) Do
 .Do SCRNTYP^ATK("?",Taal)
 .Job ORDER^ATKJOB(%J,KLNr,$S(Input="O":"",1:Input),$G(LEVNr))::LTimeOut
 .If $T Set Time=$P($H,",",2) Do
 ..For  Hang HangTime Quit:$P($H,",",2)-Time>LTimeOut!($O(^HULP(%J,Ref,""),-1)>@DL(1)@(4))!$G(^HULP(%J,Ref))
 ..If $P($H,",",2)-Time>LTimeOut Goto TIMEOUT
 .Set InitList=1
 If $D(^HULP(%J,Ref)) Do
 .Do MERGNAME^ATKPROD($G(InitList))
 .Do SCRNTYP^ATK(Input,Taal)
 .Do ADD^vhScherm(@DL(1)@(3)-1,24)
 Quit
 ;
BON 
 New R,InitList
 Quit:$G(DL(1))="BON"
 Do LDINIT(Input,Taal)
 If '$D(^HULP(%J,"BON")) Do
 .Do SCRNTYP("?",Taal)
 .Job BON^ATKJOB(%J,KLNr)::LTimeOut
 .If $T Set Time=$P($H,",",2) Do
 ..For  Hang HangTime Quit:$P($H,",",2)-Time>LTimeOut!($O(^HULP(%J,"BON",""),-1)>BON(4))!$G(^HULP(%J,"BON"))
 ..If $P($H,",",2)-Time>LTimeOut Goto TIMEOUT
 .Set InitList=1
 If $D(^HULP(%J,"BON")) Do
 .Do MERGNAME^ATKPROD($G(InitList))
 .Do SCRNTYP(Input,Taal)
 .Do ADD^vhScherm(BON(3)-1,24)
 Quit
 ;
VERKAN 
 New R,InitList
 Quit:$G(DL(1))="VERKAN"
 Do LDINIT(Input,Taal)
 If '$D(^HULP(%J,"VERKAN")) Do
 .Do SCRNTYP("?",Taal)
 .Job VERKAN^ATKJOB(%J,KLNr)::LTimeOut
 .If $T Set Time=$P($H,",",2) Do
 ..For  Hang HangTime Quit:$P($H,",",2)-Time>LTimeOut!($O(^HULP(%J,"VERKAN",""),-1)>VERKAN(4))!$G(^HULP(%J,"VERKAN"))
 ..If $P($H,",",2)-Time>LTimeOut Goto TIMEOUT
 .Set InitList=1
 If $D(^HULP(%J,"VERKAN")) Do
 .Do MERGNAME^ATKPROD($G(InitList))
 .Do SCRNTYP(Input,Taal)
 .Do ADD^vhScherm(VERKAN(3)-1,24)
 Quit
 ;
OFAKT 
 New R
 Quit:$G(DL(1))="OFAKT"
 Do LDINIT(Input,Taal)
 If '$D(^HULP(%J,"OFAKT")) Do
 .Do SCRNTYP("?",Taal)
 .Job OFAKT^ATKJOB(%J,KLNr)::LTimeOut
 .If $T Set Time=$P($H,",",2) Do
 ..For  Hang HangTime Quit:$P($H,",",2)-Time>LTimeOut!($O(^HULP(%J,"OFAKT",""),-1)>OFAKT(4))!$G(^HULP(%J,"OFAKT"))
 ..If $P($H,",",2)-Time>LTimeOut Goto TIMEOUT
 If $D(^HULP(%J,"OFAKT")) Do
 .Do SCRNTYP(Input,Taal)
 .Do ADD^vhScherm(OFAKT(3)-1,24)
 Quit
 ;
INTRAST 
 New R,%SC,LastMnd,KlMunt
 Set LastMnd=$G(IsMaand),IsMaand=$G(IsMaand,$$CALCDATE^vhLib.DataTypes($H,"M","-1"))
 Do DISPLAY^vhScherm("ATKINTRAST"),FIELD^vhScherm("ATKINTRAST","ISMAAND")
 Do ADD^vhScherm(20,24)
 Quit:'%SC
 Set KlMunt="EUR"
 If IsMaand=LastMnd Quit:$G(DL(1))="INTRAST"
 Else  Kill INTRAST
 Do LDINIT^ATK(Input,Taal)
 If '$D(^HULP(%J,"INTRAST",IsMaand)) Do
 .Do SCRNTYP^ATK("?",Taal)
 .Job INTRAST^ATKJOB(%J,KLNr,IsMaand)::LTimeOut
 .If $T Set Time=$P($H,",",2) Do
 ..For  Hang HangTime Quit:$P($H,",",2)-Time>LTimeOut!($O(^HULP(%J,"KLREF",""),-1)>INTRAST(4))!$G(^HULP(%J,"INTRAST",IsMaand))
 ..If $P($H,",",2)-Time>LTimeOut Goto TIMEOUT^ATK
 If $D(^HULP(%J,"INTRAST",IsMaand)) Do
 .Set ^HULP(%J,"FAXPAR",Input,"IsMaand")=IsMaand
 .Do SCRNTYP^ATK(Input,Taal," ("_$$EXTDATE^vhLib.DataTypes(IsMaand,"DM")_")")
 .Do ADD^vhScherm(INTRAST(3)-1,24)
 Quit
 ;
LDINIT(Input,Taal) 
 New R,GloRef,LocRef
 Set GloRef=$$LDGLOB(Input),LocRef=$$LDLOC(Input)
 Quit:'$L(LocRef)
 If '$D(@LocRef) Do
 .Do INIT^PROC("ATK"_GloRef,LocRef,Taal)
 .Set @DL(1)@(8.1)=@DL(1)@(8)
 Else  Set DL(1)=LocRef
 If $D(@DL(1)),$D(@DL(1)@(8.1)) Do
 .Set R=@DL(1)@(8.1)
 .Set:$E(R)'="""" R=""""_R Set:$E(R,$L(R))'="""" R=R_""""
 .Xecute "Set R="_R
 .Set @DL(1)@(8)=R
 Quit
 ;
LDGLOB(Input) 
 New Ref
 Set:Input="*" Ref="LEGEND" Set:Input="P" Ref="RPLPR"
 If "\O\C\A\T\"[(D_Input_D) Set Ref="ORDER"
 Set:Input="Q" Ref="OFFERTE" Set:Input="B" Ref="BON"
 Set:Input="V" Ref="VERKAN" Set:Input="M" Ref="MOEDERB" Set:Input="S" Ref="OFAKT"
 Set:Input="R" Ref="KLREF" Set:Input="Y" Ref="LEVADR" Set:Input="E" Ref="INTRAST"
 Quit $G(Ref)
 ;
LDLOC(Input) 
 New Ref
 Set Ref=$$LDGLOB(Input)
 If "\O\C\A\T\"[(D_Input_D),Ref="ORDER" Set Ref=Input_Ref
 Quit $G(Ref)
 ;
LDINPUT(Ref) 
 New Input
 If "\O\C\A\T\"[(D_$E(Ref)_D),$E(Ref,2,$L(Ref))="ORDER" Set Input=$E(Ref)
 Set:Ref="OFFERTE" Input="Q" Set:Ref="BON" Input="B"
 Set:Ref="OFAKT" Input="S" Set:Ref="VERKAN" Input="V" Set:Ref="MOEDERB" Input="M"
 Set:Ref="KLREF" Input="R" Set:Ref="LEVADR" Input="Y" Set:Ref="INTRAST" Input="E"
 Quit $G(Input)
 ;
SCRNTYP(Input,Taal,ToConc) 
 New I,R,T,Quit,MenuTyp
 Set ToConc=$G(ToConc),FP=140
 Write @F,@F2
 Set T=""
 If "?"'[Input Do
 .Set Quit=0
 .For MenuTyp="ATKSCREENS","ATKAKTIES" Do  Quit:Quit
 ..For I=1:1 Quit:'$D(^MN("D",MenuTyp,"F",I))  Do  Quit:Quit
 ...Set R=^MN("D",MenuTyp,"F",I)
 ...If $P(R,"`",4)=Input Do
 ....If $L($P(R,"`",5)) Xecute "Set $P(R,""`"",5)="_$P(R,"`",5) Quit:'$P(R,"`",5)
 ....If $L($P(R,"`")),"$"""[$E($P(R,"`")) Xecute "Set $P(R,""`"")="_$P(R,"`")
 ....Set T=$P(R,"`"),Quit=1
 Else  Set:$L(Input) T=$$GETTXT("ATK","OGENBL",Taal)
 Set T=T_ToConc,FP=180-$L(T)
 Write @F,@FMTB,$$FLATASCI^vhRtn1(T),@FMTCL
 Quit
 ;
INIT 
 New I,DevTyp
 Use 0:(0::::262144)
 Do MASTER^cQ5
 Do INIT^vhTERMINA
 Set sScr("VT")=1,%J=$$%J^vhRtn1(),ITimeOut=300,STimeOut=300,DefInput="?",Screens=""
 Do SINIT
 Set (I,DevTyp)="ATK"
 For  Set I=$O(^vhDEV(I)) Quit:$E(I,1,$L(DevTyp))'=DevTyp  Set @($E(I,$L(DevTyp)+1,9))=^(I)
 Do CLEAN
 Quit
 ;
SINIT  
 Set LTimeOut=10,HangTime=1
 Quit
 ;
TITEL 
 Set FP=101
 Write @F,@FMTI," ",$$GETTXT("ATK","LVHNV",$S($G(Taal)="":"N",1:Taal))," ",@FMTCL
 If $D(DL(1)),$D(@DL(1)@(1)) Set Input=$$LDINPUT(DL(1)) Do SCRNTYP(Input,Taal)
 Write @F2
 Quit
 ;
STITEL(Groep,Titel,Line) 
 New R
 Set R=$$GETTXT^ATK(Groep,Titel,Taal),FP=Line*100+1 Set:$L(R) R=" "_R_" "
 ;Write @F,@FMTU,$J("",80-$L(R)\2),@FMTu,R,@FMTU,$J("",80-$L($J("",80-$L(R)\2)_R)),@FMTu
 Write @F,@FMTI,$J("",80-$L(R)\2),R,$J("",80-$L($J("",80-$L(R)\2)_R)),@FMTi
 Quit
 ;
CLEAN 
 Kill:$D(%J) ^HULP(%J)
 Write:$D(FCS) @FCS
 Quit
 ;
WRITETXT(Groep,Ref,Taal,Line,Colom) 
 New R,FP
 Set FP=Line*100+1
 Write @F,@F2
 Set R=$$GETTXT(Groep,Ref,Taal),Colom=$G(Colom)
 Set:'Colom Colom=80-$L(R)\2 Set FP=Line*100+Colom
 Write @F,R
 Quit
 ;
NOJOB  
 Set Taal=$G(Taal),FP=201
 Write @F,@F1
 If Taal="" Do
 .Do WRITETXT("ATK","NOJOB1","N",10),WRITETXT("ATK","NOJOB6","N",11)
 .Do WRITETXT("ATK","NOJOB1","F",13),WRITETXT("ATK","NOJOB6","F",14)
 If $L(Taal) Do WRITETXT("ATK","NOJOB1",Taal,12),WRITETXT("ATK","NOJOB6",Taal,13)
 Quit
 ;
NOJOBTXT(Taal) 
 New R,Date,Time,PlusMin
 Set R=$G(^ATK("AMS")) Set:R="" R=$G(^ATK("ASS"))
 If $L(R) Do
 .Set Date=$P($P(R,D),","),Time=$P($P(R,D),",",2),PlusMin=$P(R,D,2)
 .If $$DIFFTIME^vhLib.DataTypes($H,Date_","_Time)<0 Set R=$$GETTXT("ATK","NOJOB2",Taal) Quit
 .Set R=$$GETTXT("ATK","NOJOB3",Taal)_" "
 .If Date>+$H Do
 ..Set R=R_$$LOCASE^vhRtn1($$EXTDATE^vhLib.DataTypes(Date,"DC",Taal))_" "_$$EXTDATE^vhLib.DataTypes(Date)
 ..Set R=R_" "_$$GETTXT("ATK","NOJOB4",Taal)_" "
 .Set R=R_$$EXTTIME^vhLib.DataTypes(Time,"TL")
 .Set:PlusMin R=R_" "_$$GETTXT("ATK","NOJOB5",Taal)
 .Set R=R_","
 Else  Set R=$$GETTXT("ATK","NOJOB2",Taal)
 Quit R
 ;
GETTXT(Groep,Ref,Taal) 
 New R
 Set R=$G(^POP(Groep,"D",Ref,Taal))
 Xecute:$E(R)="""" "Set R="_R
 If $L(R),$G(sScr("VT"))=1 Set R=$$FLATASCI^vhRtn1(R)
 Quit R
 ;
EXIT(SuperV) 
 New C,R,zb
 Quit:$D(NewKLNr) 1
 If SuperV Do
 .Set R=$$GETTXT("ATK","KLEXIT",Taal),R=$P(R,"@1")_Naam_$p(R,"@1",2)
 Else  Set R=$$GETTXT("ATK","EXIT",Taal)
 Set C=$$GETTXT("ATK","JA",Taal)
 Set FP=2201
 Write @F,@F1,!?1,R," : .",!?1,$E(C)," = ",C
 Set FP=2305+$L(R)
 Write @F
 Set R=$$IN^vhKEY("",ITimeOut,1) Set:'$D(zb) R=$E(C)
 Do ADD^vhScherm(22,24)
 Set FP=2301
 Write @F,@F1
 If R'=$E(C),Menu["\K\" Set DefInput="?"
 Else  If '$D(DL(1)) Set DefInput="?"
 Quit R=$E(C)
 ;
NOPRICE() 
 Quit $G(^HULP(%J,"KLINIT","P"))
 ;
SWPRICE 
 New R,Top
 Set ^HULP(%J,"KLINIT","P")='$G(^HULP(%J,"KLINIT","P"))
 Set Top=1
 If $D(DL(1)),$D(@DL(1)) Do
 .Set Top=@DL(1)@(3)-1
 .Quit:'$D(@DL(1)@(8.1))
 .Set R=@DL(1)@(8.1) Set:$E(R)'="""" R=""""_R Set:$E(R,$L(R))'="""" R=R_""""
 .Xecute "Set R="_R
 .Set @DL(1)@(8)=R
 Do ADD^vhScherm(Top,24)
 Quit
 ;
MASK(Data) 
 New NoPrice
 Set NoPrice=$$NOPRICE() Set:NoPrice Data=$$GETTXT^ATK("ATK","NOPRICE",Taal)
 Quit $G(Data)
 ;
WL 
 New WriteLst
 Set WriteLst=1
 Do WL^PROC
 Quit
 ;
TIMEOUT 
 New LTimeOut
 Job TIMEOUT^ATKJOB($G(KLNr),$G(UserName))
 Set LTimeOut=0,R=^|"LVH,LVH"|ATK
 Quit
 ;
CALLBACK 
 New CBNr
 Quit:'$D(^HULP(%J,"KLINIT","@"))
 Set CBNr=^HULP(%J,"KLINIT","@")
 Set CBNr=$$ASK^vhINP($$GETTXT^ATK("ATK","CBNR",Taal)_" : ",20,CBNr,"","","","",ITimeOut)
 Set CBNr=$$TRIMN^vhRtn1(CBNr)
 If 'CBNr Do ADD^vhScherm(22,24) Quit
 Do SCRNTYP("",Taal)
 Set FP=201
 Write @F,@F1
 Do LOGOFF^ATKLOGOF(),WRITETXT("ATK","CALLBACK",Taal,13)
 Hang 2
 Do CLEAN
 Do VT520()
 Job CALL($I,CBNr)
 Halt
 ;
CALL(Device,Number) 
 Open Device
 Use Device
 Hang 15
 Write "AT DT" Write:$L(Number)>2 "0,,," Write Number,$C(13)
 Close Device
 Quit
 ;
SCREENS(Input) 
 If $L(Input),$E(Screens,$L(Screens))'=Input Set Screens=Screens_$S($L(Screens):D,1:"")_Input
 Quit
 ;
STARTUP 
 Do SINIT
 Job STARTUP^ATKJOB()::LTimeOut
 Quit
 ;
VT520(Emulat,TermId) 
 New VT520
 Set VT520=$G(^ATK("VT520"))
 If ("\"_VT520_"\")[("\"_$I_"\"),$D(sScr("VT")),sScr("VT")=1 Do
 .Set Emulat=$G(Emulat),TermId=$G(TermId)
 .Do DECTME^VT520("",Emulat)
 .Do DECTID^VT520("",TermId)
 Quit
 ;
FAX(FaxNr) 
 New R,LcUser,List,Prompt,NoPrice
 Quit:'$$FAXLIST()
 Set:$G(RplKlAtk) FaxNr="760.19.19" Set:FromVol=ToVol&(ToVol="DEV") FaxNr="760.19.19"
 Set List=$$LDINPUT(DL(1)),NoPrice=$$NOPRICE()
 Set FaxNr=$$ASK^vhINP($$GETTXT^ATK("ATK","FAXNR",Taal)_" : ",20,FaxNr,"","","","",ITimeOut)
 Set R=$$UPTRIMA^vhRtn1($TR(FaxNr," ",""))
 If $L(R) Do ADD^vhScherm(22,24) Quit
 Set R=$$TRIMN^vhRtn1(FaxNr)
 If 'R Do ADD^vhScherm(22,24) Quit
 Set LcUser=^HULP(%J,"KLINIT","LcUser") Set:LcUser="" LcUser=UserName
 Job FAX^ATKJOB(%J,KLNr,LcUser,FaxNr,Taal,List,NoPrice,$G(LvhKlRef))::LTimeOut
 If $T Set Time=$P($H,",",2) Do
 .For  Quit:($P($H,",",2)-Time)>LTimeOut!$D(^HULP(%J,"FAX"))
 .If $P($H,",",2)-Time>LTimeOut Goto TIMEOUT
 Set Prompt=$$GETTXT^ATK("ATKFAX",$P(List,U),Taal)_$$GETTXT^ATK("ATK","FAXSEND",Taal)
 Set Prompt=Prompt_"   "_$$GETTXT^ATK("ATKMOEDERB","OK",Taal)
 Do TXT^vhINP(Prompt,"",ITimeOut,1)
 Kill ^HULP(%J,"FAX")
 Quit
 ;
FAXLIST() 
 New Input
 If $D(DL(1)),$D(@DL(1)@(1)),$G(@DL(1)@(9)) Set Input=$$LDINPUT(DL(1))
 Quit "\O\C\A\T\B\S\V\R\E\Q\"[(D_$G(Input)_D)
 ;
SL 
 Set DL(4)=$G(Taal)
 Do SL^PROC
 Kill DL(4)
 Quit
 ;
FIND 
 Do REFRESH
 Set DL(2)="FI",DL(3)=Taal
 Do ML^PROC
 Set DefInput=R
 Kill DL(2),DL(3)
 If $G(DL(1))="LEVADR" Do DISPLEVA^ATKCUST
 Quit
 ;
CHKHOR 
 New
 Do INIT^vhTERMINA
 Set Horolog=$$GETHOR^vhSLVH("ATK")
 Set R=$$^vhTXTPOP("ATK","CHKHOR",,$$FMTDT^vhLib.DataTypes(Horolog))
 Quit
 
EXPORT
 New KlTyp
 Set Dev=0
 Set Dev=$$OPEN^vhDEV(,"VHISIEGEBRUIKERS.txt","W")
 Use Dev
 Write $TR("KLNr;Naam;Regio;Taal;Gebruiker;WachtW;LastUsed",";",$C(9)),!
 Set Key =""
 For  Set Key=$O(^ATK("W",Key)) Quit:Key=""  Do
 . Set Rec=^ATK("W",Key)
 . Set KLNr=$P(Rec,D,1)
 . Set KLId=$G(^KK1(KLNr))
 . Quit:KLId=""
 . Quit:$P(^KKL(KLId,2),D,10) ; non akt
 . Quit:$L($P(^KKL(KLId,0),D,30)) ; non akt of verwijderd
 . Quit:'$P(^KKL(KLId,0),D,20) ; geen regio
 . Set KlTyp=$$GetKlantType^KLANT5(KLNr)
 . Quit:KlTyp="Z" ; Non akt
 . Quit:KlTyp=0 ; Non akt
 . 
 . Quit:+$P(Rec,D,2)=0 ; Nieuw of oude toegang -> alleen nieuw toegelaten
 . Set Dat=""
 . Set Found=0
 . For  Set Dat=$O(^ATK("L",Dat),-1) Quit:Dat=""  Quit:Dat<($H-370)  Do  Quit:Found
 . . Set:$D(^ATK("L",Dat,KLNr,Key))>1 Found=1
 . Set Hulp(KLNr,Found,Key)=$S(Found:Dat,1:"")
 
 Set KLNr=""
 For  Set KLNr=$O(Hulp(KLNr)) Quit:KLNr=""  Do
 . Set Found=$S($D(Hulp(KLNr,1)):1,1:0)
 . Set Key=""
 . For  Set Key=$O(Hulp(KLNr,Found,Key)) Quit:Key=""  Do   
 . . Set KLId=$G(^KK1(KLNr))
 . . Set KLNm=$P(^KKL(KLId,0),D,2)
 . . Set User=$P(Key,D,1)
 . . Set Taal=$P(^KKL(KLId,0),D,9)
 . . Set WachtW=$P(Key,D,2)
 . . Set Regio=$P(^KKL(KLId,0),D,20)
 . . Set LastUsed=Hulp(KLNr,Found,Key)
 . . Write KLNr,*9,KLNm,*9,Regio,*9,Taal,*9,User,*9,WachtW,*9,$$EXTDATE^vhLib.DataTypes(LastUsed,"DK"),!
 Close:Dev'=0 Dev
 Quit