#Include BL.Derde.Kennis
 
RPLKL5 ;RAADPLEGEN KLANTEN (KennisAnker) ;RPLKL;
 
 ; Tonen van alle ankers
ALL(KLNr)
 New PopUp
 Set PopUp("Buttons")="OK;NIEUW;WIJZIG"
 Set PopUp("Titel")="Alle"
 New NietTeTonenItemsOuderDan6MaandVanRubrieken set NietTeTonenItemsOuderDan6MaandVanRubrieken = $listbuild($$$adContactLogging,$$$adContactLoggingBoekhouding) 
 Quit $$Read(KLNr,,$LB($$$adSkip($$$adContactLogging),$$$adSkip($$$adOrderVerwerkingFacturatie)),1,.PopUp,$$$cpNoCheck,NietTeTonenItemsOuderDan6MaandVanRubrieken)
 ;
 ; Tonen van alle ongelezen ankers
ALLUnRead(KLNr)
 New PopUp
 Set PopUp("Buttons")="GELEZEN;ANNULEER;NIEUW;WIJZIG"
 Set PopUp("Titel")="Ongelezen"
 Quit $$Read(KLNr,,,,.PopUp)
 ;
 ; Tonen van de ongelezen contact log (OV en BKH)
OVBKHUnRead(KLNr)
 If $$IsGroep^vhUSER(,"BOEKH") Quit $$BKHUnRead(KLNr)
 Quit $$OVUnRead(KLNr)
 ;
 ; Tonen van de ongelezen contact log betreffende OV
OVUnRead(KLNr)
 New PopUp
 Set PopUp("Buttons")="GELEZEN;ANNULEER;NIEUW;WIJZIG"
 Set PopUp("Titel")="Ongelezen (OV)"
 Quit $$Read(KLNr,"ORDVW",$LB($$$adContactLogging,$$$adContactDoelstelling,$$$adpGetAll($$$adOrderVerwerking)),,.PopUp)
 ;
 ; Tonen van de ongelezen contact log betreffende de boekhouding
BKHUnRead(KLNr)
 New PopUp
 Set PopUp("Buttons")="GELEZEN;ANNULEER;NIEUW;WIJZIG"
 Set PopUp("Titel")="Ongelezen (BKH)"
 Quit $$Read(KLNr,"BOEKH",$LB($$$adContactLoggingBoekhouding),,.PopUp)
 ;
 ; Tonen van de ongelezen ankers betreffende CON(tact)
CONUnRead(KLNr)
 New PopUp
 Set PopUp("Buttons")="GELEZEN;ANNULEER;NIEUW;WIJZIG"
 Set PopUp("Titel")="Ongelezen (Contact)"
 Quit $$Read(KLNr,,$LB($$$adpGetAll($$$adContact)),,.PopUp)
 ;
ConLogAll(KLNr)
 New PopUp
 Set PopUp("Buttons")="GELEZEN;ANNULEER;NIEUW;WIJZIG"
 Set PopUp("Titel")="Alle (Contact logging)"
 Set PopUp("ConLog")=1
 Quit $$Read(KLNr,,$LB($$$adContactLogging,$$$adContactLoggingBoekhouding),1,.PopUp)
 ;
 ; Tonen van de ongelezen ankers volgens selectie
Read(KLNr,GebruikersGroep,ActieDomein,BypassAutoShow,PopUp,CheckProd,NietTeTonenItemsOuderDan6MaandVanRubrieken)
 New Input
 Set GebruikersGroep=$G(GebruikersGroep),ActieDomein=$G(ActieDomein)
 If GebruikersGroep'="",'$$IsGroep^vhUSER(,GebruikersGroep)
 Else  Do  ; Indien geen GebruikersGroep gedefinieerd of de gebruiker behoord tot de GebruikersGroep
 . Set PopUp("KLNr")=KLNr,PopUp("List")=1,PopUp("Criteria",2)=KLNr_" "_$P(^KKL(^KK1(KLNr),0),D,2)
 . Set PopUp("Oorsprong")="RPLKL"
 . Set Input=##class(CHUI.Derde.Kennis.Kennis).PopUp(KLNr,ActieDomein,,$G(CUserId,$G(QU(1))),,,,$G(CheckProd,$$$cpEmpty),+$G(BypassAutoShow),.PopUp,.NietTeTonenItemsOuderDan6MaandVanRubrieken)
 . If $D(KennisAnker) Kill KennisAnker Do ToonAantal(KLNr)
 Quit $G(Input)
 ;
 ;Toon aantal ankers
ToonAantal(KLNr)
 New R
 Do Init
 If $G(KennisAnker("Aantal")) Do
 . Set R=""""_$J("Kennisanker : "_KennisAnker("Aantal"),30)_""""
 . If $LL($G(KennisAnker("Contact"))),$LI(KennisAnker("Contact")),KennisAnker("IsOV") Set $E(R,2,11)="",R=R_",""/"","_FMTB_",""Contact"","_FMTb
 . If $LL($G(KennisAnker("NotRead"))),$LI(KennisAnker("NotRead")),'KennisAnker("IsOV") Set $E(R,2,11)="",R=R_",""/"","_FMTB_",""Ongelezen"","_FMTb
 Else  Set R=""""_$J("",30)_""""
 Set FP=250
 Write @F,@R
 If $L($G(KennisAnker("DoelStel"))) Set R=FMTK_",""DOELSTELLING"","_FMTk
 Else  Set R=""""_$J("",12)_""""
 Set FP=238
 Write @F,@R
 Quit
 ;
 ; Ophalen aantal ankers
GetAantal(KLNr)
 Quit ##class(BL.Derde.Kennis.Kennis).GetAnkerCountViaKlant(KLNr)
 ;
 ; Initialisatie ankers
Init
 New Aantal,lbIDs,varErrStr
 Do:$G(KennisAnker("KLNr"))'=KLNr
 . Kill KennisAnker
 . Set KennisAnker("KLNr")=KLNr
 . Set KennisAnker("IsOV")=$$IsGroep^vhUSER(,"ORDVW")
 . Set Aantal=$$GetAantal(KLNr)
 . Do:Aantal
 . . Set KennisAnker("Aantal")=Aantal
 . . If KennisAnker("IsOV") Do
 . . . Set lbIDs=##class(BL.Derde.Kennis.Kennis).GetIDsToPopup(KLNr,.varErrStr,$LB($$$adpGetAll($$$adContact)),,$G(CUserId,$G(QU(1))),,,,$$$cpEmpty)
 . . . Set KennisAnker("Contact")=$LB($LL(lbIDs),lbIDs)
 . . If 'KennisAnker("IsOV") Do
 . . . Set lbIDs=##class(BL.Derde.Kennis.Kennis).GetIDsToPopup(KLNr,.varErrStr,"",,$G(CUserId,$G(QU(1))),,,,$$$cpEmpty)
 . . . Set KennisAnker("NotRead")=$LB($LL(lbIDs),lbIDs)
 . . Set KennisAnker("ConLog")=##class(BL.Derde.Kennis.Kennis).GetIDsToPopup(KLNr,.varErrStr,$LB($$$adContactLogging),,$G(CUserId,$G(QU(1))))
 . Set KennisAnker("DoelStel")=##class(BL.Derde.Kennis.Kennis).GetIDsToPopup(KLNr,.varErrStr,$LB($$$adContactDoelstelling),,,,,,$$$cpNoCheck,1)
 Quit
 ;