PVSTM2 ; Order timings [ 11/08/2003   8:40 PM ]
MBON ;Wie heeft het order ingegeven 
 Set Dev=$$OPEN^vhDEV(,"TRANSINPUT2.txt","W")  Quit:Dev=0
 Set KLNr=0,(Node,BONNr,LNr)=""
 Set ChkDat=$H-300
 ;UITLEVERINGEN
 Use 0 Write "Uitleveringen (openstaande en gefaktureerde)",!
 Use Dev
 Write $TR("KLNr;KLNm;Regio;Order;OrdDat;Maand;Usr;InpDat;InpTijd;ProdGrp;Terugname;OrdTyp;Cnt",";",$C(9)),!
 For  Set KLNr=$O(^KUL(KLNr)) Quit:KLNr=""  Do 
 .For  Set Node=$O(^KUL(KLNr,Node)) Quit:Node=""  Do
 ..;Set Node="F" Do
 ..For  Set BONNr=$O(^KUL(KLNr,Node,BONNr)) Quit:BONNr=""  Do
 ...Set (UsrKey,ORDNr,ORDDat)=""
 ...Kill Cnt
 ...Quit:$$INTDATE^vhLib.DataTypes($P(^KUL(KLNr,Node,BONNr,1),D,2))<ChkDat
 ...Set OrdTyp=$P(^KUL(KLNr,Node,BONNr,1),D,25)
 ...Set LNr=100
 ...For  Set LNr=$O(^KUL(KLNr,Node,BONNr,LNr)) Quit:'LNr  Do
 ....Set Rec=^(LNr)
 ....If $P(Rec,D,17)="KF5" Do  Quit
 .....Do:$D(Cnt) WRITEREC(KLNr,ORDNr,ORDDat,OrdTyp,UsrKey,.Cnt)
 .....Set UsrKey=$P(Rec,D,4) 
 .....Set ORDNr=$P($P(Rec,D,5)," - ")
 .....Set ORDDat=$P($P(Rec,D,5)," - ",2)
 .....Kill Cnt 
 ....Do DEFINE($P(Rec,D,2),$P(Rec,D,3),.Cnt)
 ...Do:$D(Cnt) WRITEREC(KLNr,ORDNr,ORDDat,OrdTyp,UsrKey,.Cnt)
 ...Set (UsrKey,ORDNr,ORDDat)=""
 ...Kill Cnt
 ;ORDERS
 Use 0 Write "Orders",! Use Dev
 Set KLNr=0,(Node,ORDNr,LNr)=""
 For  Set KLNr=$O(^KOD(KLNr)) Quit:KLNr=""  Do
 .For  Set Node=$O(^KOD(KLNr,Node)) Quit:Node=""  Do
 ..For  Set ORDNr=$O(^KOD(KLNr,Node,ORDNr)) Quit:ORDNr=""  Do
 ...Set UsrKey=$P(^KOD(KLNr,Node,ORDNr,1),D,8)
 ...Set ORDDat=$P(^KOD(KLNr,Node,ORDNr,1),D,2)
 ...Set OrdTyp=$P(^KOD(KLNr,Node,ORDNr,1),D,25)
 ...Kill Cnt
 ...Set LNr=100
 ...For  Set LNr=$O(^KOD(KLNr,Node,ORDNr,LNr)) Quit:LNr=""  Do
 ....Set Rec=^(LNr)
 ....Do DEFINE($P(Rec,D,2),$P(Rec,D,3),.Cnt)
 ...Do:$D(Cnt) WRITEREC(KLNr,ORDNr,ORDDat,OrdTyp,UsrKey,.Cnt)
 Close:0'[Dev Dev
 Quit
 
DEFINE(PRNr,Qty,Cnt) 
 ;Cnt via .Local
 Quit:PRNr'?4.7N
 Set ProdGrp=$$PRODGRP^PRODUKT(PRNr)
 Set:ProdGrp="" ProdGrp="*"
 Set Neg=$S(Qty<0:"-",1:"+")
 Set Cnt(ProdGrp,Neg)=$G(Cnt(ProdGrp,Neg))+1
 Quit
 
WRITEREC(KLNr,ORDNr,ORDDat,OrdTyp,UsrRec,Cnt) 
 ;Cnt via .Local
 Quit:$$INTDATE^vhLib.DataTypes(ORDDat)<ChkDat
 Set OrdTyp=$S(OrdTyp="M":"M",OrdTyp="P":"P",1:"O")
 Set ORDDat=$$INTDATE^vhLib.DataTypes(ORDDat)
 Set Maand=$$EXTDATE^vhLib.DataTypes($$CALCDATE^vhLib.DataTypes(ORDDat,"M","FD"),"DK")
 Set ORDDat=$$EXTDATE^vhLib.DataTypes(ORDDat,"DK")
 Set KLId=^KK1(KLNr)
 Set KLNm=$P(^KKL(KLId,0),D,2)
 Set Regio=$P(^KKL(KLId,0),D,20)
 Set UsrKey=$P(UsrRec,"#",1)
 Set DevIO=$P(UsrRec,"#",2)
 Set Usr=$S(UsrKey:$P($G(^vhUSER("D",UsrKey)),D,4),1:UsrKey_"-"_DevIO)
 Use Dev
 Set ProdGrp=""
 For  Set ProdGrp=$O(Cnt(ProdGrp)) Quit:ProdGrp=""  Do
 .Set Neg=""
 .For  Set Neg=$O(Cnt(ProdGrp,Neg)) Quit:Neg=""  Do
 ..Write KLNr,$C(9),KLNm,$C(9),Regio,$C(9),ORDNr,$C(9),ORDDat,$C(9),Maand,$C(9),Usr,$C(9),$$EXTDATE^vhLib.DataTypes($P(UsrRec,"#",3)),$C(9),$$EXTTIME^vhLib.DataTypes($P(UsrRec,"#",3))
 ..Write $C(9),ProdGrp,$C(9),Neg,$C(9),OrdTyp,$C(9),Cnt(ProdGrp,Neg),!
 Quit