DCOFFP ;AFDRUKKEN OFFERTES (Prijslijsten) [ 01/17/2002   4:06 PM ]
 ;
 Do FTITEL,FHEADER,BODY,VOORW,LFOOTER,PPRINT
 Quit
 ;
FN(Number,Fraction,Format) 
 Quit $$FN^DCALG(Number,Fraction,$G(Format))
 ;
PASTEB(R,AddBlank) 
 New NewPage
 Set NewPage="Do FOOTER^"_$ZN_",TITEL^"_$ZN_",HEADER^"_$ZN
 Do PASTEB^DCALG(R,NewPage,$G(AddBlank))
 Quit
 ;
BLOCK(R) 
 Do BLOCK^DCALG(R)
 Quit
 ;
CACHE(R) 
 Do CACHE^DCALG(R)
 Quit
 ;
PASTE(Page,Line,Text,BPos,EPos,Attr) 
 Do PASTE^DCALG(Page,Line,Text,BPos,EPos,Attr)
 Quit
 ;
 ; Afdruk body
BODY 
 New B,R,BCount,OLNr,HoofdGr,Groep,SubGroep,TSubGrp,SelTyp,SelLnr,KortTxtC,Paste,OffRef
 Set R=^KOFKL(KLNr,"F",OFFNr,1),OffRef=$P(R,D,3)
 If $L(OffRef) Do
 .Do CACHE(L("B","B"))
 .Set T=$$TXT("Ref")_": "_OffRef
 .Do PASTE(PCount,LCount,T,3,"","U")
 .Do CACHE(L("B","B"))
 Set BCount=0,SubGroep=""
 Set OLNr=100
 For  Set OLNr=$O(^KOFKL(KLNr,"F",OFFNr,OLNr)) Quit:OLNr=""!(OLNr'?.N)  Do
 .Set Paste=$$OFFERTE^DCDETAIL(OFFNr,OLNr)
 .If Paste Do PASTEB(L("B","B"),1)
 If $D(B) Do PASTEB(L("B","B"),1)
 Set HoofdGr=10000
 For  Set HoofdGr=$O(^KOFKL(KLNr,"F",OFFNr,HoofdGr)) Quit:"ZZZZ"[$E(HoofdGr,1,4)  Do
 .Set Groep=""
 .For  Set Groep=$O(^KOFKL(KLNr,"F",OFFNr,HoofdGr,Groep)) Quit:Groep=""  Do
 ..If Groep=0 Set Paste=$$OFFERTE^DCDETAIL(OFFNr,HoofdGr) Do:Paste PASTEB(L("B","B",1)) Quit
 ..Set SubGroep=""
 ..For  Set SubGroep=$O(^KOFKL(KLNr,"F",OFFNr,HoofdGr,Groep,SubGroep)) Quit:SubGroep=""  Do
 ...If SubGroep=0 Set Paste=$$OFFERTE^DCDETAIL(OFFNr,HoofdGr,Groep) Do:Paste PASTEB(L("B","B",1)) Quit
 ...Set PRNr=$O(^KOFKL(KLNr,"F",OFFNr,HoofdGr,Groep,SubGroep,""))
 ...If PRNr=0 Set Paste=$$OFFERTE^DCDETAIL(OFFNr,HoofdGr,Groep,SubGroep) Do:Paste PASTEB(L("B","B",1)) Quit
 ...Kill ^HULP($J,"z")
 ...Set PRNr=""
 ...For  Set PRNr=$O(^KOFKL(KLNr,"F",OFFNr,HoofdGr,Groep,SubGroep,PRNr)) Quit:PRNr=""  Do
 ....Set KortTxtC=$$COMPR^PRODUKT(PRNr)
 ....Set ^HULP($J,"z",KortTxtC)=PRNr
 ...Set KortTxtC=""
 ...For  Set KortTxtC=$O(^HULP($J,"z",KortTxtC)) Quit:KortTxtC=""  Do
 ....Set PRNr=^HULP($J,"z",KortTxtC)
 ....Set Paste=$$OFFERTE^DCDETAIL(OFFNr,HoofdGr,Groep,SubGroep,PRNr)
 ....If Paste Do PASTEB(L("B","B",1))
 Set SelTyp="ZZZZ"
 For  Set SelTyp=$O(^KOFKL(KLNr,"F",OFFNr,SelTyp)) Quit:SelTyp=""  Do
 .Set SelLnr=0
 .For  Set SelLnr=$O(^KOFKL(KLNr,"F",OFFNr,SelTyp,SelLnr)) Quit:SelLnr=""  Do
 ..Set Paste=$$OFFERTE^DCDETAIL(OFFNr,SelTyp,SelLnr)
 ..If Paste Do PASTEB(L("B","B"),1)
 If $D(B) Do PASTEB(L("B","B"),1)
 Quit
 ;
 ; Afdruk hoofding (volgende bladzijden)
HEADER 
 New T
 If $D(VPerfoT) New VPerfo Set VPerfo=VPerfoT
 Do CACHE(L("B","F"))
 Do CACHE(L("B","B"))
 Set T=$$TXT("Art")
 Do PASTE(PCount,LCount,T,3,"","")
 Set T=$$TXT("LevTrm")
 Do PASTE(PCount,LCount,T,"",51,"")
 Set T=$$TXT("Minim")
 Do PASTE(PCount,LCount,T,"",60,"")
 Set T=$$TXT("Prijs") If OffMunt'="MTL" Set T=T_" "_OffMunt
 Do PASTE(PCount,LCount,T,"",77,"")
 If NetBrutP Do
 .Do CACHE(L("B","B"))
 .Set T=$$TXT("Kort")
 .Do PASTE(PCount,LCount,T,"",77,"")
 If $D(L("B","S")) Do CACHE(L("B","S"))
 Quit
 ;
 ; Afdruk hoofding (eerste blad)
FHEADER 
 New T
 Do HEADER
 Set BCount=0
 Set T="" For I=1:1:5 Do  ; Openingstekst op offerte
 .If $G(^KBA(22,"O",Taal,I))="" Quit
 .Set T=^KBA(22,"O",Taal,I)
 .Set T=T_$J("",48-$L(T))_"`3`42`CT"
 .Do BLOCK(T)
 If $L(T) Do PASTEB(L("B","B"),1)
 Quit
 ;
 ; Afdruk titel (volgende blazijden)
TITEL 
 New OffDat,KlantInd,R,T,Blank,Titel,Allign,VPerfo
 New Aanspr,Naam,Woonpl
 Do PPRINT
 Set PCount=PCount+1,LCount=0
 If $G(%Fax),$G(%FaxNr) Set LCount=$$FLINES^vhFAX("LOGO_ORD")
 Set R=^KOFKL(KLNr,"F",OFFNr,1),OffDat=$TR($P(R,D,2),".","-")
 Set KlantInd=^KK1(KLNr),R=^KKL(KlantInd,0)
 Set Naam=$P(R,D,2),Aanspr=$P(R,D,4),Woonpl=$P(R,D,7)
 For Blank=1:1:6 Do CACHE("")
 Set T=$$FIRMANM^DCALG("K",KLNr)
 Do PASTE(PCount,Blank-1,T,40,"","")
 Do PASTE(PCount,Blank,Woonpl,40,"","")
 Set Titel=$$TXT("Offer"_OffTyp),Allign=$L(Titel)
 Set T=$$TXT("Date") Set:$L(T)>Allign Allign=$L(T)
 Do PASTE(PCount,Blank,T,2,"","")
 Do PASTE(PCount,Blank,OffDat,Allign+4,"","")
 Set T=Titel_$J("",Allign-$L(Titel)+2)_$TR($FN(OFFNr,","),",",".")
 If $G(%Fax),$G(%FaxNr) Set T=" "_T_" "
 Do PASTE(PCount,Blank-1,T,2-$G(%Fax),"","B")
 If PCount>1 Do
 .Set T=$$TXT("Vervg")_" ("_(PCount-1)_")"
 .Do PASTE(PCount,Blank,T,"",79,"")
 Quit
 ;
 ; Afdruk titel (eerste blad)
FTITEL 
 New OffDat,KlantInd,R,T,Blank,Titel,Allign,VPerfo
 New Aanspr,Naam,Toenaam,Straat,PostNr,Woonpl,Land
 Set PCount=PCount+1,LCount=0
 If $G(%Fax),$G(%FaxNr) Set LCount=$$FLINES^vhFAX("LOGO_ORD")
 Set R=^KOFKL(KLNr,"F",OFFNr,1),OffDat=$TR($P(R,D,2),".","-")
 Set KlantInd=^KK1(KLNr),R=^KKL(KlantInd,0)
 Set Naam=$P(R,D,2),Toenaam=$P(R,D,3),Aanspr=$P(R,D,4)
 Set Straat=$P(R,D,5),PostNr=$P(R,D,6),Woonpl=$P(R,D,7)
 Set Land=$$LAND^vhRtn1($P(R,D,8))
 Do VHPB^DCALG(PCount,.Blank)
 Set T=$$FIRMANM^DCALG("K",KLNr)
 If KLNr=8545,$L(T),$L(Toenaam) Set R=T,T=Toenaam,Toenaam=R
 Do PASTE(PCount,AdresPos,T,40,"","")
 If '$L(Toenaam) Do
 .Do PASTE(PCount,AdresPos+1,Straat,40,"","")
 .Do PASTE(PCount,AdresPos+3,PostNr_"   "_Woonpl,40,"","")
 .If Land'="BE" Do PASTE(PCount,AdresPos+4,$$LAND^vhRtn1(Land,2,Taal),40,"","")
 If $L(Toenaam) Do
 .Do PASTE(PCount,AdresPos+1,Toenaam,40,"","")
 .Do PASTE(PCount,AdresPos+2,Straat,40,"","")
 .Do PASTE(PCount,AdresPos+4,PostNr_"   "_Woonpl,40,"","")
 .If Land'="BE" Do PASTE(PCount,AdresPos+5,$$LAND^vhRtn1(Land,2,Taal),40,"","")
 Set Titel=$$TXT("Offer"_OffTyp),Allign=$L(Titel)
 Set T=$$TXT("Date") Set:$L(T)>Allign Allign=$L(T)
 Do PASTE(PCount,Blank-1,T,2,"","")
 Do PASTE(PCount,Blank-1,OffDat,Allign+4,"","")
 Set T=Titel_$J("",Allign-$L(Titel)+2)_$TR($FN(OFFNr,","),",",".")
 If $G(%Fax),$G(%FaxNr) Set T=" "_T_" "
 Do PASTE(PCount,Blank-3,T,2-$G(%Fax),"","B")
 Do VHPD^DCALG(PCount,.Blank,.VH)
 Quit
 ;
 ; Afdruk afsluiting (eerste bladzijden)
FOOTER 
 Set C(PCount,LCount)=C(PCount,LCount)_P("D",0)
 For I=LCount+1:1:MaxLines-1 Do CACHE(L("B","B"))
 Do CACHE(L("B","L"))
 Set T=" "_$$TXT("Vervt")_" "
 Do PASTE(PCount,LCount,T,"",77,"")
 Set C(PCount,LCount)=P("D",1)_C(PCount,LCount)
 Quit
 ;
 ; Afdruk afsluiting (laatste blad)
LFOOTER 
 Do CACHE(L("A","L"))
 Quit
 ;
 ; Afdruk van de voorwaarden
VOORW 
 New B,I,R,R1,T,BCount,Land,%KontKrt,TKontKrt,BetVw,Rembours,VoorBet,LeverVw,GeldVan,GeldTot,LTemp,VPerfoT
 Set VPerfoT=VPerfo
 New VPerfo
 Set BCount=0
 Set R=^KOFKL(KLNr,"F",OFFNr,1),GeldVan=$TR($P(R,D,2),".","-"),GeldTot=$TR($P(R,D,16),".","-")
 Set KlantInd=^KK1(KLNr),R=^KKL(KlantInd,0),Land=$$LAND^vhRtn1($P(R,D,8)),%KontKrt=$P(R,D,17),BetVw=$P(R,D,18)
 Set R=^KKL(KlantInd,2),TKontKrt=$P(R,D,2)
 Set R=^KKL(KlantInd,3),Rembours=$P(R,D),VoorBet=$P(R,D,2),LeverVw=$P(R,D,3)
 Set T=$$TXT("Geldig")_" "
 If $L(GeldTot)
 .Set T=T_$$TXT("Geldig",4)_" "_GeldVan
 .Set T=T_" "_$$TXT("Geldig",5)_" "_GeldTot
 Else  Set T=T_$$TXT("Dagen")
 Do BLOCK(T_"`3``B"),BLOCK("")
 Do WRAP^vhRtn1(75,"^KBA(22,""S"",Taal,","",.I,4) ; Tekst op offerte
 For I=1:1:I Do BLOCK(I(I))
 If I Do BLOCK("")
 Set R=$$LEVVW^KLANT(LeverVw,Taal) ; Leveringsvoorwaarde
 If $L(R) Do
 .Set T=$$TXT("LevVw")
 .Set R=T_"`3``U\:`"_($L(T)+3)_D_R
 .For I=1:1:$L(R,"#") Set $P(R,"#",I)=$P(R,"#",I)_"`"_($L(T)+5)
 .For I=1:1:$L(R,"#") Do BLOCK($P(R,"#",I))
 .Do BLOCK("")
 Set T=$$TXT("BetVw") ; Betalingsvoorwaarde
 Set R=$$BETVW^KLANT(BetVw,%KontKrt,TKontKrt,Rembours,VoorBet,Taal)
 Set R=T_"`3``U\:`"_($L(T)+3)_D_R
 For I=1:1:$L(R,"#") Set $P(R,"#",I)=$P(R,"#",I)_"`"_($L(T)+5)
 For I=1:1:$L(R,"#") Do BLOCK($P(R,"#",I))
 Do BLOCK("")
 If 0,Land="NL" Do  ; Deze voorwaarde is niet meer nodig afgedrukt
 . Do BLOCK($P($T(TVwNl1),U,2)),BLOCK($P($T(TVwNl2),U,2)),BLOCK("") ; Export
 Do MEMO^DCALG("P")
 If Prefs("OrdBev") Do  ; ok voor order
 .Set T=$$TXT("GVOrd") Do BLOCK(T_"``53")
 .Set T=$$TXT("Date")_" :" Do BLOCK(T_"``53")
 .Set T=$$TXT("HandT")_" :" Do BLOCK(T_"``53")
 .Do BLOCK("")
 If B(BCount)="" Kill B(BCount) Set BCount=BCount-1
 Set LTemp=L("B","S") If P("Type")="CA"!(P("Type")="BL")!(P("Type")="TK") Kill L("B","S")
 If LCount+BCount+2>MaxLines Do FOOTER,TITEL,HEADER
 Set L("B","S")=LTemp
 Set C(PCount,LCount)=C(PCount,LCount)_P("D",0)
 If P("Type")'="CA",P("Type")'="BL",P("Type")'="TK" For I=LCount+1:1:MaxLines-2-BCount Do CACHE(L("B","B"))
 Do CACHE(L("V","F"))
 Set C(PCount,LCount)=P("D",1)_C(PCount,LCount)
 Do PASTEB(L("V","B"))
 Quit
 ;
 ; Afdrukken van een bladzijde
PPRINT 
 Do PPRINT^DCPRINT(PCount)
 Kill C(PCount)
 Quit
 ;
 ; Ophalen taalafhankelijke tekst
TXT(Ref,Piece) 
 If '$D(Piece) Set Piece=2
 Quit $P($P($T(@("T"_Ref)),U,Piece),D,$F("NFDE",Taal)-1)
 ;
TOfferP ;OFFERTE\OFFRE\ANGEBOT\OFFER
TDate ;Datum\Date\Datum\Date
TRef ;Ref\Ref\Ref\Ref
TVervg ;vervolg\suite\fortsetzung\continue
TVervt ;vervolgt\à suivre\fortgesetzt\t.b.continued
TArt ;Artikel\Article\Artikel\Article
TMinim ;Minim.\Minim.\Mindest\M Quant
TPrijs ;E.Prijs\Prix U\E.Preis\U.Price
TLevTrm ;Termijn\Delai\Termin\Deliv
TKort ;Korting\Remise\Rabat\Discount
TStock ;Stock\Stock\Lager\Stock
TWeek ;wk\se\wo\we
TVwNl1 ;Verkopen en leveringen in Nederland volgens BELUNED-condities, gedeponeerd
TVwNl2 ;bij de Kamer van Koophandel en Fabrieken te 's Gravenhage onder nummer 1287.
TLevVw ;Leveringsvoorwaarde\Conditions de livraison\Lieferbedingung\Betalingsvoorwaarde
TBetVw ;Betalingsvoorwaarde\Conditions de paiement\Zahlungsbedingung\Betalingsvoorwaarde
TGVOrd ;Goed voor order\Bien pour commande\Gut fur auftrag\Ok to order
TGeldig ;Geldig\Valable\Gueltig\Valid;op\le\den\on;van\du\vom\from;tot\jusqu a\bis\until
TDagen ;30 dagen\30 jours\30 tage\30 days
THandT ;handtekening\signature\unterschrift\sign
TKlRef ;Uw ref\Votre ref\Ihre ref\Uw ref