RPLKL4 ;RAADPLEGEN KLANTEN ;RPLKL; Do naar OUTPUT, PROC - Quit naar RPLKL1 [ 11/07/2003  8:25 AM ]
 ;
OUTPUT
 New K,List,PapTyp
 Set List=$$GIVELIST^vhPRINTER($$IO^cQ5,"CA;BL")
 Set PapTyp=$S(@DL(1)@(5)>95:"B",1:"S;L;B")
 Do:"P"[$G(PrintMode) ^OUTPUT($S($L(List):"P",1:"M"),"-",PapTyp)
 Do:"T"=$G(PrintMode) ^OUTPUT("T","-",PapTyp)
 Kill PrintMod
 Quit
 
REFRESH
 Set DL(2)=20 D WL^PROC
 Set FP=101 Write @F,@F2
 Quit
 
NAAM() 
 New String,KlantVan
 Set String="Klant "_KC_" "_$P(^KKL(^KK1(KC),0),D,2)
 Set KlantVan=$P(^KKL(^KK1(KC),1),D,10)
 Quit:KlantVan="" String
 Set String=String_D_"Klant van : "
 If KlantVan?4.5N,$D(^KK1(KC)) Set String=String_$P(^KKL(^KK1(KlantVan),0),D,2)
 Else  Set String=String_KlantVan
 Quit String
 ;
 ;Omzet per subgroep
VKG If '$D(^HULP($J,"K"_KC,"G")) Write *7 Quit
 S VKG(11)="Omzetten per subgroep"_D_$$NAAM()
 S VKG(10)="VKGCB^RPLKL4"
 S VKG(2,1)=^LD("L","RPLKLVKGH")
 S VKG(2,2)=^LD("L","RPLKLVKGT")
 Do OUTPUT
 KILL VKG(10)
 DO REFRESH
 Q
VKGCB(Ref) 
 Q:Ref'="E"&(Ref'="H") ""
 New Typ
 If Ref="H" Do
 .S FL(3)=$P(^VKASGR,"\",5)
 .S $P(FL(3),"\",2)=+FL(3)#100\1
 .S $P(FL(3),"\",3)=+FL(3)#100\1-1
 .S $P(FL(3),"\",4)=$P(FL(3),"\",2)_$E(FL(3),5,7)
 .S $P(FL(3),"\",5)=$P(FL(3),"\",3)_$E(FL(3),5,7)
 .S Typ="BR\;1\;\BR"
 If Ref="E" Do
 .S FL(3)=$G(^VKASGR(KC))
 .S Typ="BR\;2"
 Quit Typ 
 ;
 ;Rapporten
RAP If '$D(^HULP($J,"K"_KC,"N")) Write *7 Quit
 S RAP(11)="Rapporten"_D_$$NAAM()
 Do OUTPUT,REFRESH
 Q
 ;
 ;Prijsuitzonderingen
UTZ If '$D(^HULP($J,"K"_KC,"U")) Write *7 Quit
 S UTZ(11)="Prijsuitzonderingen"_D_$$NAAM()
 Do OUTPUT,REFRESH
 Q
 ;
 ;Openstaande fakturen
OFA If '$D(^HULP($J,"K"_KC,"S")) Write *7 Quit
 S OFA(11)="Openstaande fakturen"_D_$$NAAM()
 Do OUTPUT,REFRESH
 Q
 ;
 ;Betalingsgedrag       
BGD If '$D(^HULP($J,"K"_KC,"B")) Write *7 Quit
 S BGD(11)="Betalingsgedrag"_D_$$NAAM()
 Do OUTPUT,REFRESH
 Q
 ;
 ;Verkoopanalyze
VKA If '$D(^HULP($J,"K"_KC,"V")) Write *7 Quit
 S VKA(11)="Verkoopanalyze"_D_$$NAAM()
 S VKA(10)="VKACB^RPLKL4"
 Do OUTPUT
 Kill VKA(10)
 DO REFRESH
 Q
VKACB(Ref) 
 Q:Ref'="E" ""
 S FL(3)="" I $D(^HULP($J,"K"_KC,"V")) S $P(FL(3),D,12)=^("V")
 Quit "BR;\;"
 
 ;Koopgedrag analyze
KGA If '$D(^HULP($J,"K"_KC,"KGA")) Write *7 Quit
 S KGA(11)="Koopgedrag analyze"_D_$$NAAM()
 Do OUTPUT
 Kill KGA(11)
 Do REFRESH
 Quit
 
 ;
 ;Faktuurlijnen
FLD If '$D(^HULP($J,"K"_KC,"F")) Write *7 Quit
 New Mem
 Do
 .New DL,FPLD,FMTK,FMTk
 .Merge FPLD=FLD
 .If $D(^HULP($J,"K"_KC,"F",0)) Set Mem=^(0) Kill ^(0)
 .Set DL(1)="FPLD",FPLD(11)="Faktuurlijnen"_D_$$NAAM(),FPLD(2,0)=FPLD(2)
 .Do OUTPUT
 Set:$D(Mem) ^HULP($J,"K"_KC,"F",0)=Mem
 Do REFRESH
 Q
 ;
 ;Proformalijnen (Monsters)
PLD If '$D(^HULP($J,"K"_KC,"P")) Write *7 Quit
 New Mem
 Do
 .New DL,FPLD,FMTK,FMTk
 .Merge FPLD=PLD
 .If $D(^HULP($J,"K"_KC,"P",0)) Set Mem=^(0) Kill ^(0)
 .S DL(1)="FPLD",FPLD(11)="Proformalijnen (Monsters)"_D_$$NAAM(),FPLD(2,0)=FPLD(2)
 .Do OUTPUT
 Set:$D(Mem) ^HULP($J,"K"_KC,"F",0)=Mem
 Do REFRESH
 Q
 
 ;Offertes
OFF If '$D(^HULP($J,"K"_KC,"E")) Write *7 Quit
 S OFF(11)="Offertes"_D_$$NAAM()
 Do OUTPUT
 Do REFRESH
 Q
 ;
 ;Orders
ORD New Mem,MemH,M
 If '$D(^HULP($J,"K"_KC,"O")) Write *7 Quit
 S Mem=ORD(2),ORD(2)=$P(ORD(2),"\",1,$L(ORD(2),"\")-1)
 S M=$P(ORD(2),"\",$L(ORD(2),"\")),$P(M,";",6)="",$P(ORD(2),"\",$L(ORD(2),"\"))=M
 S MemH=ORD(8),ORD(8)=$P(ORD(8),"|",1,$L(ORD(8),"|")-1)
 S ORD(11)="Openstaande orders"_D_$$NAAM()
 Do OUTPUT
 S ORD(2)=Mem
 S ORD(8)=MemH
 Do REFRESH
 Q
 ;
 ; Openstaande orders volgens boom en leverweek
OBL New Mem,MemH,M
 If '$D(^HULP($J,"K"_KC,"OBL")) Write *7 Quit
 S Mem=OBL(2),OBL(2)=$P(OBL(2),"\",1,$L(OBL(2),"\")-2)
 S M=$P(OBL(2),"\",$L(OBL(2),"\")),$P(M,";",6)="",$P(OBL(2),"\",$L(OBL(2),"\"))=M
 S MemH=OBL(8),OBL(8)=$P(OBL(8),"|",1,$L(OBL(8),"|")-1)
 S OBL(11)="Openstaande orders"_D_$$NAAM()
 Do OUTPUT
 S OBL(2)=Mem
 S OBL(8)=MemH
 Do REFRESH
 Q
 ;
 ;UitLevering
BON If '$D(^HULP($J,"K"_KC,"L")) Write *7 Quit
 S BON(11)="Openstaande uitleveringen"_D_$$NAAM()
 Do OUTPUT,REFRESH
 Q
 ;
 ;Produktreferentie     
PRF If '$D(^HULP($J,"K"_KC,"R")) Write *7 Quit
 S PRF(11)="Produktreferenties"_D_$$NAAM()
 Do OUTPUT,REFRESH
 Q
 ;
 ;Maandomzetten
MOM If '$D(^HULP($J,"K"_KC,"M")) Write *7 Quit
 S MOM(11)="Maandomzetten"_D_$$NAAM()
 N K
 R *K:1
 D ^OUTPUT("M","",$S(K:$C(K),1:""))
 S FP=2001 W @F,@F1
 Q
 ;
 ;Prijsvergelijk     
SPV 
 New R,RPLSCHAD,KLNr
 If '$D(^HULP($J,"K"_KC,"SPV")) Write *7 Quit
 Kill ^HULP($J,"K"_KC,"SPVOP")
 Merge ^HULP($J,"K"_KC,"SPVOP")=^HULP($J,"K"_KC,"SPV")
 Set KLNr=KC,R=^HULP($J,"K"_KC,"SPVOP"),$P(R,D,1,3)="\T\Totaal"
 Set ^HULP($J,"K"_KC,"SPVOP",($O(^HULP($J,"K"_KC,"SPVOP",""),-1)+1))=R
 Do INIT^vhLISTO("RPLSCHAD","LIJST"_$G(SchMarge)_$G(RplOldSchad),.RPLSCHAD)
 Set RPLSCHAD(1)="^HULP($J,""K""_KC,""SPVOP"")"
 For  Quit:RPLSCHAD(2)'["sFL(1)"  Set RPLSCHAD(2)=$P(RPLSCHAD(2),"sFL(1)")_"FL(3)"_$P(RPLSCHAD(2),"sFL(1)",2)
 For  Quit:RPLSCHAD(2,"L")'["sFL(1)"  Set RPLSCHAD(2,"L")=$P(RPLSCHAD(2,"L"),"sFL(1)")_"FL(3)"_$P(RPLSCHAD(2,"L"),"sFL(1)",2)
 Set RPLSCHAD(11)=$S(VTB="!":"Oude p",1:"P")_"rijsvergelijk"_D_$$NAAM()
 Set RPLSCHAD(10)="PERC^RPLKL4"
 Do OUTPUT
 Kill ^HULP($J,"K"_KC,"SPVOP")
 Q
 ;
 ;Berekenen omzet% prijsvergelijk
PERC(Rec) 
 New Perc
 If $E(Rec,1,5)="^HULP" Set Rec=@Rec
 Set Perc=$$PERC^RPLSCHAD(Rec),FL(3,"P")=Perc
 Quit $S($P(Rec,D,2)="T":"BR;\;",1:"")
 ;
MENU 
 New Input
 Do CALL^vhMenu("RPLKL","F*")
 Set R=$G(Input)
 Quit
 ;
SPEC 
 New Input,Menu
 Quit:'$D(DL)
 Set Menu="RPLKLSPEC"
 Do:$D(@DL(1)@(3)) CALLSPEC^vhMenu(@DL(1)@(3)+@DL(1)@(6)-1_";80",Menu,"")
 Do:'$D(@DL(1)@(3)) CALLSPEC^vhMenu(@DL(1)@("POS")+@DL(1)@("SELECT")-1_";80",Menu,"")
 Set R=$G(Input)
 Quit
 ;
CHKMENU(Menu) 
 New AddMenu,PRNr
 Set AddMenu=0
 If Menu="LINK" Do
 .If "\E\O\X\L\R\S\U\N\§\"[(D_VTB_D) Set AddMenu=1 Quit
 .If "\F\Z\M\B\Y\"[(D_VTB_D),U4'="D" Set AddMenu=1 Quit
 .If $G(VTB)="S",$G(U4)'="D",$P($G(^HULP($J,"K"_KC,"S",OFA(6))),D,2)="F" Set AddMenu=1 Quit
 .If VTB="F",$D(^HULP($J,"K"_KC,"F",FLD(6))) Set PRNr=$P(^(FLD(6)),D,3)
 .If VTB="Z",$D(^HULP($J,"K"_KC,"P",PLD(6))) Set PRNr=$P(^(PLD(6)),D,3)
 .If VTB="M",DEM,$D(^HULP($J,"K"_KC,"M",BP,DEM(6))) Set PRNr=$P(^(DEM(6)),D,1)
 .If VTB="V",$D(^HULP($J,"K"_KC,"VM",VMB(6))) Set PRNr=$P(^(VMB(6)),D,15)
 .If VTB="Y",$D(^HULP($J,"K"_KC,"KGA",KGA(6))) Set PRNr=$P(^(KGA(6)),D,15)
 .If VTB="Q",$D(^HULP($J,"K"_KC,"V",VKA(6))) Set PRNr=$P(^(VKA(6)),D,15)
 .If $G(PRNr),$D(^KPR(PRNr)) Set AddMenu=1
 .If VTB="~",$G(%J),$D(^HULP(%J)) Set AddMenu=1
 Quit AddMenu
 ;
CHKITEM(Item) 
 New AddItem,PRNr
 Set AddItem=0
 If "\PRODUKT\SNIJDOOS\"[(D_Item_D) Do
 .If VTB="F",$D(^HULP($J,"K"_KC,"F",FLD(6))) Set PRNr=$P(^(FLD(6)),D,3)
 .If VTB="Z",$D(^HULP($J,"K"_KC,"P",PLD(6))) Set PRNr=$P(^(PLD(6)),D,3)
 .If VTB="L",$D(^HULP($J,"K"_KC,"L",BON(6))) Set PRNr=$P(^(BON(6)),D,3)
 .If VTB="M",DEM,$D(^HULP($J,"K"_KC,"M",BP,DEM(6))) Set PRNr=$P(^(DEM(6)),D,1)
 .If VTB="E",$D(^HULP($J,"K"_KC,"E",OFF(6))) Set PRNr=$P(^(OFF(6)),D,3)
 .If VTB="O",$D(^HULP($J,"K"_KC,"O",ORD(6))) Set PRNr=$P(^(ORD(6)),D,3)
 .If VTB="R",$D(^HULP($J,"K"_KC,"R",PRF(6))) Set PRNr=$P(^(PRF(6)),D,2)
 .If VTB="V",$D(^HULP($J,"K"_KC,"VM",VMB(6))) Set PRNr=$P(^(VMB(6)),D,15)
 .If VTB="Y",$D(^HULP($J,"K"_KC,"KGA",KGA(6))) Set PRNr=$P(^(KGA(6)),D,15)
 .If VTB="Q",$D(^HULP($J,"K"_KC,"V",VKA(6))) Set PRNr=$P(^(VKA(6)),D,15)
 .If VTB="§",$D(^HULP($J,"K"_KC,"DIRORD",DIRORD("SELECT"))) Set PRNr=$P(^(DIRORD("SELECT")),D,4)
 .If VTB="X",$D(^HULP($J,"K"_KC,"OBL",OBL(6))) Set PRNr=$P(^(OBL(6)),D,3)
 .If VTB="~",$G(%J) Set PRNr=$P($G(^HULP(%J,List("SELECT"))),D,2)
 .If $G(PRNr),$D(^KPR(PRNr)) Set AddItem=1
 If Item="SNIJDOOS",AddItem,'$L(##class(BL.Prod.OptiBox.Diverse).HasOptiData(PRNr)) Set AddItem=0
 Quit AddItem
 ;
 ; Sijden van een overdoos vanuit het Link-menu
SnijDoos 
 New PRNr
 If VTB="F",$D(^HULP($J,"K"_KC,"F",FLD(6))) Set PRNr=$P(^(FLD(6)),D,3)
 If VTB="Z",$D(^HULP($J,"K"_KC,"P",PLD(6))) Set PRNr=$P(^(PLD(6)),D,3)
 If VTB="L",$D(^HULP($J,"K"_KC,"L",BON(6))) Set PRNr=$P(^(BON(6)),D,3)
 If VTB="M",DEM,$D(^HULP($J,"K"_KC,"M",BP,DEM(6))) Set PRNr=$P(^(DEM(6)),D,1)
 If VTB="E",$D(^HULP($J,"K"_KC,"E",OFF(6))) Set PRNr=$P(^(OFF(6)),D,3)
 If VTB="O",$D(^HULP($J,"K"_KC,"O",ORD(6))) Set PRNr=$P(^(ORD(6)),D,3)
 If VTB="R",$D(^HULP($J,"K"_KC,"R",PRF(6))) Set PRNr=$P(^(PRF(6)),D,2)
 If VTB="V",$D(^HULP($J,"K"_KC,"VM",VMB(6))) Set PRNr=$P(^(VMB(6)),D,15)
 If VTB="Y",$D(^HULP($J,"K"_KC,"KGA",KGA(6))) Set PRNr=$P(^(KGA(6)),D,15)
 If VTB="Q",$D(^HULP($J,"K"_KC,"V",VKA(6))) Set PRNr=$P(^(VKA(6)),D,15)
 If VTB="§",$D(^HULP($J,"K"_KC,"DIRORD",DIRORD("SELECT"))) Set PRNr=$P(^(DIRORD("SELECT")),D,4)
 If VTB="X",$D(^HULP($J,"K"_KC,"OBL",OBL(6))) Set PRNr=$P(^(OBL(6)),D,3)
 If VTB="~",$G(%J) Set PRNr=$P($G(^HULP(%J,List("SELECT"))),D,2)
 If $G(PRNr),$D(^KPR(PRNr)) Do SnijDoos^PRODUKT8(PRNr)
 Quit
 ;
PRINT
 If VTB="E" Goto OFF
 If VTB="O" Goto ORD
 If VTB="L" Goto BON
 If VTB="F" Goto FLD
 If VTB="Z" Goto PLD
 If VTB="B" Goto BGD
 If VTB="G" Goto VKG
 If VTB="N" Goto RAP
 If VTB="Q" Goto VKA
 If VTB="R" Goto PRF
 If VTB="S" Goto OFA
 If VTB="U" Goto UTZ
 If VTB="X" Goto OBL
 If VTB="Y" Goto KGA
 If VTB="V" Do PRINT^RPLMBON
 If VTB="&" Goto SPV
 If VTB="!" Goto SPV
 Quit
 ;
DPRINT(Type) 
 New Nummer
 Set Type=$S(Type="E":"A",Type="Z":"V",1:Type)
 If Type="A" Set Nummer=$P(^HULP($J,"K"_KC,"E",@DL(1)@(6)),D,15)
 If Type="O" Set Nummer=$P(^HULP($J,"K"_KC,"O",@DL(1)@(6)),D,15)
 If Type="L" Set Nummer=$P(^HULP($J,"K"_KC,"L",@DL(1)@(6)),D,10)
 If Type="F" Set Nummer=$P(^HULP($J,"K"_KC,"F",@DL(1)@(6)),D,16)
 If Type="V" Set Nummer=$P(^HULP($J,"K"_KC,"P",@DL(1)@(6)),D,16)
 Do
 .If Type="L",'$$CHKBON^RPLKL1(Nummer) Quit
 .Do STORE^vhTERMINA(),EXTERN^DCPRINT(Type,Nummer,0,"\V\F\"[(D_Type_D),1),REFRESH^vhTERMINA()
 Quit
 ;
FAX 
 If VTB="V",$$CHECKFAX^RPLMBON(KC)=1 Goto FAX^RPLMBON
 Set Locals("KC")=KC
 Do DO^vhPROGRAM("FREEFAX^DCFAX(""K"",KC)")
 Quit
 ;
EDI 
 New Locals
 If $$CHKFILE^ATKEDI(KC) Do
 .Set Locals("KC")=KC
 .Do DO^vhPROGRAM("VERWERK^ATKEDI(KC)")
 .Set VTB="O",U4="REFRESH"
 Quit
 ;
EDE 
 New Locals
 If $$CHKORD^ATKEDE(KC) Do
 .Set Locals("KC")=KC
 .Do DO^vhPROGRAM("VERWERK^ATKEDE(KC)")
 .Set VTB="O",U4="REFRESH"
 Quit
 ;
MAIL 
 New MailId
 Set Locals("KC")=KC,Locals("VTB")=$G(VTB),Locals("Refer")="KL\"_KC_"\R\"_$G(VTB)
 Do XECUTE^vhPROGRAM("Set MailId=$$EXTERN^vhMAIL(""KL"",KC,"""","""","""",.Refer)")
 Quit
 ;
KLACHT 
 New R,KLNr,ORDNr,BONNr,FAKTNr,PROFNr,OLNr,BLNr,OrdTyp
 Set KLNr=KC
 New KC
 If VTB="O",$D(^HULP($J,"K"_KLNr,"O")) Do
 .Set R=^HULP($J,"K"_KLNr,"O",@DL(1)@(6)),ORDNr=$P(R,D,15),OLNr=$P(R,D,16)
 .Set R=^KOD(KLNr,"F",ORDNr,1),OrdTyp=$P(R,D,25)
 .If OrdTyp="P" Set R="PROF^KLACHT("_KLNr_","_ORDNr_")"
 .Else  Set R="ORD^KLACHT("_KLNr_","_ORDNr_","_OLNr_")"
 Else  If VTB="L",$D(^HULP($J,"K"_KLNr,"L")) Do
 .Set R=^HULP($J,"K"_KLNr,"L",@DL(1)@(6)),BONNr=$P(R,D,10),BLNr=$P(R,D,11)
 .Set R="BON^KLACHT("_KLNr_","_BONNr_","_BLNr_")"
 Else  If VTB="F",$D(^HULP($J,"K"_KLNr,"F")) Do
 .Set R=^HULP($J,"K"_KLNr,"F",@DL(1)@(6)),FAKTNr=$P(R,D,16),BONNr=$P(R,D,17),BLNr=$P(R,D,18)
 .Set R="FAKT^KLACHT(,"_FAKTNr_","_BONNr_","_BLNr_")"
 Else  If VTB="Z",$D(^HULP($J,"K"_KLNr,"P")) Do
 .Set R=^HULP($J,"K"_KLNr,"P",@DL(1)@(6)),PROFNr=$P(R,D,16),BONNr=$P(R,D,17),BLNr=$P(R,D,18)
 .Set R="FAKT^KLACHT(""P"","_PROFNr_","_BONNr_","_BLNr_")"
 Else  If VTB="S",$D(^HULP($J,"K"_KLNr,"S")) Do
 .Set R=^HULP($J,"K"_KLNr,"S",@DL(1)@(6)),FAKTNr=$P(R,D)
 .If $P(R,D,2)="W" Set R="" Write *7 Quit
 .Set R="FAKT^KLACHT(,"_FAKTNr_")"
 Else  Set R="KLANT^KLACHT("_KLNr_")"
 Do:$L($G(R)) XECUTE^vhPROGRAM("Do "_R)
 Quit
 ;
 ; Een SMS verzenden
SMS(KLNr)
 Do STORE^vhTERMINA()
 Xecute FLO
 Do ##class(CHUI.Derde.SMSService).Run()
 Do REFRESH^vhTERMINA()
 Quit
 ;