PRSTBESL ;Produktlijst voor STOCK BESLISSING [ 11/08/2003   8:41 PM ]
 Do INIT^vhTERMINA
 u 0:(::::4096)
 Set (HG,GR,SG,KortT,Cnt)=""        
 Read "TRANSFERT",k
 Write $TR("VolgNr,Produktnaam,IdentNr,LeverNr,LeverNaam,Klas,Cif%,CifPPL,Verpakking,MinBH,LevTrm,GemWVK,FysStock,TheoStock,S/NS,#KL,#KL80%,Klanten",",",$C(9)),!
 For  Set HG=$O(^KPH(HG)) Quit:HG=""  Do:HG'["DE"
 .For  Set GR=$O(^KPH(HG,GR)) Quit:GR=""  Do
 ..For  Set SG=$O(^KPH(HG,GR,SG)) Quit:SG=""  Do
 ...For  Set KortT=$O(^KPH(HG,GR,SG,"  ",KortT)) Quit:KortT=""  Do
 ....Set PRNr=$P(^(KortT),D)
 ....Do FETCHPR^UTILI(PRNr,"Rec")
 ....Set Cnt=Cnt+1
 ....Write Cnt,$C(9) ; VolgNr
 ....Write $P(Rec(0),D,1),$C(9) ; KortTekst
 ....Write $P(Rec(2),D,25),$C(9) ; IdentNr
 ....Write $P(Rec("J"),D,1),$C(9) ; Leverancier
 ....Write $E($P(^KLE(^KL1($P(Rec("J"),D,1)),0),D,2),1,10),$C(9) ; Leverancier naam
 ....Write $$DISPL^KLASS($P(Rec("I"),D,4)),$C(9) ;Klassificatie
 ....Write $TR($P(Rec("J"),D,21),".",","),$C(9) ;Cif%
 ....Write $TR($P(Rec("J"),D,23),".",","),$C(9) ;CifPPL
 ....Write $P(Rec("J"),D,16) ; Verpakking
 ....Write:$P(Rec("J"),D,15) "/"_$P(Rec("J"),D,15)
 ....Write:$P(Rec("J"),D,14) "/"_$P(Rec("J"),D,14)
 ....Write:$P(Rec("J"),D,13)=1 "*" ; Per stuk
 ....Write $C(9)
 ....Write $P(Rec("J"),D,6),$C(9) ; Min Bestelhv
 ....Write $P(Rec("J"),D,7),$C(9) ; Levertermijn
 ....Write $P(Rec(1),D,23)+$P($P(Rec(1),D,23),"#",2),$C(9) ; GemWVK
 ....Write $$GETSTOCK^PRODUKT4(PRNr,"F"),$C(9) ; FysStock
 ....Write $$GETSTOCK^PRODUKT4(PRNr,"T"),$C(9) ; TheoStock
 ....Write $S($P(Rec(1),D,25):"NA",$P(Rec(1),D,20):"S",1:"NS"),$C(9) ;Stock/niet stock/nonaktief
 ....Set KLQty=$O(^AKANAL(PRNr,""),-1)
 ....Write KLQty,$C(9) ; Aantal klanten
 ....Set Tot=$P($G(^AKANAL(PRNr)),D)*0.8\1 ; 80% van totale afname
 ....Set String=""
 ....For I=1:1:KLQty Do  Quit:Tot'>0 
 .....Set Qty=$P(^AKANAL(PRNr,I),D,4)
 .....Set Tot=Tot-Qty
 .....Set:I<10 String=String_"/"_Qty_" "_$E($P(^AKANAL(PRNr,I),D,3),1,10)
 ....Write I,$C(9)
 ....Write $E(String,2,255),$C(9)
 ....Write !
 Write "~~~"