DCTRANSP ;AFDRUKKEN TRANSPORTAANVRAAG [ 11/17/2003  9:39 AM ]
 ;
 ; Het afdrukken van een transportaanvraag kan met volgende oproep --> Do PRINT^DCTRANSP(TranspNr)
 ;
VERWERK() 
 Quit
 ;
FN(Number,Fraction,Format) 
 Quit $$FN^DCALG(Number,Fraction,$G(Format))
 ;
PASTEB(R,AddBlank) 
 New NewPage
 Set NewPage="Do TITEL^"_$ZN_",HEADER^"_$ZN
 Do PASTEB^DCALG(R,NewPage,$G(AddBlank))
 Quit
 ;
BLOCK(R) 
 Do BLOCK^DCALG(R)
 Quit
 ;
CACHE(R) 
 Do CACHE^DCALG(R)
 Quit
 ;
PASTE(Page,Line,Text,BPos,EPos,Attr) 
 Do PASTE^DCALG(Page,Line,Text,BPos,EPos,Attr)
 Quit
 ;
PASTER(Value,From,To) 
 Do PASTER^DCALG(Value,$G(From),$G(To))
 Quit
 ;
 ; Afdruk body
BODY
 New %J,B,I,R,T,BCount,GroepNr,KLNr,Naam,ToeNaam,Adres,PostNr,Woonpl,Land,Munt,SortKey,KlTaal,VrachtKost
 New Gewicht,Rembours,KlantOpm,ORDNr,BONNr,FANr,PROFNr,ContactType,ContactRef,Paletten,Collo,LangGoed,KPaletten,BPaletten,WPaletten
 New lbKenAnk,KenAnk,ObjKenAnk,IRef,Referenties,FSepLin,LSepLine
 Set %J=$$%J^vhRtn1()
 Do SortBody(%J,TranspNr)
 Set SortKey=""
 For  Set SortKey=$O(^HULP(%J,SortKey)) Quit:SortKey=""  Do
 . Set GroepNr=^HULP(%J,SortKey)
 . Kill B,KlantOpm
 . Set LSepLine=L("B","S"),R=^TRANSP("D",TranspNr,"D",GroepNr),ContactRef=$P(R,D),ContactType=$P(R,D,6),Rembours=$P(R,D,2),VrachtKost=$P(R,D,7)
 . Set:ContactType="" ContactType="K"
 . Set Gewicht=$P(R,D,3),TotGewicht=TotGewicht+Gewicht,I=1
 . Set:Gewicht $P(B(I),D,3)=$$EXTNUM^vhLib.DataTypes(Gewicht,0,".T",1)_"``"_(51-VFax)
 . Set R=$$LEVADR^TRANSPL(TranspNr,GroepNr)
 . Set Naam=$P(R,D,2),ToeNaam=$P(R,D,3),Adres=$P(R,D,5)
 . Set PostNr=$P(R,D,6),Woonpl=$P(R,D,7),Land=$$LAND^vhRtn1($P(R,D,8)),KlTaal=$P(R,D,9) Set:KlTaal="" KlTaal="N"
 . Set $P(B(I),D)=$E($$FIRMANM^DCALG(ContactType,ContactRef,Naam,"Z",Land),1,25)_"`"_(5-VFax)
 . Set Munt=$$MUNT^TRANSPZ(ContactType,ContactRef)
 . Set:Munt="MTL" Munt=$P($G(^KUL(ContactRef,"F",GroepNr,1)),D,18)
 . Set:Rembours $P(B(I),D,4)=$$EXTNUM^vhLib.DataTypes(Rembours,0,".T",2)_Munt_"``"_(65-VFax)
 . Set:$L(ToeNaam) I=I+1,$P(B(I),D)=$E(ToeNaam,1,25)_"`"_(5-VFax)
 . Set I=I+1,$P(B(I),D)=$E(Adres,1,25)_"`"_(5-VFax)
 . Set I=I+1,$P(B(I),D)=$E(PostNr_$S($L(PostNr):" ",1:"")_Woonpl,1,25)_"`"_(5-VFax)
 . Set:Land'="BE" I=I+1,$P(B(I),D)=$E($$LAND^vhRtn1(Land,2,KlTaal),1,25)_"`"_(5-VFax)
 . Set Paletten=$G(^TRANSP("D",TranspNr,"D",GroepNr,"Q","E"))
 . Set WPaletten=$G(^TRANSP("D",TranspNr,"D",GroepNr,"Q","W"))
 . Set Collo=$G(^TRANSP("D",TranspNr,"D",GroepNr,"Q","C"))
 . Set LangGoed=$G(^TRANSP("D",TranspNr,"D",GroepNr,"Q","L"))
 . Set KPaletten=$G(^TRANSP("D",TranspNr,"D",GroepNr,"Q","P"))
 . Set BPaletten=$G(^TRANSP("D",TranspNr,"D",GroepNr,"Q","B"))
 . Set KlantOpm(1)=$$TXT("VrachtK")_": "_^RES("TRANSPORT","PI","VRACHTKOST","D",$S(VrachtKost="":"NV",1:VrachtKost),Taal)_"~"
 . If 'Paletten,'Collo,'LangGoed,'KPaletten,'BPaletten,'WPaletten
 . Else  Do
 . . Set KlantOpm(1)=KlantOpm(1)_$$TXT("VVolume")_":~"
 . . If Paletten Set KlantOpm(1)=KlantOpm(1)_Paletten_" "_$$TXT($S(Paletten=1:"Palet",1:"Paletten"))_", "
 . . If WPaletten Set KlantOpm(1)=KlantOpm(1)_WPaletten_" "_$$TXT($S(WPaletten=1:"WPalet",1:"WPaletten"))_", "
 . . If Collo Set KlantOpm(1)=KlantOpm(1)_Collo_" "_$$TXT($S(Collo=1:"Collie",1:"Collo"))_", "
 . . Do:LangGoed
 . . . Set KlantOpm(1)=KlantOpm(1)_$$TXT("LangGoed")_" "_$P(LangGoed,D)
 . . . Set KlantOpm(1)=KlantOpm(1)_$S($L($P(LangGoed,D,2)):" "_$$TXT("Van")_" "_$P(LangGoed,D,2)_" "_$$TXT("Meter"),1:"")
 . . . Set KlantOpm(1)=KlantOpm(1)_", "
 . . If KPaletten Set KlantOpm(1)=KlantOpm(1)_KPaletten_" "_$$TXT($S(Paletten=1:"KPalet",1:"KPaletten"))_", "
 . . If BPaletten Set KlantOpm(1)=KlantOpm(1)_BPaletten_" "_$$TXT($S(Paletten=1:"BPalet",1:"BPaletten"))_", "
 . . Set $E(KlantOpm(1),$L(KlantOpm(1))-1,$L(KlantOpm(1)))=".~"
 . Set KlantOpm(1)=KlantOpm(1)_$G(^TRANSP("D",TranspNr,"D",GroepNr,"T"))
 . Set R=$G(^TRANSP("D",TranspNr,"D",GroepNr,"A"))
 . For I=24,25 If $L($P(R,D,I)) Set:$L(KlantOpm(1)) KlantOpm(1)=KlantOpm(1)_"~" Set KlantOpm(1)=KlantOpm(1)_$P(R,D,I)
 . Set IRef=2
 . Do:$L(KlantOpm(1))
 . . For  Quit:$E(KlantOpm(1),$L(KlantOpm(1)))'="~"  Set $E(KlantOpm(1),$L(KlantOpm(1)))=""
 . . Do GETWRAP^vhBIGEDIT("KlantOpm",25,.KlantOpm,"G","~","")
 . . For I=1:1:KlantOpm Set $P(B(I),D,5)=$P(KlantOpm(I),"`",5)_"`"_(69-VFax)
 . . Set IRef=KlantOpm+1
 . Set ORDNr="",I=0,Referenties=""
 . For  Set ORDNr=$O(^TRANSP("D",TranspNr,"D",GroepNr,"O",ORDNr)) Quit:ORDNr=""  Do
 . . Set I=I+1
 . . If I'>IRef Do
 . . . Do PutRefIntoB(.B,I,", "_P("B",1)_$S($L(DocTypes)>1:"o",1:"")_P("B",0)_$$EXTNUM^vhLib.DataTypes(ORDNr,0,".",0),$L(DocTypes)=1)
 . . Else  Do
 . . . Set Referenties=Referenties_", "_P("B",1)_$S($L(DocTypes)>1:"o",1:"")_P("B",0)_$$EXTNUM^vhLib.DataTypes(ORDNr,0,".",0)
 . . . If $L(Referenties,",")=7 Set IRef=IRef+1 Do PutRefIntoB(.B,IRef,Referenties) Set Referenties=""
 . Set BONNr=""
 . For  Set BONNr=$O(^TRANSP("D",TranspNr,"D",GroepNr,"B",BONNr)) Quit:BONNr=""  Do
 . . Set I=I+1
 . . If I'>IRef Do
 . . . Do PutRefIntoB(.B,I,", "_P("B",1)_$S($L(DocTypes)>1:"l",1:"")_P("B",0)_$$EXTNUM^vhLib.DataTypes(BONNr,0,".",0),$L(DocTypes)=1)
 . . Else  Do
 . . . Set Referenties=Referenties_", "_P("B",1)_$S($L(DocTypes)>1:"l",1:"")_P("B",0)_$$EXTNUM^vhLib.DataTypes(BONNr,0,".",0)
 . . . If $L(Referenties,",")=7 Set IRef=IRef+1 Do PutRefIntoB(.B,IRef,Referenties) Set Referenties=""
 . Set FANr=""
 . For  Set FANr=$O(^TRANSP("D",TranspNr,"D",GroepNr,"F",FANr)) Quit:FANr=""  Do
 . . Set I=I+1
 . . If I'>IRef Do
 . . . Do PutRefIntoB(.B,I,", "_P("B",1)_$S($L(DocTypes)>1:"f",1:"")_P("B",0)_$$EXTNUM^vhLib.DataTypes(FANr,0,".",0),$L(DocTypes)=1)
 . . Else  Do
 . . . Set Referenties=Referenties_", "_P("B",1)_$S($L(DocTypes)>1:"f",1:"")_P("B",0)_$$EXTNUM^vhLib.DataTypes(FANr,0,".",0)
 . . . If $L(Referenties,",")=7 Set IRef=IRef+1 Do PutRefIntoB(.B,IRef,Referenties) Set Referenties=""
 . Set PROFNr=""
 . For  Set PROFNr=$O(^TRANSP("D",TranspNr,"D",GroepNr,"Z",PROFNr)) Quit:PROFNr=""  Do
 . . Set I=I+1
 . . If I'>IRef Do
 . . . Do PutRefIntoB(.B,I,", "_P("B",1)_$S($L(DocTypes)>1:"p",1:"")_P("B",0)_$$EXTNUM^vhLib.DataTypes(PROFNr,0,".",0),$L(DocTypes)=1)
 . . Else  Do
 . . . Set Referenties=Referenties_", "_P("B",1)_$S($L(DocTypes)>1:"p",1:"")_P("B",0)_$$EXTNUM^vhLib.DataTypes(PROFNr,0,".",0)
 . . . If $L(Referenties,",")=7 Set IRef=IRef+1 Do PutRefIntoB(.B,IRef,Referenties) Set Referenties=""
 . If $L(Referenties) Set IRef=IRef+1 Do PutRefIntoB(.B,IRef,Referenties,1)
 . Set lbKenAnk=$S(ContactType="K":##class(BL.Flow.Cons.TransportData).GetKennisAnker(ContactRef),1:""),HeeftKenAnk=$LL(lbKenAnk)
 . Do:HeeftKenAnk
 . . Set LSepLine=L("B","K","L"),BCount=$O(B(""),-1)
 . . Do BLOCK(L("B","K","F"))
 . . For  Kill KenAnk Set KenAnk=$LI(lbKenAnk) Quit:KenAnk=""  Do  Quit:'$LL(lbKenAnk)
 . . . Set lbKenAnk=$LI(lbKenAnk,2,99)
 . . . Set ObjKenAnk=##class(Derde.Kennis.Kennis).%OpenId(KenAnk)
 . . . Quit:'$IsObject(ObjKenAnk)
 . . . Set KenAnk(1)=$TR(ObjKenAnk.Msg,$C(13,10)," ")
 . . . Quit:KenAnk(1)=""
 . . . Do GETWRAP^vhBIGEDIT("KenAnk",60,.KenAnk,"G","~","")
 . . . For I=1:1:KenAnk Do
 . . . . Set R=L("B","K","B")
 . . . . Do PASTER($P(KenAnk(I),"`",5),31-VFax)
 . . . . Do BLOCK(R)
 . Set BCount=$O(B(""),-1)
 . Do PASTEB(P("C",1)_L("B","B")_P("C",0))
 . Do CACHE("")
 . Do:$O(^HULP(%J,SortKey))'="" PASTE(PCount,LCount,LSepLine,1,"","C")
 Kill ^HULP(%J)
 Quit
 ;
 ; Invullen van de referenties in de B-local
PutRefIntoB(B,IRef,Referenties,ExtraSpace)
 New RefPieces,From,To
 Set $E(Referenties,1,2)="",RefPieces=$L(Referenties,", ")
 Set From=33-VFax,To=30+(RefPieces*10)-VFax
 If $L(DocTypes)=1 Do
 . Set:RefPieces>1!$G(ExtraSpace) From=From+1
 . Set To=To-RefPieces+1
 Set $P(B(IRef),D,2)=Referenties_"`"_From_"`"_To
 Quit
 ;
 ; Rangschikken volgens leveringsadres
SortBody(%J,TranspNr)
 New R,GroepNr,SortKey,Node,KLNr
 Kill ^HULP(%J)
 Set GroepNr=""
 For  Set GroepNr=$O(^TRANSP("D",TranspNr,"D",GroepNr)) Quit:GroepNr=""  Do
 . Set SortKey="",KLNr=$P($G(^KU1(GroepNr,"F")),"\")
 . Do:KLNr
 . . Set Node=$$NODE^FLOWBON(GroepNr)
 . . Set R=^KUL(KLNr,Node,GroepNr,3)
 . . Set:$P(R,"\",2)="" R=^KKL(^KK1(KLNr),0)
 . . Set SortKey=$$UPTRIMAN^vhRtn1($P(R,"\",2))_" "_KLNr
 . Set SortKey=SortKey_GroepNr,^HULP(%J,SortKey)=GroepNr
 Quit
 ;
 ; Afdruk leveringsadres
LEVADR 
 Set R=$$TXT("LevAdr")_" "_LevAdr,R=$E(R,1,47)
 Set R=R_$J("",48-$L(R))_"`3`42`C"
 Do BLOCK(R)
 Quit
 ;
 ; Afdruk hoofding
HEADER 
 New I,T,R,Obj,LTemp,AlgOpm,Creator,TransportType,Groeperen,UitersteLeverDatum,tl
 Set LTemp=L("B","F")
 Set Obj=##class(Flow.Cons.Transport).%OpenId(TranspNr)
 Set TransportType=Obj.TransportType,Groeperen=Obj.Groeperen,UitersteLeverDatum=Obj.UitersteLeverDatum
 Do:PCount=1  ; Transport van naar en eventueel de algemene opmerking afdrukken
 . Set AlgOpm(1)=$G(^TRANSP("D",TranspNr,"T"))
 . If TransportType="T" Set T="*** "_$$TXT("Retour")_" ***~"
 . Else  Set T=""
 . ; Transport van -> naar
 . Set T=T_$$TXT("FromAdres")
 . If TransportType'="T" Set T=T_"~"_VH(1)_"~"_VH(2)_"~"_VH(3)
 . Else  Set T=T_" "_$$TXT("Onderst")
 . Set T=T_"~"_$$TXT("ToAdres")
 . If TransportType="T" Set T=T_"~"_VH(1)_"~"_VH(2)_"~"_VH(3)
 . Else  Do
 . . Set T=T_" "_$$TXT("Onderst")
 . . Quit:Groeperen'="S"  Quit:'UitersteLeverDatum
 . . Set T=T_",~"_P("B",1)_$$TXT("TenLste")_" "_$$EXTDATE^vhLib.DataTypes(UitersteLeverDatum)
 . . Set:$P(UitersteLeverDatum,",",2) T=T_" "_$$TXT("TenLste",3)_" "_$$EXTTIME^vhLib.DataTypes(UitersteLeverDatum,"TKL")
 . . Set T=T_P("B",0)
 . Set:$L(AlgOpm(1)) AlgOpm(1)="~~"_AlgOpm(1)
 . Set AlgOpm(1)=T_"."_AlgOpm(1)
 . Do:PrintCount>1
 . . Set Creator=Obj.Creator
 . . Set:$L(AlgOpm(1)) AlgOpm(1)="~~"_AlgOpm(1)
 . . Set T=$$TXT("RePrint")_" "_TranspNr Set:PrintCount>2 T=T_"v"_(PrintCount-2)
 . . Set T=T_"/"_$$USERNAME^vhUSER(Creator,-1)
 . . Set T=T_" "_$$TXT("Van")_" "_$$EXTDATE^vhLib.DataTypes(OudeAfgedruktTijdstip)
 . . Set AlgOpm(1)=T_"."_AlgOpm(1)
 . Quit:AlgOpm(1)=""
 . Do GETWRAP^vhBIGEDIT("AlgOpm",75,.AlgOpm,"G","~","")
 . Do CACHE("")
 . Set R=L("T","F")
 . Do PASTE(PCount,LCount,R,1,"","C")
 . For I=1:1:AlgOpm Do
 . . Do CACHE("")
 . . If MetFax Do
 . . . Set R=L("T","B")
 . . . Set T=$P(AlgOpm(I),"`",5)
 . . . Do PASTER(T,3)
 . . . Do PASTE(PCount,LCount,R,1,"","C")
 . . Else  Do
 . . . Do PASTE(PCount,LCount,$E(L("T","B")),1,"","C")
 . . . Set T=$P(AlgOpm(I),"`",5)
 . . . Do PASTE(PCount,LCount,T,9,"","")
 . . . Do PASTE(PCount,LCount,$E(L("T","B"),$L(L("T","B"))),83+(T[P("B",1)*$L(T,P("B",1)))+(T[P("B",1)*$L(T,P("B",0))),"","C")
 . Set $E(LTemp)=$$C^vhRtn1(7),$E(LTemp,$L(LTemp))=$$C^vhRtn1(6)
 Do CACHE("")
 Do PASTE(PCount,LCount,LTemp,1,"","C")
 Do CACHE("")
 Set R=L("B","B")
 Set T=$$TXT($S(TransportType="T":"Ophalen",1:"Leveren"))
 Do PASTER(T,3)
 Set T=$$TXT($S($E(DocTypes)="O":"OrdNr",$E(DocTypes)="B":"LevNr",$E(DocTypes)="F":"FactNr",$E(DocTypes)="Z":"ProfNr",1:"")),tl=$L(T)
 Do PASTER(T,"",38)
 Set T=$$TXT("Gew")
 Do PASTER(T,"",48)
 Set T=$$TXT("Remb")
 Do PASTER(T,"",63)
 Set T=$$TXT("Opmerk")
 Do PASTER(T,67)
 Set:$L(DocTypes)>1 $E(R,38-tl+1)=P("B",1)_$E(R,38-tl+1)_P("B",0)
 Do PASTE(PCount,LCount,R,1,"","C")
 If $L(DocTypes)>1 For I=2:1:$L(DocTypes) Do
 . Do CACHE("")
 . Set R=L("B","B")
 . Set T=$$TXT($S($E(DocTypes,I)="O":"OrdNr",$E(DocTypes,I)="B":"LevNr",$E(DocTypes,I)="F":"FactNr",$E(DocTypes,I)="Z":"ProfNr",1:"")),tl=$L(T)
 . Do PASTER(T,"",38)
 . Set $E(R,38-tl+1)=P("B",1)_$E(R,38-tl+1)_P("B",0)
 . Do PASTE(PCount,LCount,R,1,"","C")
 Do CACHE("")
 Do PASTE(PCount,LCount,L("B","S"),1,"","C")
 Quit
 ;
 ; Afdruk titel
TITEL 
 New R,I,T,Obj,TijdstipOphalingVoorzien,Transporteur,Naam,StraatNrBus,Postnummer,Woonplaats,LandCode,Land
 New Creator
 Set PCount=PCount+1,LCount=0
 Set Obj=##class(Flow.Cons.Transport).%OpenId(TranspNr)
 Set Transporteur=Obj.Transporteur
 Set TijdstipOphalingVoorzien=Obj.TijdstipOphalingVoorzien,Creator=Obj.Creator
 Set Obj=##class(Derde.Lev.Lev).%OpenId(Transporteur)
 Set Naam=Obj.Naam,StraatNrBus=Obj.StraatNrBus
 Set Postnummer=Obj.Postnummer,Woonplaats=Obj.Woonplaats
 Xecute "Set Land=Obj.Land.Oms"_Taal
 Set LandCode=Obj.Land.Code
 Do VHPB^DCALG(PCount,.Blank,12)
 For I=1:1:5 Do
 . Set R=VH(I)
 . If $L($P(R,":",2)) Set $P(R,":",2)=" "_$TR($P(R,":",2)," ","")
 . Do PASTE(PCount,I,R,2,"","")
 Do PASTE(PCount,3,Naam,48,"","")
 Do PASTE(PCount,4,StraatNrBus,48,"","")
 Set R=Postnummer Set:$L(R) R=R_"   " Set R=R_Woonplaats
 Do PASTE(PCount,5,R,48,"","")
 Do:LandCode'="BE" PASTE(PCount,4,Land,48,"","")
 Do:PrintCount>1!Closed
 . Set T="*** "_$$TXT($S(Closed:"Defin",1:"Corr"))_" ***"
 . Do PASTE(PCount,7,T,2,"","B")
 Set T=P("B",1)_$$TXT("TpAanvr")_P("B",0)
 Set:TijdstipOphalingVoorzien T=T_" "_$$TXT("Ophaal")_" "_$$TXT("Voor")_" "_$$FMTDT^vhLib.DataTypes(TijdstipOphalingVoorzien)
 Do PASTE(PCount,8,T,2,"","")
 Set T=$$TXT("Date")_": "_$$EXTDATE^vhLib.DataTypes(AfgedruktTijdstip)
 Do PASTE(PCount,10,T,2,"","")
 Set T=$$TXT("ORef")_": "_TranspNr Set:PrintCount>1 T=T_"v"_(PrintCount-1)
 Set T=T_"/"_$$USERNAME^vhUSER(Creator,-1)
 Do PASTE(PCount,11,T,2,"","")
 Quit
 ;
 ; Afdruk afsluiting
FOOTER 
 New I,T,R,LCount,Page
 For Page=1:1:PCount Do
 . Set LCount=$O(C(Page,""),-1)
 . Kill C(Page,LCount)
 . Set R=L("A","F")
 . If $Get(HeeftKenAnk),Page=PCount Set R=$$LINE^vhRtn1("S",92,"1;29;40$$C^vhRtn1(5);50$$C^vhRtn1(5);92")
 . Do PASTE(Page,LCount,R,1,"","C")
 . Set LCount=LCount+1
 . Do PASTE(Page,LCount,L("A","B"),1,"","C")
 . Set T=$$TXT("Page")
 . Do PASTE(Page,LCount,T,(5-VFax),"","")
 . Do:Page=PCount
 . . Set T=$$EXTNUM^vhLib.DataTypes(TotGewicht,0,".T",1)
 . . Do PASTE(Page,LCount,T,"",(51-VFax),"")
 . . Do:TransportStatus="T"
 . . . Set T=$$TXT("HandT")
 . . . Do PASTE(Page,LCount,T,(54-VFax),"","")
 . Set LCount=LCount+1
 . Do PASTE(Page,LCount,L("A","B"),1,"","C")
 . Set T=Page_"/"_PCount
 . Do PASTE(Page,LCount,T,(5-VFax),"","")
 . If Page=PCount,TransportStatus="T" Do
 . . Set LCount=LCount+1
 . . Do PASTE(Page,LCount,L("A","B"),1,"","C")
 . Set LCount=LCount+1
 . Do PASTE(Page,LCount,L("A","L"),1,"","C")
 Quit
 ;
 ; Afdrukken van het document
DPRINT
 New R,Exemplaren,Closed
 Set Exemplaren=1,Closed=0,R=^TRANSP("D",TranspNr)
 If $P(R,D,2)="T",$P(R,D,11),$P(R,D,12) Set Closed=1
 Set:Closed Exemplaren=$P($G(^TRANSP("T",Transporteur)),D,13) Set:'Exemplaren Exemplaren=1
 For Exemplaren=1:1:Exemplaren For PCount=1:1:PCount Do PPRINT^DCPRINT(PCount)
 Quit
 ;
 ; Afdrukken van de transportaanvraag
PRINT(TranspNr,Init,MetFax) 
 New C,R,Obj,PCount,LCount,TotGewicht,VFax,AfgedruktTijdstip,OudeAfgedruktTijdstip,PrintCount,MaxLines,PageLen,TransportStatus,HeeftKenAnk,Closed,DocTypes
 Set MetFax=$G(MetFax)
 Set Obj=##class(Flow.Cons.Transport).%OpenId(TranspNr)
 Do:$IsObject(Obj)
 . Do:'$D(Print) INIT^vhPRINTER()
 . Quit:'$D(Print)
 . Set VFax=''$D(Print("FAX"))*2
 . If '$G(Init) Do INIT
 . Set Transporteur=Obj.Transporteur
 . Set TransportStatus=Obj.Status
 . Set OudeAfgedruktTijdstip=Obj.TijdstipAfgedrukt
 . Set PrintCount=$P(OudeAfgedruktTijdstip,",",2)+1
 . Set AfgedruktTijdstip=+$H_","_PrintCount
 . If Obj.Status'="T" Do
 . . Set Closed=0,Obj.Status="P",Obj.TijdstipAfgedrukt=AfgedruktTijdstip
 . . Do Obj.%Save()
 . Else  Set Closed=1
 . Set Obj=##class(Derde.Lev.Lev).%OpenId(Transporteur)
 . Quit:'$IsObject(Obj)
 . Set (PCount,TotGewicht)=0
 . Set Taal=Obj.Taal Set:Taal="" Taal="N"
 . Set DocTypes=$$DocTypes(TranspNr) Set:DocTypes="" DocTypes="B"
 . Do TITEL,HEADER,BODY,FOOTER,DPRINT
 . Set:$G(MetFax) Data("Pages")=$G(Data("Pages"))+PCount
 Quit
 ;
 ; Initialisatie
INIT 
 If '$D(VH) Do VH^DCINIT
 If '$D(P) Do PINIT^DCINIT
 If '$D(L) Do LINIT^DCINIT("E")
 If '$D(PageLen)!'$D(V) Do FINIT^DCINIT("E")
 Quit
 ;
 ; Ophalen taalafhankelijke tekst
TXT(Ref,Piece) 
 If '$D(Piece) Set Piece=2
 Quit $P($P($T(@("T"_Ref)),U,Piece),D,$F("NFDE",Taal)-1)
 ;
 ; Welke soorten van documenten zijn er in dit transport
DocTypes(TranspNr)
 New DocTypes
 Set (DocTypes,GroepNr)=""
 For  Set GroepNr=$O(^TRANSP("D",TranspNr,"D",GroepNr)) Quit:GroepNr=""  Do  Quit:$L(DocTypes)=4
 . For DocType="O","B","F","Z" If DocTypes'[DocType,$D(^TRANSP("D",TranspNr,"D",GroepNr,DocType)) Set DocTypes=DocTypes_DocType Quit:$L(DocTypes)=4
 Quit DocTypes
 ;
TTpAanvr ;TRANSPORTOPDRACHT\ORDRE DE TRANSPORT\TRANSPORTANFORDERUNG\TRANSPORTOPDRACHT
TDate ;Datum\Date\Datum\Date
TVoor ;voor\pour le\für\voor
TOphaal ;ophaling\enlèvement\Abholung\ophaling
TRetour ;RETOUR\RETOUR\RETOUR\RETOUR
TORef ;O/ref\N/réf\U/Ref\O/ref
TLeveren ;Leveren aan\Livrer à\Liefern an\Leveren aan
TOphalen ;Ophalen bij\Enlever chez\Abholung bei\Ophalen bij
TGew ;Kg\Kg\Kg\Kg
TRemb ;Rembours\Remboursement\Nachnahme\Rembours
TOpmerk ;Opmerking\Remarque\Notiz\Opmerking
TOrdNr ;OrderNr\OrderNr\OrderNr\OrderNr
TLevNr ;LevBonNr\LevBonNr\LevBonNr\LevBonNr
TFactNr ;FactuurNr\FactuurNr\FactuurNr\FactuurNr
TProfNr ;ProfromaNr\ProformaNr\ProformaNr\ProformaNr
TPage ;Blz\Pg.\S.\Blz
TCorr ;WIJZIGING\CORRECTION\ÄNDERUNG\WIJZIGING
TDefin ;DEFINITIEF\DEFINITIF\ENDGULTIG\DEFINITIEF
TRePrint ;Dit document vervangt transportaanvraag\Ce document remplace la demande de transport\Dieses Dokument ersetzt die Speditionsanfrage\Dit document vervangt transportaanvraag
TVan ;van\du\vom\van
TFromAdres ;De goederen dienen opgehaald te worden bij\Les marchandises doivent être enlevés chez\Die Waren werden abgeholt bei\De goederen dienen opgehaald te worden bij
TToAdres ;en geleverd bij\et livrés aux\und geliefert bei\en geleverd bij
TOnderst ;onderstaande adressen\adresses suivantes\folgende Adressen\onderstaande adressen
TTenLste ;ten laatste op\en dernier lieu\spätestens am\at the latest on;om\à\um\
TVVolume ;Voorzien volume\Volume prévu\Vorgeschenes volume\Foreseen volume
TPalet ;Europallet\Europalette\Euro-Palette\Euro Pallet
TPaletten ;Europalletten\Euro-palettes\Euro-Paletten\Euro Pallets
TWPalet ;Wegwerppallet\Palette jetable\Einwegpalette\Disposable Pallet
TWPaletten ;Wegwerppalletten\Palettes jetables\Einwegpaletten\Disposable Pallets
TKPalet ;klein pallet\petite palette\kleine palette\small pallet
TKPaletten ;kleine palletten\petites palettes\kleine Paletten\small pallets
TBPalet ;Buitenmaatse pallet\Buitenmaatse pallet\Buitenmaatse pallet\Buitenmaatse pallet
TBPaletten ;Buitenmaatse palletten\Buitenmaatse palletten\Buitenmaatse palletten\Buitenmaatse palletten
TCollie ;collie\collis\Pakette\Packet
TCollo ;collo\collis\Pakette\Packets
TLangGoed ;langgoed\langgoed\langgoed\langgoed
TMeter ;meter\mètre\Meter\meter
TVrachtK ;Vrachtkost\Frais transport\Frachtkosten\Freight costs
THandT ;Handtekening chauffeur\Signature chauffeur\Unterschrift Fahrer\Signature driver