PVKS ;Klantenservice [ 11/08/2003   8:40 PM ]
IMPORT Do MASTER^cQ5
 READ !,"Filenaam (D:\Mac Files\User\File.ext) : ",File
 ;Set File="D:\Mac Files\Paul\KS.TXT2"
 For Dev=54:-1:51 Open Dev:(File:"R"):0 Quit:$T
 Use Dev
 Kill ^["LVH",master]PVKS("I")
 Set ^["LVH",master]PVKS("I")=$H
 Set Cnt=0
 For  Read Lijn Quit:$ZC=-1  Do
 .Set Cnt=Cnt+1,^["LVH",master]PVKS("I",Cnt)=$TR(Lijn,$C(9),"\")
 Close Dev
 Quit
  
TNODES ;IDNr:3;KortT:4;IsKS:11;KVP:13;GVP:14
CONVERT D ^cA604,MASTER^cQ5
 If master'=boot Write "Moet lopen in ",master Q
 Kill ^PVKS("C")
 Set ^PVKS("C")=$H
 Set Nodes=$P($T(TNODES),";",2,99)
 For Cnt=1:1:$O(^PVKS("I",""),-1) Do
 .Set Rec=$G(^PVKS("I",Cnt))
 .Quit:$TR(Rec,"\ ","")=""
 .For I=1:1:$L(Nodes,";") Set @$P($P(Nodes,";",I),":")=$P(Rec,D,$P($P(Nodes,";",I),":",2))
 .Set IDNr=$TR(IDNr,". ","")
 .Set Error=0
 .If IDNr="" Set Error=1
 .If $L(IDNr),'$D(^KPR2(IDNr_" ")) Set Error=2
 .If Error Write !,Cnt," -> ",Rec Quit
 .Set PRNr=+^KPR2(IDNr_" ")
 .Set ^PVKS("C",PRNr)=IDNr_D_IsKS_D_KVP_D_GVP
 Quit
 
PUTPROD Set PRNr=0,KSCnt=0
 For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  Do 
 .Set KSDB="",KSKV="",KSGV="",IsKS=0
 .If '$P(^KPR(PRNr,1),D,20) ; Niet stock
 .Else  If $D(^PVKS("C",PRNr)) Do
 ..Set KSRec=^PVKS("C",PRNr)
 ..If $$UPTRIMAN^vhRtn1($P(KSRec,D,2))'="HANDEL" Quit
 ..Set IsKS=1,KSCnt=KSCnt+1
 ..Set KSDB=20
 ..Set KSKV=$P(KSRec,D,3)
 ..Set KSGV=$P(KSRec,D,4)
 .Else  Do
 ..Set Key=$O(^KPR(PRNr,"I"))
 ..Quit:$P(^KPR(PRNr,Key),D)["DE"
 ..Write !,PRNr," ",$P(^KPR(PRNr,0),D,1)," NOT FOUND AND CLEANED"
 .Set Key=$O(^KPR(PRNr,"J")) Quit:$E(Key)'="J"
 .Set Rec=^KPR(PRNr,Key)
 .;W:IsKS !!,PRNr," ",Rec
 .Set $P(Rec,D,10)=KSDB
 .Set $P(Rec,D,11)=KSKV
 .Set $P(Rec,D,12)=KSGV
 .;W:IsKS !,PRNr," ",Rec
 .Set ^KPR(PRNr,Key)=Rec
 Quit
 
EXPORT(Munt,Taal,MetHGSep) 
 New FVAN,FNAAR
 Set Taal=$G(Taal,"N")
 Set Munt=$G(Munt,$$FADEF^vhRtn1())
 Do VANNAAR^vhTERMINA("M")
 ;goto TEST
 Set File="KS"_Taal_Munt_".TXT"
 Set Dev=$$OPEN^vhDEV($$DIRUSER^vhDEV,File,"W")
 IF $ZC=1 Do TXT^vhINP("File "_File_" niet te openen") Quit
 Use Dev
TEST Set (HG,GR,SG,KT)=""
 For  Set HG=$O(^KPH(HG)) Quit:HG=""  Do:HG'["DE"
 .Write:$G(MetHGSep,1) !,"<Hoofdgroep>",$E(HG,3,4)
 .For  Set GR=$O(^KPH(HG,GR)) Quit:GR=""  Do
 ..For  Set SG=$O(^KPH(HG,GR,SG)) Quit:SG=""  Do
 ...For  Set KT=$O(^KPH(HG,GR,SG,"  ",KT)) Quit:KT=""  Do
 ....Set PRNr=+^(KT)
 ....Quit:'$D(^KPR(PRNr,"J6118"))
 ....Do EXPONE(PRNr)
 Close Dev
 Write !,"File "_File_" weggeschreven"
 Quit
 
EXPONE(PRNr) 
 Quit:'$P(^KPR(PRNr,3),D,3)  ; Mag NIET in de KS-prijslijst
 Set KSRec=$$STAFFEL^KS(PRNr)
 Quit:'$L(KSRec)
 Set KortTekst=$P(^KPR(PRNr,0),D,1)
 Set Ltekst1=$P(^KPR(PRNr,0),D,2)
 Set Ltekst2=$P(^KPR(PRNr,0),D,11)
 Set:Taal="F" Ltekst1=$P(^KPR(PRNr,1),D,22)
 Set:Taal="F" Ltekst2=$P(^KPR(PRNr,3),D,21)
 Set:Ltekst2="" Ltekst2=" "
 Set Kleur=$E(KortTekst,22,25)
 Set KleurOms=$P($G(^KCOL(Kleur_" ",Taal)),D,1)
 Set Rec=$$TRIM($E(KortTekst,1,11))_$C(9)_$$TRIM($E(KortTekst,12,21))_$C(9)_$$TRIM($E(KortTekst,22,25))
 Set Rec=Rec_$C(9)_Ltekst1_$C(9)_KleurOms
 Write !,"<Produkt Lijn1>",$TR(Rec,FVAN,FNAAR)
 For I=3:-1:1 Do
 .Write $C(9),$$EXTNUM^vhLib.DataTypes($P(KSRec,D,I),0,"Z.",0)
 .Set Rec=$$PROD^KPRIJS(PRNr,$E("LKE",I),"",Munt,"","","S")
 .Write $C(9),$$EXTNUM^vhLib.DataTypes($P(Rec,D),0,"Z.",2)
 .Write $C(9),$S($P(Rec,D,3)="H":"%",1:"")
 Write !,"<Produkt Lijn2>",$TR(Ltekst2,FVAN,FNAAR)
 Quit
 
TRIM(X) For  Quit:$E(X)'=" "  Set $E(X)=""
 For  Quit:$E(X,$L(X))'=" "  Set $E(X,$L(X))=""
 Quit X