PVMatthias
#Include BL.Derde.LevSpecifiek
#include Prod.Product
#include vhLib.Macro

Verwerk
	Set Dev=$$OPEN^vhDEV(,"InkomendeGoederen.txt","W","T")
	Use Dev
	Set Begin=$$CALCDATE^vhLib.DataTypes($H,"M",-12,"FD")
	Set Einde=$$CALCDATE^vhLib.DataTypes($H,"M",-1,"LD")
	Do WriteHeader
	Set PRNr=""
	For  Set PRNr=$O(^PRHIST(PRNr)) Quit:'PRNr  Do
    . Quit:'$$IncludeProduct(PRNr)
	. Do Historiek(PRNr,Begin,Einde)
	Do CLOSE^vhDEV(Dev)
	Quit
	
Historiek(PRNr,Begin,Einde) 
	New Key,HistRec,Acties
	Set Acties=";I;J;R;Q;"
	Set Key=""
	For  Set Key=$O(^PRHIST(PRNr,Key)) Quit:Key=""  Do
	. Set HistRec=^PRHIST(PRNr,Key)
	. Quit:+$P(HistRec,"\")<Begin
	. Quit:+$P(HistRec,"\")>Einde
	. Quit:Acties'[(";"_$P(HistRec,"\",4)_";")
	. Do WriteRecord(PRNr,HistRec)
	Quit

IncludeProduct(PRNr)
	Quit:($$$PRGet($$$LinkType)="S")&&$D(^PRBS("BS",PRNr)) 0
	Quit:$E($P(^KPR(PRNr,2),D,25))=6 0  ; geen kinderen, behalve op bon
	Quit:$E($P(^KPR(PRNr,2),D,25))=7 0  ; geen DO producten ook niet voor de werkvloer
	Quit 1 

WriteRecord(PRNr,HistRec) 
	NEw KortTekst,LevNr,LevNaam,Firma,LinkType,Aantal,Waarde,Actie
	Set KortTekst=$$$PRGet($$$KortTekst)
	Set LevNr=$$$PRGet($$$LeveranciersNr)
	Set LevNaam=$P(^KLE(^KL1(LevNr),0),"\",2)
	Set LinkType=$$$PRGet($$$LinkType)
	Set Firma=$S($E(LinkType,1,2)="HH":"Halux",1:"NV")
	Set Actie=$P(HistRec,"\",4)
	Set Aantal=$P(HistRec,"\",2)
	Set Waarde=$P(HistRec,"\",12)
	Write PRNr,*9,KortTekst,*9,Firma,*9,LinkType,*9,LevNr,*9,LevNaam,*9,Actie
	Write *9,$$$ExcelDat(+$P(HistRec,"\")),*9,$$$ExcelDat($$CALCDATE^vhLib.DataTypes(+$P(HistRec,"\"),"M","FD")),*9,$$$ExcelNum(Aantal),*9,$$$ExcelNum(Waarde)
	Write !
	Quit
 
WriteHeader
	Write "PRNr	KortTekst	Firma	LinkType	LevNr	LevNm	Actie	Datum	Maand	Aantal	WaardeCifPPL",!
	Quit