#include vhLib.Macro
#include BL.Derde.KlantSpecifiek
#include BL.Derde.LevSpecifiek

ExportNaarShared(TranspNr)
	New FileNaam,Pad,PadEnFile
	Set FileNaam="Transport "_TranspNr_".txt"
	Set Pad=$$DIRUSER^vhDEV()
	Set PadEnFile=$$ExportNaarBestand(TranspNr,Pad,FileNaam)
	Quit

ExportEnFtp(TranspNr,FtpConfiguratie)
	New FileNaam,Pad,PadEnFile,Subject,Body
	Set FileNaam="Transport "_TranspNr_".txt"
	Set Pad="C:\SCRATCH"
	Set PadEnFile=$$ExportNaarBestand(TranspNr,Pad,FileNaam)
	Quit:PadEnFile=""
	Set FtpService=##class(TECH.Ftp.impl.FtpAPI).%New()
	Do FtpService.Connecteer(FtpConfiguratie)
	Do FtpService.VerzendBestand(PadEnFile,FileNaam)
	Do FtpService.VerbreekVerbinding()
	Do DELFILE^vhDEV(PadEnFile)
	Do ##class(vhLib.Logger).%New("Transport").Info("FTP Transportlijst", "Ftp van transport "_TranspNr_" naar "_FtpConfiguratie.Adres)
	Quit
	
ExportEnMail(TranspNr,lbAdressen)
	New FileNaam,Pad,PadEnFile,Subject,Body
	Set FileNaam="Transport "_TranspNr_".txt"
	Set Pad="C:\SCRATCH"
	Set PadEnFile=$$ExportNaarBestand(TranspNr,Pad,FileNaam)
	Quit:PadEnFile=""
	Set lbAttachments=$LB($LB(PadEnFile))
	Set Subject="Transportlijst "_TranspNr
	Set Body="Afsluiting van transport "_TranspNr_", details zie bijlag."_$$$CRLF
	Set Mail=$$SendMiniMail^vhLib.Mail("RDL@VANHOECKE.BE",lbAdressen,Subject,Body,,,,,lbAttachments)
	Do DELFILE^vhDEV(PadEnFile)
	Do ##class(vhLib.Logger).%New("Transport").Info("Mail Transportlijst", "Mail van transport "_TranspNr_" naar "_$ListToString(lbAdressen))
	Quit

ExportNaarBestand(TranspNr,Pad,FileNaam)
	New %J,Dev,D
	Set D="\"
	Quit:'$G(TranspNr) ""
	Do Init
	Quit:'$D(^HULP(%J)) ""
	Set Dev=$$OPEN^vhDEV(Pad,FileNaam,"W","M")
	Use Dev
	Do WriteHeader
	Do ExportCache
	Do CLOSE^vhDEV(Dev)
	Quit $$FULLPAD^vhDEV(Pad,FileNaam)
	
Init
	Set %J=$$%J^vhRtn1()
	Kill ^HULP(%J)
	Do SortBody^DCTRANSP(%J,TranspNr)
	Quit
	
ExportCache	
	New SortKey,GroepNr
	Set SortKey=""
	For  Set SortKey=$O(^HULP(%J,SortKey)) Quit:SortKey=""  Do
	. Set GroepNr=^HULP(%J,SortKey)
	. Do WriteAdres(TranspNr,GroepNr)
	Quit

WriteHeader
	Write $TR("TranspNr,GroepNr,Type,ContactNr,Naam,Toenaam,StraatEnNr,PostNr,Woonplaats,Land,Taal,Rembours,Munt,Gewicht,EuroPallet,Colli,Langgoed,HalvePallet,GrootPallet",",",$c(9))
	Write !
	Quit

WriteAdres(TranspNr,GroepNr)
	New TranspRec,TranspType,ContractRef,ContactType,Rembours,Gewicht,LevAdr,Naam,ToeNaam,Adres,PostNr,Woonpl,Land,KLTaal,Munt,EPallet,Collo,LangGoed,KPallet,BPAllet
	Set TranspRec=^TRANSP("D",TranspNr,"D",GroepNr)
	Set ContactRef=$P(TranspRec,"\")
	Set ContactType=$P(TranspRec,"\",6)
    Set:ContactType="" ContactType="K"
	Set Rembours=$P(TranspRec,"\",2)
    Set Gewicht=$P(TranspRec,"\",3)
 	Set TranspType=$P(^TRANSP("D",TranspNr),"\",5)
	Set LevAdr=$$LEVADR^TRANSPL(TranspNr,GroepNr)
 	Set Naam=$P(LevAdr,"\",2)
 	Set ToeNaam=$P(LevAdr,"\",3)
 	Set Adres=$P(LevAdr,"\",5)
 	Set PostNr=$P(LevAdr,"\",6)
 	Set:PostNr?1.2A1"-".E PostNr=$P(PostNr,"-",2,99) ; land prefix moet eraf voor TTC
 	Set Woonpl=$P(LevAdr,"\",7)
 	Set Land=$$LAND^vhRtn1($P(LevAdr,"\",8))
 	Set KlTaal=$P(LevAdr,"\",9) Set:KlTaal="" KlTaal="N"
	Set Munt=$$MUNT^TRANSPZ(ContactType,ContactRef)
 	Set EPallet=$G(^TRANSP("D",TranspNr,"D",GroepNr,"Q","E"))
 	Set Collo=$G(^TRANSP("D",TranspNr,"D",GroepNr,"Q","C"))
 	Set LangGoed=$G(^TRANSP("D",TranspNr,"D",GroepNr,"Q","L"))
	Set KPallet=$G(^TRANSP("D",TranspNr,"D",GroepNr,"Q","P"))
	Set BPallet=$G(^TRANSP("D",TranspNr,"D",GroepNr,"Q","B"))
	Write TranspNr,*9,GroepNr,*9,TranspType
	Write *9,ContactRef,*9,Naam,*9,ToeNaam,*9,Adres,*9,PostNr,*9,Woonpl,*9,Land,*9,KlTaal
	Write *9,$$$ExcelNum(Rembours),*9,Munt,*9,$$$ExcelNum(Gewicht)
	Write *9,$$FmtAantal(EPallet),*9,$$FmtAantal(Collo),*9,$$FmtAantal(LangGoed),*9,$$FmtAantal(KPallet),*9,$$FmtAantal(BPallet)
	Write !
	
FmtAantal(VerpakRecord)
	Set Aantal=+VerpakRecord
	Set:Aantal=0 Aantal=""
	Quit Aantal