cAB127	;Beheer synoniemen; %AB123 [ 03/29/01  9:33 AM ]
	G YZ
	;
T0	;Beheer DMC ;
T1	;Beheer layout;
T22	;Volgnummer\"Geef het volgnummer van het synoniem waarvan u de layout wenst te wijzigen";
T23	;Volgnummer\"[] = toevoegen   V[] = verwijderen   Y[] = kopiëren";
T24	; Wijzigen layout;
T25	;Index;
T26	;Verplaatsing;
T27	;Lengte;
T28	;Alligneren;
T29	;Output;
T30	;Nummer element;
T31	;Lengte\"nn[] = lengte";
T32	;Alligneren\"[] = links    1[] = rechts";
T33	;Output\"Vb. S K=$$SIG^cAFA1(""PR"",K,101)";
T35	;Invoegen voor volgnr\"[] = invoegen op het einde";
T36	; Verwijderen layout;
T37	;Volgnummer\"Volgnummer van het te verwijderen veld";
T38	;Er is geen layout aanwezig;
T39	;Verwijderen\"V[] = verwijderen   ,[] = hernemen"
	;
	;  Vraag ALIN
ALIN	S R="ALIN\22\3\"_$P($T(@("T32"_QT)),U,2)_"\1\\""1-""[K\\\\\1" D R0 G ALINZ:K="-"
	S $P(^DMC(UQC,USC,"SYN",VOLGNR,"LAY",KEUS),D,4)=ALIN
ALINZ	Q
	;
	;  Vraag BINDEX
BINDEX	S R="BINDEX\22\3\"_$P($T(@("T25"_QT)),U,2)_"\\3\\$L(K)&(K?3N!(""-""[K))\\\\\1" D R0 G BINDEXZ:K="-"
	S $P(^DMC(UQC,USC,"SYN",VOLGNR,"LAY",KEUS),D)=BINDEX
BINDEXZ	Q
	;
	;  Beheer van de layout van een synoniem
	;  SWOP = 1 bij openen
	;       = 0 bij wijzigen VOLGNR=0 men komt uit menu
	;       = 0 bij wijzigen VOLGNR=n men is een layout aan het wijzigen
LAY(SWOP,VOLGNR)	
	D P^cA612(2,1,20,80,1,0,0,1,$P($T(@("T1"_QT)),U,2),0,1,1,0,0)
	N BINDEX,VERPL,LENGTE,ALIN,OUT,MENU,EINDE1,I1,I2 S $ZT="TRAP^cAN000"
	S MENU=0
	;  Layout bewerken vanuit menu
	I (SWOP=0&(VOLGNR'=0))!(SWOP=1) G LAYB
	S MENU=1,VOLGNR=""
LAYA	W /CUP(1,1),@F1
	S NR=0 S I1=0
	F  S I1=$O(^DMC(UQC,USC,"SYN",I1)) Q:I1=""  D
	. S NR=NR+1
	. S MTAB(NR,0)=I1,MTAB(NR,1)="",TEKST="",BINDEX="",I2=""
	. F  S I2=$O(^DMC(UQC,USC,"SYN",I1,I2)) Q:(I2="LAY"!(I2=""))  D
	.. S BINDEX=$P($G(^DMC(UQC,USC,"SYN",I1,I2,"B")),D)
	.. S MTAB(NR,1)=$G(MTAB(NR,1))_I2_U_BINDEX_D
	.. S TEKST=TEKST_$P($G(^DMC(UQC,USC,"SYN",I1,I2,"TAAL","N")),D,3)
	.. S TEKST=TEKST_" ("_BINDEX_") "
	. W /CUP(NR+1,2),$J(NR,2),". ",TEKST
	S R="NUM\22\3\"_$P($T(@("T22"_QT)),U,2)_"\2\\$L(K)&(((K?.N)&((K'<1)&(K'>NR)))!(""-""[K))" D R0 G LAYZ:K="-"  
	S VOLGNR=MTAB(NUM,0)
	;  Bewerken van de gekozen layout
LAYB	D OPEN^cAB1270
	S R="KEUS\22\3\"_$P($T(@("T23"_QT)),U,2)_"\1\\(((K?.1N)&((K'<1)&(K'>(TELLER-1))))!(""YV-""[K))\\\1" D R0
	I KEUS="-" G LAYA:MENU=1 G LAYZ:MENU=0
	I KEUS="Y" D KOPY^cAB1270(VOLGNR) G LAYB
	I KEUS="V" D WEG G LAYB
	I KEUS="" D
	. S BINDEX="",VERPL="",ALIN="",OUT=""
	. K SWOUT
	. D P^cAN230("DMC.LAY","DAM","")
	. I $G(SWOUT) K SWOUT S ^DMC(UQC,USC,"SYN",VOLGNR,"LAY",TELLER)=BINDEX_D_VERPL_D_LENGTE_D_ALIN_D_OUT_D
	. S EINDE1=1
	I EINDE1=1 G LAYB
	I KEUS<(TELLER-1)!(KEUS=(TELLER-1)) D WIJZ
	I EINDE1=1 G LAYB
LAYZ	D C^cA612 Q    
	;
	;  Vraag LENGTE
LENGTE	S R="LENGTE\22\3\"_$P($T(@("T31"_QT)),U,2)_"\2\\(K?1.2N!(""-""[K))&($L(K))\\\\\1" D R0 G LENGTEZ:K="-"
	S $P(^DMC(UQC,USC,"SYN",VOLGNR,"LAY",KEUS),D,3)=LENGTE
LENGTEZ	Q
	;
	;  Wegschrijven van een nieuw synoniem
OPSYN	S EINDE=0
	F i=1:1:2 Q:(EINDE=1)  D
	. I (INDEX(i)="") S EINDE=1 Q
	. S ^DMC(UQC,USC,"SYN",NIEUW,i,"B")=INDEX(i)
	. S ^DMC(UQC,USC,"SYN",NIEUW,i,"TAAL","N")=PROMPTN(i)_D_INPUT(i)_D_OMN(i)_D
	. S ^DMC(UQC,USC,"SYN",NIEUW,i,"TAAL","F")=PROMPTF(i)_D_INPUT(i)_D_OMF(i)_D
	. S ^DMC(UQC,USC,"SYN",NIEUW,i,"TAAL","E")=PROMPTE(i)_D_INPUT(i)_D_OME(i)_D
	. S ^DMC(UQC,USC,"SYN",NIEUW,i,"TAAL","D")=PROMPTD(i)_D_INPUT(i)_D_OMD(i)_D
	. I CONV(i)'="" S ^DMC(UQC,USC,"SYN",NIEUW,i,"CONV")=CONV(i)
	. I XEC(i)'="" S ^DMC(UQC,USC,"SYN",NIEUW,i,"X")=XEC(i)
OPSYNZ	Q
	;
	;  Vraag OUT
OUT	S OUT=$$I^cAB1(OUT,"Execute ivm output")
	I OUT="-" G OUTZ
	S $P(^DMC(UQC,USC,"SYN",VOLGNR,"LAY",KEUS),D,5)=OUT
OUTZ	Q
	;
	;  Maken van een nieuw synoniem
S2	N NIEUW,VOOR,VORIG S $ZT="TRAP^cAN000"
S2A	I (NR=0) S NIEUW=1 S ^DMC(UQC,USC,"SYN","0")=1 G S2E
	; D SORT
S2B	S R="VOOR\22\3\"_$P($T(@("T35"_QT)),U,2)_"\2\\(K?.N&(K'<1)&(K'>NR))!(""-""[K)" D R0 G S2Z:K="-"
S2C	I K="" S NIEUW="",NIEUW=$O(^DMC(UQC,USC,"SYN",NIEUW),-1),NIEUW=NIEUW+1
S2D	I (VOOR'="") D
	. S J=VOOR,VOOR=0
	. F I=1:1:J S VOOR=$O(^DMC(UQC,USC,"SYN",VOOR))
	. S VORIG=$O(^DMC(UQC,USC,"SYN",VOOR),-1)
	. S NIEUW=(VORIG+VOOR)/2
S2E	S (INDEX(1),INDEX(2))="",(PROMPTN(1),PROMPTN(2))=""
S2F	S (PROMPTF(1),PROMPTF(2),PROMPTE(1),PROMPTE(2),PROMPTD(1),PROMPTD(2))="",(INPUT(1),INPUT(2))="",(OMN(1),OMN(2))=""
S2G	S (OMF(1),OMF(2),OME(1),OME(2),OMD(1),OMD(2))="",(CONV(1),CONV(2))="",(XEC(1),XEC(2))=""
S2H	S VOLGNR=NIEUW
S2I	D P^cAN230("DMC.SYN","DAM","")
S2J	D OPSYN
S2K	D LAY(1,VOLGNR)
S2L	; D SORT
S2Z	Q     
	;
	;  Schrijven van de geslecteerde layout
SCHRIJF	S BINDEX=$P($G(^DMC(UQC,USC,"SYN",VOLGNR,"LAY",KEUS)),D)
	S VERPL=$P($G(^(KEUS)),D,2),LENGTE=$P($G(^(KEUS)),D,3)
	S ALINE=$S($P($G(^(KEUS)),D,4)=1:"rechts",1:"links")
	S OUT=$P($G(^(KEUS)),D,5)
	W /CUP(2,2),@F2,"1.",@F6,$P($T(@("T25"_QT)),U,2),@F9,"       : ",BINDEX
	W /CUP(3,2),@F2,"2.",@F6,$P($T(@("T26"_QT)),U,2),@F9,": ",VERPL
	W /CUP(4,2),@F2,"3.",@F6,$P($T(@("T27"_QT)),U,2),@F9,"      : ",LENGTE
	W /CUP(5,2),@F2,"4.",@F6,$P($T(@("T28"_QT)),U,2),@F9,"  : ",ALINE
	W /CUP(6,2),@F2,"5.",@F6,$P($T(@("T29"_QT)),U,2),@F9,"      : ",OUT
SCHRIJFZ	Q
	;
	;  Sorteren van synoniem
SORT	K ^HULP(boot,$J+.07)
	S TEL=0,I1=""
	F  S I1=$O(^DMC(UQC,USC,"SYN",I1)) Q:(I1="")  D
	. M ^HULP(boot,$J+.07,TEL)=^DMC(UQC,USC,"SYN",I1)
	. S TEL=TEL+1
	K ^DMC(UQC,USC,"SYN")
	M ^DMC(UQC,USC,"SYN")=^HULP(boot,$J+.07)
	K ^HULP(boot,$J+.07)
SORTZ	Q
	;
	;  Sorteren van de layout
SORTL	K ^HULP(boot,$J+.07)
	S TEL=0,I1=""
	F  S I1=$O(^DMC(UQC,USC,"SYN",VOLGNR,"LAY",I1)) Q:(I1="")  D
	. S TEL=TEL+1
	. M ^HULP(boot,$J+.07,TEL)=^DMC(UQC,USC,"SYN",VOLGNR,"LAY",I1)
	K ^DMC(UQC,USC,"SYN",VOLGNR,"LAY")
	M ^DMC(UQC,USC,"SYN",VOLGNR,"LAY")=^HULP(boot,$J+.07)
	K ^HULP(boot,$J+.07)
SORTLZ	Q
	;
	;  Vraag VERPL
VERPL	S R="VERPL\22\3\"_$P($T(@("T26"_QT)),U,2)_"\\2\\(K?1.2N!(""-""[K))&($L(K))\\\\\1" D R0 G VERPLZ:K="-"
	S $P(^DMC(UQC,USC,"SYN",VOLGNR,"LAY",KEUS),D,2)=VERPL
VERPLZ	Q
	;
	;  Verwijderen van een layout
WEG	; D SORTL
	I '$D(^DMC(UQC,USC,"SYN",VOLGNR,"LAY",1)) S K=$P($T(@("T38"_QT)),U,2) D TXT^cAFA1(250) G WEGZ
WEGA	S R="VOLG\22\3\"_$P($T(@("T37"_QT)),U,2)_"\2\\$L(K)&(((K?.N)&((K'<1)&(K'>(TELLER-1))))!(""-""[K))" D R0 G WEGZ:K="-"
	S KEUS=VOLG
	D P^cA612(12,0,10,80,1,0,1,0,$P($T(@("T36"_QT)),U,2),0,1,1,0,0)
	D SCHRIJF
	S R="VERWI\22\3\"_$P($T(@("T39"_QT)),U,2)_"\1\\$L(K)&("",V-""[K)\\\1" D R0
	I VERWI="-" D C^cA612 G WEGA
	I VERWI="," D C^cA612 G WEGZ
	I VERWI="V" D
	. K ^DMC(UQC,USC,"SYN",VOLGNR,"LAY",KEUS)
	. ; D SORTL
	. D C^cA612
WEGZ	Q
	;
WIJZ	;  Wijzigen van een bestaande layout
	D P^cA612(12,0,10,80,1,0,1,0,$P($T(@("T24"_QT)),U,2),0,1,1,0,0)
WIJZA	D SCHRIJF
WIJZB	S R="NUME\22\3\"_$P($T(@("T30"_QT)),U,2)_"\\1\\$L(K)&(""12345-""[K)" D R0
	I NUME="-" S EINDE1=1 G WIJZZ
	I NUME="1" D BINDEX G WIJZA
	I NUME="2" D VERPL G WIJZA
	I NUME="3" D LENGTE G WIJZA
	I NUME="4" D ALIN G WIJZA
	I NUME="5" D OUT G WIJZA
WIJZZ	D C^cA612 Q
	;
YZ	Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q
	;
ZZ	; 18.05.04 - 15 u 48 * V8