EWORDST3 ;E'WMS Status orderpicking [ 10/26/2001  3:35 PM ]
 ;
CHKMENU(Menu,Aktie) 
 New R,Ok,EWStat
 Set Aktie=$G(Aktie),Ok=0
 If Menu="F" Do  ; File menu
 .If Aktie="" Do
 ..Set Ok=1
 .Else  If Aktie="S" Do  ; Nieuwe selektie
 ..Set:$D(^ORDW("D")) Ok=1
 .Else  If Aktie="M" Do  ; Selekteer macro
 ..Set:$D(^EWSEL("ORDST")) Ok=1
 .Else  If Aktie="O" Do  ; Open klant
 ..Set Ok=1
 .Else  If Aktie="T" Do  ; Toon ...
 ..Quit:'$D(^HULP(%J,"F"))  ; Geen gegevens om te tonen
 ..Set Ok=1
 .Else  If Aktie="TS" Do  ; Toon selektie
 ..Quit:'$D(^HULP(%J,"F"))  ; Geen gegevens om te tonen
 ..Set:$L($G(KritD("A","DISPMODE"))) Ok=1
 .Else  If Aktie="TK" Do  ;Toon klant
 ..Quit:'$D(^HULP(%J,"F"))  ; Geen gegevens om te tonen
 ..Set:$G(KritD("A","DISPMODE"))'="K" Ok=1
 .Else  If Aktie="TC" Do  ; Toon leveringsbon
 ..Quit:'$D(^HULP(%J,"F"))  ; Geen gegevens om te tonen
 ..Set:$G(KritD("A","DISPMODE"))'="C" Ok=1
 .Else  If Aktie="TD" Do  ; Toon pickdetails
 ..Quit:'$D(^HULP(%J,"F"))  ; Geen gegevens om te tonen
 ..Set:$G(KritD("A","DISPMODE"))'="D" Ok=1
 .Else  If "\)\(\"[(D_Aktie_D) Do  ; Volgende/vorige klant
 ..Quit:$G(KritD("A","DISPMODE"))="D"
 ..Quit:'$D(^HULP(%J,"F"))  ; Geen gegevens om te tonen
 ..Quit:$D(KritF("K","KLNR"))  ; Fullnode heeft maar 1 klant
 ..Quit:'$D(KritD("A","DISPMODE"))="C"  ; Nextklant kan niet in DISPMode=Consolidatie
 ..Set Ok=1
 .Else  If "\]\[\"[(D_Aktie_D) Do  ; Volgende/vorige leveringsbon
 ..Quit:'$D(^HULP(%J,"F"))  ; Geen gegevens om te tonen
 ..Set Ok=1
 .Else  If Aktie="R" Do  ; Refresh
 ..Quit:'$D(^HULP(%J,"F"))  ; Geen gegevens om te tonen
 ..Set Ok=1
 .Else  If "\WA\WD\"[(D_Aktie_D) Do  ; Aktiveer/Deaktiveer WMS-link
 ..Quit:$P("D\A",D,$G(^EWREC("P","NOSEND"))+1)'=$E(Aktie,2)
 ..Set Ok=1
 Else  If Menu="E" Do  ; Edit menu
 .If Aktie="" Do
 ..Set:$G(KLNr) Ok=1
 .Else  If Aktie="Z" Do  ; Doorsturen consolidatie
 ..Quit:'CONSNr  Quit:'$D(^HULP(%J,Node,CONSNr))
 ..Set R=^HULP(%J,Node,CONSNr),EWStat=$P(R,D,20) Set:"K"[EWStat Ok=1
 .Else  If Aktie="ZA" Do  ; Doorsturen alle consolidaties
 ..If $G(KritD("O","STAT"))=1,$D(^HULP(%J,"F")) Set Ok=1
 .Else  If Aktie="WZ" Do  ; Wijzig verzendwijze en tijdstip
 ..Quit:'CONSNr  Quit:'$D(^HULP(%J,Node,CONSNr))
 ..Set R=^HULP(%J,Node,CONSNr),EWStat=$P(R,D,20) Set:"\\W\K\P\"[(D_EWStat_D) Ok=1
 .Else  If Aktie="U" Do  ; Terugtrekken consolidatie
 ..Quit:'CONSNr  Quit:'$D(^HULP(%J,Node,CONSNr))
 ..Set R=^HULP(%J,Node,CONSNr),EWStat=$P(R,D,20) Set:"\W\"[(D_EWStat_D) Ok=1
 .Else  If Aktie="X" Do  ; Verwijder consolidatie
 ..Quit:'CONSNr  Quit:'$D(^HULP(%J,Node,CONSNr))
 ..Set R=^HULP(%J,Node,CONSNr),EWStat=$P(R,D,20) Set:"\\W\K\"[(D_EWStat_D) Ok=1
 .Else  If Aktie="B" Do  ; Opmaken bon
 ..Quit:'CONSNr  Quit:'$D(^HULP(%J,Node,CONSNr))
 ..Set R=^HULP(%J,Node,CONSNr),EWStat=$P(R,D,20) Set:"\A\C\"[(D_EWStat_D) Ok=1
 Else  If Menu="L" Do  ; Link menu
 .If Aktie="" Do
 ..Set:$G(KLNr) Ok=1
 .Else  If Aktie="K" Do  ; Raaplegen klant
 ..Set:KLNr Ok=1
 .Else  If Aktie="P" Do  ; Raaplegen produkt
 ..Set:PRNr Ok=1
 .Else  If Aktie="J" Do  ; Wijzig order
 ..Set:ORDNr Ok=1
 Quit Ok
 ;