ATKOFF ; Afstand-toegang voor klanten [ 05/31/2002   9:17 AM ]
 ;
AANVRAAG 
 New R
 Quit:$G(DL(1))="OFFERTE"
 Do LDINIT^ATK(Input,Taal)
 Set:'$O(^HULP(%J,"OFFERTE","")) ^HULP(%J,"OFFERTE")=0
 Do MERGNAME^ATKPROD(1)
 Do SCRNTYP^ATK(Input,Taal)
 Do ADD^vhScherm(OFFERTE(3)-1,24)
 Quit
 ;
INPUT(PRNr,AutoAant,IsPakket) 
 New I,K,R,Aantal,MinAant,Verpak,IsStock,PerStuk,Colom,Prijs
 Set AutoAant=$G(AutoAant),IsPakket=$G(IsPakket)
 If '$G(^HULP(%J,"OFFINPUT",PRNr)) Do
 .Job OFFINPUT^ATKJOB(%J,PRNr,KLNr)::LTimeOut
 .If $T Set Time=$P($H,",",2) Do
 ..For  Quit:$P($H,",",2)-Time>LTimeOut!$G(^HULP(%J,"OFFINPUT",PRNr))
 ..If $P($H,",",2)-Time>LTimeOut Goto TIMEOUT^ATK
 If $G(^HULP(%J,"OFFINPUT",PRNr)) Do
 .Set R=$$PAKREF^ATKPROD(PRNr) Set:$L(R) ^HULP(%J,"OFFINPUT",PRNr,"R")=R
 .Merge R=^HULP(%J,"OFFINPUT",PRNr)
 .Set IsStock=$P(R(1),D,20),PerStuk=$P(R("J"),D,13)
 .Set Aantal=$G(^HULP(%J,"OFFINPUT","D",PRNr))
 .If $L(AutoAant) Do
 ..Set:'IsPakket $P(Aantal,D)=AutoAant
 ..Set:IsPakket $P(Aantal,D,2)=$P(Aantal,D,2)+AutoAant
 .Else  Do
 ..Set MinAant=$P(R("J"),D,6),Verpak=$P(R("J"),D,16)
 ..If IsStock Do
 ...Set:$P(R("J"),D,15)<Verpak&$P(R("J"),D,15) Verpak=$P(R("J"),D,15)
 ...Set:$P(R("J"),D,14)<Verpak&$P(R("J"),D,14) Verpak=$P(R("J"),D,14)
 ...Set:PerStuk=1 Verpak=1 Set MinAant=Verpak
 ..Do DISPLAY^vhScherm("ATKOFFERTE","","","","")
 ..Do FIELD^vhScherm("ATKOFFERTE","AANTAL")
 .If $P(Aantal,D)+$P(Aantal,D,2) Do
 ..Set ^HULP(%J,"OFFINPUT","D",PRNr)=Aantal
 ..Merge R=^HULP(%J,"OFFINPUT",PRNr)
 ..Set Prijs=$$PRIJS^ATKPROD(.R,$P(Aantal,D)+$P(Aantal,D,2))
 ..Kill ^HULP(%J,"OFFINPUT","S",PRNr)
 ..If $P(Prijs,D,2) Set ^HULP(%J,"OFFINPUT","S",PRNr)=$P(Prijs,D)
 ..Quit:$P(Aantal,D)+$P(Aantal,D,2)<$G(^HULP(%J,"OFFINPUT",PRNr,"A"))
 ..Set ^HULP(%J,"OFFINPUT",PRNr,"A")=$P(Aantal,D)+$P(Aantal,D,2)
 .Else  Do KILL
 .Do ADD^vhScherm(5,24)
 Quit
 ;
RUBRIEK(Rubr,Value) 
 Set R=$$GETTXT^ATK("ATKOFFERTE",Rubr,Taal)
 If Rubr="PRIJS",$D(R("P")) Set R=R_" ("_$P(R("P"),D,2)_"/"_$P(R("P"),D,3)_")"
 Set R=R_$J("",Colom-$L(R)+1)_$S($L(R):":",1:" ")_" "_Value
 Quit R
 ;
HELPAANT(Type) 
 New R
 Set R=""
 If Verpak>1 Set R=R_$$GETTXT^ATK("ATKOFFERTE","VEELV",Taal)_" "_Verpak
 If Verpak'=MinAant Set:$L(R) R=R_" " Set R=R_$$GETTXT^ATK("ATKOFFERTE","MINAANT",Taal)_" "_MinAant
 Set:R="" Type=Type+1
 If Type=2 Set R="0 "_$$GETTXT^ATK("ATKOFFERTE","DELETE",Taal)
 Quit " "_$G(R)
 ;
ERRAANT() 
 New R
 Set R=$$HELPAANT(1)_" "_$$GETTXT^ATK("ATKOFFERTE","AUB",Taal)_"   "_$$GETTXT^ATK("ATKOFFERTE","OK",Taal)
 Quit R
 ;
HELPRUBR(RubrNr) 
 New R
 If $D(sDir) Do
 .Set R=$$GETTXT^ATK("ATKOFFERTE",$S(RubrNr=1:"ANULING",1:"VORIGING"),Taal)
 .Set R=R_"   "_$$GETTXT^ATK("ATKOFFERTE","EINDEING",Taal)
 Quit $G(R)
 ;
SINIT 
 New I,Rubr
 For I=1:1 Quit:'$D(sScrnDef(I))  Do
 .Quit:$P(sScrnDef(I),"`",4)["H"
 .Set Rubr=$P(sScrnDef(I),"`",15)
 .If $L(Rubr) Do
 ..Set R=$$GETTXT^ATK("ATKOFFERTE",Rubr,Taal)
 ..If Rubr="PRIJS",$D(R("P")) Set R=R_" ("_$P(R("P"),D,2)_"/"_$P(R("P"),D,3)_")"
 .Set:$L(R)>$G(Colom) Colom=$L(R)
 Quit
 ;
SIINIT 
 New I
 If $$NOPRICE^ATK() Do PUTATTR^vhScherm(6,"H","H")
 If IsStock For I=7,9 Do PUTATTR^vhScherm(I,"H","H")
 Do SINIT
 Quit
 ;
SPINIT 
 Do SINIT
 Quit
 ;
SCINIT 
 Set LevAdr=$G(LevAdr),Memo=$G(Memo)
 If '$G(^HULP(%J,"LEVADR")) Set LevAdr=^HULP(%J,"KLINIT",0)
 Else  If ^HULP(%J,"LEVADR")=1 Set LevAdr=^HULP(%J,"LEVADR",1)
 Else  Do REMATTR^vhScherm(6,"D","D")
 Do SINIT
 Quit
 ;
COMMAND 
 New R,IK
 Set:'$G(^HULP(%J,"OFFERTE")) DefInput="N"
 For  Do  Quit:$L(Input)
 .Do REFRESH^ATK
 .If $D(DefInput) Set Input=DefInput Kill DefInput
 .Else  Do
 ..Kill zb
 ..Set DL(3)=-STimeOut
 ..If $D(DL(1)),$D(@DL(1)@(1)) Do
 ...Do SL^ATK
 ..Else  Do
 ...New IK
 ...Set IK(2)=DL(3)
 ...Do IK^PROC
 ..Kill DL(3)
 ..If $G(zb)="",$G(R)="" Set R="-"
 ..Set Input=R
 .If "\-\?\+\*\ENTER\"'[(D_Input_D) Set Input=$$ITRANSL^ATKMENU(Input,Taal)
 .If Input="+",$L($$MAKTIE^ATKMENU($G(DL(1)))) Do MENU^ATKMENU(Input) Set:Input="+" Input=""
 .If "\P\U\=\>\"[(D_Input_D) Set Input=$$ITRANSL^ATKMENU(Input,Taal,1) Quit
 .If '$$CHKMENU^ATKMENU() Do  Quit
 ..If "\-\?\+\*\ENTER\"'[(D_Input_D) Set Input=$$ITRANSL^ATKMENU(Input,Taal,1)
 .If Input="ENTER" Do ENTER
 .If Input="N" Do NIEUWPR()
 .If Input="X" Do DELETE
 .Set Input=""
 Quit
 ;
DELETE 
 New PRNr,Aantal,offerte
 Set PRNr=$$GETPROD^ATKPROD()
 Quit:'PRNr
 Set Aantal=^HULP(%J,"OFFINPUT","D",PRNr),$P(Aantal,D)=""
 If $P(Aantal,D,2) Set ^HULP(%J,"OFFINPUT","D",PRNr)=Aantal
 Merge offerte=@DL(1)
 Else  Do KILL
 If @DL(1)@(9)'=offerte(9) Do
 .Do ADD^vhScherm(5,24)
 Else  If @DL(1)@(6)=offerte(6),offerte(6)-offerte(7)+offerte(3)<$G(sRT) Do EL^PROC
 Quit
 ;
NIEUWPR(PRNr,AutoAant,IsPakket) 
 New R,PakNr,Next,KortText,Prijs,NewPr,LevTerm,IsStock
 Set PRNr=$G(PRNr),AutoAant=$G(AutoAant),IsPakket=$G(IsPakket),PakNr=""
 If 'PRNr Set PRNr=$$SELECT^ATKPROD(Taal),PakNr=$P(PRNr,"#",2)
 If PRNr Do
 .Set DefInput="N",NewPr=1
 .Do INPUT(PRNr,AutoAant,IsPakket)
 .Quit:'$D(^HULP(%J,"OFFINPUT","D",PRNr))
 .For I=1:1 Quit:'$D(^HULP(%J,"OFFERTE",I))  If $P(^HULP(%J,"OFFERTE",I),D,15)=PRNr Set NewPr=0 Quit
 .Kill @DL(1)@(7)
 .If 'NewPr Set @DL(1)@(6)=I Quit
 .Set R=^HULP(%J,"OFFINPUT",PRNr,0),KortText=$P(R,D)
 .Set R=^HULP(%J,"OFFINPUT",PRNr,1),IsStock=$P(R,D,20)
 .Set R=^HULP(%J,"OFFINPUT",PRNr,"P"),Prijs=$P(R,D,1,3)
 .Set R=^HULP(%J,"OFFINPUT",PRNr,"J"),LevTerm=$S(IsStock:0,1:$P(R,D,7)+1+($H#7<4))
 .Set R=D_KortText_"\\\"_LevTerm_D_Prijs_D_Prijs_"\\\\"_PRNr_D
 .Set Next=^HULP(%J,"OFFERTE")+1,^HULP(%J,"OFFERTE")=Next,^HULP(%J,"OFFERTE",Next)=R
 .Set @DL(1)@(6)=Next
 If PakNr Do PAKKET(PakNr)
 Quit
 ;
PAKKET(PakNr) 
 New R,AutoAant,AantPak,OldAant,ProdAant,PRNr,Colom,PakNaam
 If '$D(^HULP(%J,"OFFINPUT","P",PakNr)) Do
 .Set ^HULP(%J,"OFFINPUT","P")=0
 .Job OFPAKKET^ATKJOB(%J,PakNr)::LTimeOut
 .If $T Set Time=$P($H,",",2) Do
 ..For  Hang HangTime Quit:$P($H,",",2)-Time>LTimeOut!$G(^HULP(%J,"OFFINPUT","P"))
 ..If $P($H,",",2)-Time>LTimeOut Goto TIMEOUT^ATK
 .Set $P(^HULP(%J,"OFFINPUT","P",PakNr),D)=""
 If $D(^HULP(%J,"OFFINPUT","P",PakNr)) Do
 .Set R=^HULP(%J,"OFFINPUT","P",PakNr),(AantPak,OldAant)=$P(R,D),PakNaam=$P(R,D,2)
 .Do DISPLAY^vhScherm("ATKOFFPAK"),FIELD^vhScherm("ATKOFFPAK","AANTPAK"),ADD^vhScherm(18,24)
 .Set:AantPak=0 AantPak=""
 .If $L(AantPak),'AantPak Quit
 .Quit:AantPak=OldAant
 .Set ^HULP(%J,"OFFINPUT","P",PakNr)=AantPak
 .Set PRNr=""
 .For  Set PRNr=$O(^HULP(%J,"OFFINPUT","P",PakNr,PRNr)) Quit:'PRNr  Do
 ..Set ProdAant=+^HULP(%J,"OFFINPUT","P",PakNr,PRNr),AutoAant=ProdAant*-OldAant
 ..Do NIEUWPR(PRNr,AutoAant,PakNr)
 ..Set AutoAant=ProdAant*AantPak
 ..Do NIEUWPR(PRNr,AutoAant,PakNr)
 .Do ADD^vhScherm(5,24)
 Quit
 ;
KILL 
 Kill ^HULP(%J,"OFFINPUT","D",PRNr),^HULP(%J,"OFFINPUT","S",PRNr)
 For I=1:1 Quit:'$D(^HULP(%J,"OFFERTE",I))  Set R=^HULP(%J,"OFFERTE",I) Quit:$P(R,D,15)=PRNr
 Quit:'$D(^HULP(%J,"OFFERTE",I))
 Kill @DL(1)@(7)
 Set @DL(1)@(6)=I
 Set:@DL(1)@(6)>1 @DL(1)@(6)=@DL(1)@(6)-1
 Set @DL(1)@(9)=@DL(1)@(9)-1,^HULP(%J,"OFFERTE")=^HULP(%J,"OFFERTE")-1
 Kill ^HULP(%J,"OFFERTE",I)
 For I=I+1:1 Quit:'$D(^HULP(%J,"OFFERTE",I))  Do
 .Set ^HULP(%J,"OFFERTE",I-1)=^HULP(%J,"OFFERTE",I)
 .Kill ^HULP(%J,"OFFERTE",I)
 Quit
 ;
ENTER 
 New PRNr
 Set PRNr=$$GETPROD^ATKPROD()
 Quit:'PRNr
 Do INPUT(PRNr)
 Quit
 ;
BOLD(Test) 
 Set Test=$G(Test,Selected)
 Quit Test&'$D(^HULP(%J,"COPYOFFERTE"))
 ;
STAFFEL(Prijs) 
 If Selected,$D(^HULP(%J,"OFFINPUT","S",PRNr)) Set Prijs=$P(^HULP(%J,"OFFINPUT","S",PRNr),D)
 Quit $$MASK^ATK(Prijs)
 ;