cA5001(LN,KOL,WIN,EKOL,SC)	;Nieuwe toegangscontrole ;%A5001 ;[ 03/10/00  12:14 PM ]
	; LN = beginlijn
	; KOM = beginkolom
	; WIN = 1 = window rond
	; EKOL = eindkolom
	; SC = 1 : handscanners (PDT)
	;    = 2 : VRC
	;
	; S K=$$^cA5001(...)
	;
	; Uitgang : var RQ
	;               |-> Q_D_QM_D_QN_D_QU_D_QT_D_QTU_D_QU(1)_D_QU(2)
	;                                                  |        |
	;                                      intern nr init.   naam gebruiker
	;
T1	;Uw initialen  : ;Uw wachtwoord : ;Initialen  : ;Wachtwoord : ;
T2	;Deze poort is geblokkeerd;
T3	;Uw wachtwoord is vervallen\"[] = nu wijzigen   .[] = later wijzigen";
T4	;Gebruiker ; is geblokkeerd;
T5	;Initialen geblokkeerd;
T6	;Poort geblokkeerd;
T7	;Geen toegang tot dit systeem;Geen toegang;
T8	;Gelieve eerst uw wachtwoord in te vullen;_old
T9	;Gelieve eerst uw wachtwoord te wijzigen;Wachtwoord wijzigen;
	;
T1F	;Vos initiales : ;Votre mot de passe : ;Initiales  : ;Code : ;
T2F	;Cette porte est bloquée;
T3F	;Votre mot de passe n'est plus valable\"[] = modifier immédiatement   .[] = modifier plus tard";
T4F	;L'utilisateur ; est bloqué;
T5F	;Initiales bloqués;
T6F	;Porte bloquée;
T7F	;Pas d'accès à ce système;Pas d'accés;
T8F	;Veuillez d'abord entrer votre mot de passe;
T9F	;Veuillez d'abord modifier votre mot de passe;Modifier mot de passe;
	;
T1E	;Your initials  : ;Your password : ;Initials  : ;Password : ;
T2E	;This port is blocked;
T3E	;Your password is expired\"[] = modify now   .[] = modify later";
T4E	;User ; is blocked;
T5E	;Initials blocked;
T6E	;Port blocked;
T7E	;No entry to this system;Entry not allowed;
T8E	;Please fill in your password first;
T9E	;Please change your password first;Change password;
	;
T1D	;Ihre Initialen  : ;Ihr Losungswort : ;Initialen   : ;Losungswort : ;
T2D	;Diese Pforte ist blockiert;
T3D	;Ihr Losungswort ist verfallen\"[] = jetzt ändern   .[] = später ändern";
T4D	;Gebraucher ; ist blockiert;
T5D	;Initialen sind blockiert
T6D	;Pforte ist blockiert;
T7D	;Kein Zutritt zu diesem System;
T8D	;Bitte führen Sie erst ihr Losungswort ein;
T9D	;Bitte ändern Sie erst ihr Losungswort;
	;
	; Initialisatie
	S $ZT="^cA405"
	N UQC,USC,I,J,T,UI1QU,B,PWVERV,K,LNW,KOLW,PWS,PW,RQ,ERLOG,NUQ,NQT,LOGUI1,BLOK,PBLOK,T
	S io=$G(io,$$IO^cQ5),RQ="",NQT=$G(QT)
	S (LNW,KOLW)=""
	I '$L($G(Q)) S Q="DAM"
	;
1	; poort geblokkeerd ?
	I $P($O(^ILOGIN($ZU($ZV'["MSM"*5),"LOGIN",112,io_" "))," ")=io S K=$P($T(@("T"_$S($G(SC):6,1:2)_NQT)),U,2) S K=$$TXT(250) G YZ:'K G QQ
	;
2	; initialen
	K PBLOK,BLOK,LOGUI1
	I $G(WIN) D O^cA612(LN,KOL,5,$G(EKOL,70),1,0,0,0) S WIN=0,LNW=1,KOLW=2
	S (RK,K)="",I=$P($T(@("T1"_NQT)),U,2) W /CUP($S(LNW:LNW,1:LN),$S(KOLW:KOLW,1:KOL)),I,/WCMD
	F T=1:1:3 Q:RK=27!$L(K)  D ^cAFA0(K,LN+LNW+(+$G(SC)'=0),$L(I)*'$G(SC)+KOL+KOLW,3,7,27,60,0,0)
	I RK=27!(K="-")!'$L(K) S K="-" G YZ
	S NQU=$$UC^cAFA1(K) 
	W /CUP($S(LNW:LNW,1:LN)+(+$G(SC)'=0),$L(I)*'$G(SC)+$S(KOLW:KOLW,1:KOL)),NQU,/WCMD
	; wachtwoord
	S (RK,K)=""
	S I=$P($T(@("T1"_NQT)),U,3) W /CUP($S(LNW:LNW,1:LN)+2,$S(KOLW:KOLW,1:KOL)),I,/WCMD
	D ^cAFA0(K,LN+LNW+2+(+$G(SC)'=0),$L(I)*'$G(SC)+KOL+KOLW,30,7,27,60,1,0)
	I RK=27!(K="-") G 2
	S PW=K,PWS=$$SCR^cA50011(K),RQ=""
	;
3	; initialen geblokkeerd
	K ERLOG
	I NQU'="SU",$P($O(^ILOGIN($ZU($ZV'["MSM"*5),"LOGIN",113,NQU_" "))," ")=NQU G FOUT
	;
4	; initialen gekend en operationeel + goed paswoord
	S I=NQU_" ",UI1QU="" K B
	F  S I=$O(^INDEX(0,"USR",101,I)) Q:$P(I," ")'=NQU  D  Q:$L(UI1QU)
	. S B(1)=$G(^DATA(0,"USR",^(I),0)) I B(1)="" Q
	. F J=2:1:2 S B(J)=$G(^(J-1))
	. I $P(B(1),D,30) Q                   ; buiten gebruik
	. S UI1QU=^INDEX(0,"USR",101,I)
	I '$L(UI1QU) G FOUT
	S NQU=$P(B(1),D),$P(RQ,D,5)=$TR($P(B(1),D,9),"N"),$P(RQ,D,6)=$S($L($P(RQ,D,5)):$F("FDE",$P(RQ,D,5)),1:1)
	;
5	
	; geldig paswoord
	I $P(B(1),D,17)'=PWS S ERLOG=2 G FOUT 
	; is er reeds een paswoord ingevuld ??
	S NQT=$TR($P(B(1),D,9),"N")
	; I '$L($P(B(1),D,17)) S K=$P($T(@("T8"_NQT)),U,2) S K=$$TXT(250) G 12:'K G QQ
	; moet gewijzigd worden bij eerstvolgende log-in
	I $P(B(2),D,29) S K=$P($T(@("T9"_NQT)),U,+$G(SC)'=0+2) S K=$$TXT(250) G 12:'K G QQ
	;
6	; geldige log-in op dit systeem voor deze gebruiker
	S I=UI1QU_" "
	F  S I=$O(^DATA(0,"USR_SYS.QQM",I)) Q:$P(I," ")'=UI1QU  D  I $L($P(RQ,D,3)) Q
	. I '$D(^(I,0)) Q
	. I $P(^(0),D,30) Q
	. S T=$P(^(0),D,2) Q:T=""
	. I '$D(^DATA(0,"SYS.QQM",T,0)) Q
	. I $P(^(0),D,30) Q
	. S $P(RQ,D,1,2)=$P(^(0),D,2)_D_$P(^(0),D,3),$P(RQ,D,9)=$P(^(0),D,4),$P(RQ,D,10)=$P(^(0),D,5)  ; KU : 27.10.06
	. I '$L($P(RQ,D))!'$L($P(RQ,D,2)) Q
	. I +$p(^(0),D,6)'=+$G(SC) Q  ; KU : 23.01.07 : ingangsmenu laten afhangen van soort scherm : 0=gewoon,1=PDT,2=VRC
	. S T=$P(^(0),D) Q:T=""
	. I '$D(^DATA(0,"SYS",T,0)) Q
	. I $P(^(0),D,30) Q
	. I $P(^(0),D)'=$ZU($ZV'["MSM"*5) Q
	. I $ZV["MSM",'$D(@("^"_$P(RQ,D)_"BA(""MENU"",$P(RQ,D,2),0)")) Q
	. I $ZV["MSM",'$D(@("^"_$P(RQ,D)_"BA(99,1)")) Q
	. I $ZV'["MSM" S NS=$ZU(5) S:$L($P(RQ,D,9)) NS=$P(RQ,D,9) Q:'$D(@("^|"""_NS_"""|"_$P(RQ,D)_"BA(""MENU"",$P(RQ,D,2),0)"))  Q:'$D(@("^|"""_NS_"""|"_$P(RQ,D)_"BA(99,1)"))
	. S $P(RQ,D,3)=^(1)
	I '$L($P(RQ,D,3)) S K=$P($T(@("T7"_QT)),U,+$G(SC)'=0+2) S K=$$TXT(250) G FOUT:'K G QQ
	;
7	; is termijn wachtwoord nog geldig
	I $P(B(2),D,31) G 8  ; wachtwoord vervalt nooit
	S J=$P(B(2),D,23) I 'J S J=$P(^DPAR(0,"PAR","LOGIN",0),D,8)
	I NQU'="SU",$$DC^cAFA1($$HD^cAFA1($$DH^cAFA1($P(B(2),D,24))+J))'>$$DC^cAFA1($$HD^cAFA1($H)) G 9
	;
8	; log-in toegekend,
	; RQ=Q_D_QM_D_QN_D_QU_D_QT_D_QTU_D_QU(1)_D_QU(2)_D_NS_D_terugkeer='EXIT'
	S LOGUI1=$$LOG("",Q,NQU,PW,UI1QU,"","",$G(PWVERV)) K PWVERV
	S $P(RQ,D,4)=$P(B(1),D),$P(RQ,D,7)=UI1QU,$P(RQ,D,8)=$P(B(1),D,2)
	G YZ
	;
9	; aantal logins met vervallen paswoord
	S I=NQU_" zzz",K="",J=$P(^DPAR(0,"PAR","LOGIN",0),D,9)
	F  S I=$O(^ILOGIN($ZU($ZV'["MSM"*5),"LOGIN",107,I),-1) Q:$P(I," ")'=NQU  Q:'$P(^LOGIN($ZU($ZV'["MSM"*5),"LOGIN",^(I),0),D,17)  S K=K+1 I K'<J Q
	I K,K'<J G 12
	;
10	S R="K\22\3\"_$P($T(@("T3"_NQT)),U,2)_"\1\\"".-""[K" D R0  I K="-" G 1
	I '$L(K) G 12
	;
11	S PWVERV=1 G 8
	;
12	S QT=NQT D ^cA517(NQU)
	G 1
	;
F(Q,NQU,NQT,PW,UI1QU,ERLOG,io)	
	; check foutive login vanuit een ander progr.
	; S K=$$F^cA5001(Q,NQU,PW,UI1QU,ERLOG)
	S $ZT="TRAP^cAN000"
	N LOGUI1,PBLOK,BLOK,SWOTHER
	S SWOTHER=1
	I $P($O(^ILOGIN($ZU($ZV'["MSM"*5),"LOGIN",112,io_" "))," ")=io S K=$P($T(@("T"_$S($G(SC):6,1:2)_NQT)),U,2) S K=$$TXT(250) S RQ="-" G YZ:'K G QQ
	;
FOUT	; logging foute log-in
	K LOGUI1
	S LOGUI1=$$LOG($G(LOGUI1),Q,NQU,PW,$G(UI1QU),$G(ERLOG,1)) 
	;
FOUT1	; gebruiker reeds geblokkeerd ?
	I $P($O(^ILOGIN($ZU($ZV'["MSM"*5),"LOGIN",113,NQU_" "))," ")=NQU S BLOK=2 G FOUT3
	;
FOUT2	; aantal opeenvolgende foutieve log-in's voor gebruiker < limiet ?
	S I=NQU_" zzz",K="",J=$P(^DPAR(0,"PAR","LOGIN",0),D,4)
	F  S I=$O(^ILOGIN($ZU($ZV'["MSM"*5),"LOGIN",107,I),-1) Q:$P(I," ")'=NQU  Q:'$P(^LOGIN($ZU($ZV'["MSM"*5),"LOGIN",^(I),0),D,9)  S K=K+1 I K'<J Q
	I K<J G FOUT4
	S BLOK=1
	;
FOUT3	; boodschap gebruiker geblokkeerd
	S K=$S($G(SC):"",1:$P($T(@("T4"_NQT)),U,2))_NQU_$P($T(@("T4"_NQT)),U,3) S K=$$TXT(250) I K G QQ
	S LOGUI1=$$LOG($G(LOGUI1),Q,NQU,PW,$G(UI1QU),$G(ERLOG,1),1)  ; gebruiker blokkeren
	I BLOK=1 D MSG($ZU($ZV'["MSM"*5),$$HD^cAFA1($H),$$HT^cAFA1($H),io,NQU,$S($G(ERLOG)=2:$G(PW),1:""),$P($T(@("T5"_NQT)),U,2))
	;
FOUT4	; poort reeds geblokkeerd ?
	I $P($O(^ILOGIN($ZU($ZV'["MSM"*5),"LOGIN",112,io_" "))," ")=io S PBLOK=2 G FOUT6
	;
FOUT5	; aantal opeenvolgende foutieve log-in's voor poort < limiet ?
	S I=io_" zzz",K="",J=$P(^DPAR(0,"PAR","LOGIN",0),D,3)
	F  S I=$O(^ILOGIN($ZU($ZV'["MSM"*5),"LOGIN",106,I),-1) Q:$P(I," ")'=io  Q:'$P(^LOGIN($ZU($ZV'["MSM"*5),"LOGIN",^(I),0),D,9)  S K=K+1 I K'<J Q
	I K<J G 1:'$G(SWOTHER) S RQ="-" G YZ
	S PBLOK=1
	;
FOUT6	; poort geblokkeerd
	S K=$P($T(@("T"_$S($G(SC):6,1:2)_NQT)),U,2) S K=$$TXT(250) I K G QQ
	S LOGUI1=$$LOG($G(LOGUI1),Q,NQU,PW,$G(UI1QU),$G(ERLOG,1),$G(BLOK),"",$G(PBLOK))  ; poort blokkeren
	I PBLOK=1 D MSG($ZU($ZV'["MSM"*5),$$HD^cAFA1($H),$$HT^cAFA1($H),io,NQU,$S($G(ERLOG)=2:$G(PW),1:""),$P($T(@("T6"_NQT)),U,2))
	;
	G 2:'$G(SWOTHER)
	;
YZ	I '$L($P(RQ,D,4)) S RQ=""
	I $D(WIN) D C^cA612
	Q RQ
	;
LOG(UI1,Q,QU,PW,UI1QU,ERLOG,BLOK,PWVERV,PBLOK)	; logging log-in
	;     Q  = Q-waarde
	;     QU = initialen
	;     PW = wachtwoord
	;  UI1QU = intern nr initialen (indien bestaande)
	;  ERLOG = 1 indien fout log-in
	;   BLOK = 1 indien init. geblokkeerd
	; PWVERV = 1 indien paswoord vervallen
	;  PBLOK = 1 indien poort geblokkeerd
	S $ZT="TRAP^cAN000" 
	N UQC,USC,SW2,SW3,A,B,UFU,U2,ADR,S2
	D DMS^cAN000("UQC","USC","LOGIN") I '$L(UQC)!'$L(USC) Q ""
	S SW3=1,SW2=1,UFU=$S($G(UI1):"W",1:"O")
	I '$G(UI1) D
	. S S2=^DMC(UQC,USC,"DIN")
	. L +@S2 I $G(@S2,1000)'<9999 S @S2=1000
	. L -@S2
	. S UI1=$$NR^cAN000,UI1=$$DC^cAFA1($$HD^cAFA1($H))_UI1
	S (A(1),B(1))=D,U2(1)=""
	D B^cAN000(101,UI1)
	D B^cAN000(102,$ZU($ZV'["MSM"*5))
	D B^cAN000(103,$H)
	D B^cAN000(104,$J)
	D B^cAN000(105,$I)
	D B^cAN000(106,io)
	D B^cAN000(107,$G(QU))
	D B^cAN000(108,$G(UI1QU))
	D B^cAN000(109,$G(ERLOG)>0)
	I $G(ERLOG)=2 D B^cAN000(110,$G(PW))
	I $G(BLOK)!$G(PBLOK) D B^cAN000(111,1)
	I $G(PBLOK) D B^cAN000(112,io)
	I $G(BLOK) D B^cAN000(113,$G(QU))
	D B^cAN000(117,$G(PWVERV))
	S ADR=$S($ZV["MSM":$ZDEV($I),1:$I_"~") I ADR["~" S ADR=$$NBN^cQ5($I)_" "_$$MAC^cQ5($I)
	D B^cAN000(118,ADR)
	D U^cAN000
	S ^cJOB($j,boot,"job","login")=UI1
	Q UI1
	;
MSG(SYS,DT,TD,io,QU,PW,TXT)	; E-mail of Memodata
	; SYS = systeem ($zu(0)
	; DT = datum (dd.mm.jj)
	; TD = uur (mm:hh)
	; io = poort $$IO^cQ5($I)
	; QU = initialen
	; PW = paswoord
	; TXT = tekst
	S $ZT="TRAP^cAN000"
	N INI,A,AAN,CC,TEKSTK,K
	S I=0,INI="",AAN=""
	; opbouw bestemmelingen
	F  S I=$O(^DPAR(0,"PAR","LOGIN",I)) Q:I=""  D
	. S A=^(I) I $P(A,D,30) Q
	. I '$P(A,D,2) Q  ; geen email bij het blokkeren.
	. S INI=INI_$S($L(INI):D,1:"")_$$SIG^cAFA1("USR",$P(A,D),101)
	. I $L($$SIG^cAFA1("USR",$P(A,D),221)) S AAN=AAN_$S($L(AAN):U,1:"")_$$SIG^cAFA1("USR",$P(A,D),221)
	S CC=AAN
	; opbouw tekst
	S TEKST(1)=TXT
	S TEKST(2)=DT_"  -  "_TD
	S TEKST(3)=SYS_"  -  "_io_"  :  "_QU I $L($G(PW)) S TEKST(3)=TEKST(3)_" ("_PW_")"
	S K=$$SIG^cAFA1("PAR","LOGIN",105) I $L(K),K'?1.N X K Q
	I K?1.N,$L($$SIG^cAFA1("PAR.LOGIN.EXE",K,103)) X $P(^(0),D,3)
	Q
	;
TXT(R)	; foutboodschap via %TXT
	S $ZT="TRAP^cAN000"
	N OK
	D O^cA612($P("24\7\7",D,$G(SC)+1),1,$P("1\2\2",D,$G(SC)+1),$P("80\20\40",D,$G(SC)+1),0,0,1,1)
	N F S F="/CUP(1,3)"
	I '$G(SC) X ^cTXT(0,$E($G(NQT)_"N"),R)
	I $G(SC) W @F4,K,$J("",$P("80\20\40",D,$G(SC)+1)-$L(K)),@F5,!,@F4,"[] = ok ",@F5,@F2,@F0
	R *K
	I K=25 W "." R K:9 D ^cA106 I DD_DM_DJ#$H=K S OK=1
	D C^cA612
	Q $G(OK)
	;
OUT	; loggen van het uitloggen
	S $ZT="TRAP^cAN000"
	I '$D(^cJOB($j,boot,"job","login")) Q
	S UI1=^("login")
	D DMS^cAN000("UQC","USC","LOGIN",1) I '$L(UQC)!'$L(USC) Q
	S UREF=$G(^DMC(UQC,USC,"DATA","REF")) I '$L(UREF) Q
	I '$D(@UREF) Q
	S UFU="W",SW3=1
	D R^cAN000 M A=B
	S U2(1)=$P($T(@("T9"_QT)),U,2) D B^cAN000(119,$H) S $P(ULOG(119),D,2,3)=$P(A(1),D,19)_D_$P(B(1),D,19)
	D U^cAN000
	K ^cJOB($j,boot,"job","login")
	Q
	;
QQ	; via cQQ eruit (of %QMSMQ)
	D @$S($ZV'["MSM":"^cQQ",1:"^cQMSMQ")
	S RQ="-"
	G YZ
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
ZZ	; 19.03.07 - 15 u 31 * V8.08