LOGJOB ;BEHEER LOGGING VAN JOBS ; [ 11/07/2001  2:42 PM ]
 G BEHEER
 ;
T1 ;"Datum";C;L;8;;|\"Van";C;C;5;;-\"tot";C;C;5;;|\"Programma";C;L;28;;|\"Wijziging";C;L;27;;|\"$I";C;L;2;;
T2 ;1;C;L;8;;|\2;C;R;5;; \3;C;R;5;;|\4;C;L;28;;|\8;C;L;27;;|\9;C;R;2;;
T10 ;initialen of poortnummer=
T11 ;[] = 
T12 ;--------------------------------------------------------------------------------.
T13 ;Poort : 
 ;
HOOFD ; Hoofding
 Write @F11,@F1
 Set FP=202 W @F,@F4,$P($T(+1),";",2)_QN_" ",@F5
 Set FP=270
 Write @F,@F1,$P($T(T13),U,2)
 Q
 ;
INIT ; Initialistie
 Set UCI="LVH",VOL="DEV"
 Xecute FLO
 Quit
 ;
 ; Poort
DEVICE(K) 
 I $D(K),K="" G D2
 S FP=2002 W @F,$P($T(T10),U,2) D C1
 S FP=2002+$L($p($T(T10),U,2)) W @F,@F2 R K
D2 I K="" D  Q K
 .S K=$D(^[UCI,VOL]LOGJOB(0,"DEV",$I)) I 'K S K=$I Q
 .S K=$P(^[UCI,VOL]LOGJOB(0,"DEV",$I),D,2) I K="" S K=$I Q
 .I $D(^[UCI,VOL]LOGJOB(0,"INI",K)) Q
 .S K=$I
 S R=K
 I '$D(^[UCI,VOL]LOGJOB(0,"DEV",K)),'$D(^[UCI,VOL]LOGJOB(0,"INI",K)) D  Q ""
 .W *7
 .W !,"***  ",K,"  log bestaat niet ***"
 .W !," Druk een toets om verder te gaan"
 .R *K
 I $D(^[UCI,VOL]LOGJOB(0,"DEV",K)) S K=$P(^[UCI,VOL]LOGJOB(0,"DEV",K),"\",2)
 I K="" Q R
 I $D(^[UCI,VOL]LOGJOB(0,"INI",K)) Q K
 Q R
 ;
CHANGE S FP=2002 W @F,"wijzig alles=" R CF Q:CF=""
 W " naar=" R CT
 S (FL,CNT)=0
 F  S CNT=$O(^HULP($J,CNT)) Q:CNT=""  D
 .S K=^HULP($J,CNT)
 .F  Q:K'[CF  S K=$P(K,CF)_CT_$P(K,CF,2,999),FL=1
 .S ^HULP($J,CNT)=K
 I 'FL W !,"geen wijzigingen, Druk een toets om verder te gaan" R K Q
 S FP=301 W @F,@F1 D WL^PROC
 Q
 ;
FETCH ; Ophalen data
 K ^HULP($J) S (H,HX)="",CNT=0
 F  S H=$O(^[UCI,VOL]LOGJOB(DEV,H),-1) Q:H=""  D
 .S R=^[UCI,VOL]LOGJOB(DEV,H)
 .S ZN=$P(R,D,2),K=$P(R,D,3)
 .I $P(K," ")=ZN S K=$P(K," ",2,99)
 .S (DATE,BEGIN,END)=""
 .I $P(H,",")'=$P(HX,",") S DATE=$$EXTDATE^vhLib.DataTypes($P(H,","))
 .S BEGIN=$$EXTTIME^vhLib.DataTypes($P(H,",",2))
 .S END=$$EXTTIME^vhLib.DataTypes($P(H,",",3))
 .S HX=H
 .S CNT=CNT+1,^HULP($J,CNT)=DATE_D_BEGIN_D_END_D_""""_ZN_""" "_K_D_R
 Q
 ;
BEHEER ; Beheer
 D HOOFD,INIT
 S LD(1)="^HULP("_$J,LD(2)=$P($T(T2),U,2,999),LD(3)=4,LD(8)=$P($T(T1),U,2,999)
 S DEV=$$DEVICE("")
B1 D FETCH
 S FP=278 W @F,@F1,DEV
 S DL(1)="LD",(LD(6),LD(7))=1 D WL^PROC
B3 D SL^PROC
 I R="." D A G B99:R="Q",B3:R'="N" S R=$$DEVICE() S:R=DEV R="" S:R'="" DEV=R G B1:$L(R) D  G B3
 .I "\C\Q\N\"'[(D_R_D) S DL(2)=19 D WL^PROC K DL S DL(1)="LD"
 I R="Q" G B99
 ;I R="C" D CONNECT
 G B3
 ;
B99 K ^HULP($J) Q
 ;
A S FP=1901 W @F,@F1,$P($T(T12),U,2)
A1 S FP=2002 W @F R *R S:R=13 R=-1 S R=$C(R)
 S R=$$UPCASE^vhRtn1(R)
 I "\\C\Q\N\"'[(D_R_D) W *7 G A1
 I R="C" D CHANGE
 I "\Q\N\"'[(D_R_D) S DL(2)=19 D WL^PROC K DL S DL(1)="LD"
 Q
 ;
C1 ; Commentaar poortnummer
 W !?1,$P($T(T11),U,2)
 S K=$D(^[UCI,VOL]LOGJOB(0,"DEV",$I)) I 'K W $I Q
 S K=$P(^[UCI,VOL]LOGJOB(0,"DEV",$I),D,2) I K="" W $I Q
 I $D(^[UCI,VOL]LOGJOB(0,"INI",K)) W K Q
 W $I Q
 ;