cAB1291	;Beheer links; %AB123 [ 03/29/01  9:34 AM ]
	G YZ
	;
T0	;Beheer DMC ;            
T1	;Code;
T2	;B-index;
T3	;Nummer element;
T4	;Code;
T6	;Er kunnen geen links worden verwijderd;
T7	;Volgnummer\"Volgnummer van de te verwijderen link";
T8	; Verwijderen link;
T9	;Verwijderen\"V[] = verwijderen   ,[] = hernemen";
T10	; Wijzigen link;
	;
	;  Vraag CODE
CODE	S R="CODE\22\3\"_$P($T(@("T4"_QT)),U,2)_"\\10\\$L(K)\\\\\1" D R0 G CODEZ:K="-"
	S $P(^DMC(UQC,USC,"LINK",VOLGNR),D)=CODE
CODEZ	Q
	;
	; Vraag BINDEX
BINDEX	S R="BINDEX\22\3\"_$P($T(@("T2"_QT)),U,2)_"\\3\\$L(K)&((K?3N)!(""-""[K))\\\\\1" D R0 G BINDEXZ:K="-"
	S $P(^DMC(UQC,USC,"LINK",VOLGNR),D,2)=BINDEX
BINDEXZ	Q
	;
	;  Wijzigen van een bestaande link
S1	N VOLGNR,CODE,BINDEX S $ZT="TRAP^cAN000"
S1A	D P^cA612(16,0,6,80,1,0,1,0,$P($T(@("T10"_QT)),U,2),0,1,1,0,0)
S1B	S VOLGNR=$P(MTAB(KEUZE),D)     
S1C	S CODE=$P($G(^DMC(UQC,USC,"LINK",VOLGNR)),D)
S1D	S BINDEX=$P($G(^(VOLGNR)),D,2)
S1E	D SCHRIJF
S1F	S R="NUME\22\3\"_$P($T(@("T3"_QT)),U,2)_"\\1\\$L(K)&(""12-""[K)" D R0 G S1Z:K="-"
S1G	I NUME="1" D CODE G S1E
S1H	I NUME="2" D BINDEX G S1E
S1Z	D C^cA612 Q
	;
	;  Maken van een nieuwe link
S2	N CODE,BINDEX,NIEUW S $ZT="TRAP^cAN000"
S2A	S CODE="",BINDEX="",NIEUW=""
S2B	S NIEUW=$O(^DMC(UQC,USC,"LINK",NIEUW),-1)
S2C	S NIEUW=NIEUW+1
S2D	K SWOUT
S2E	D P^cAN230("DMC.LINK","DAM","")
S2F	I $G(SWOUT) K SWOUT S ^DMC(UQC,USC,"LINK",NIEUW)=CODE_D_BINDEX     
S2G	D SORT
S2Z	Q
	;
	;  Verwijderen van een link
S3	N VOLGNR,CODE,BINDEX S $ZT="TRAP^cAN000"
S3A	I NR=0 S K=$P($T(@("T6"_QT)),U,2) D TXT^cAFA1(250) G S3Z
S3B	S R="VOLGNR\22\3\"_$P($T(@("T7"_QT)),U,2)_"\2\\$L(K)&((K?.N&(K'<1)&(K'>NR))!(""-""[K))" D R0 G S3Z:K="-"
S3C	D P^cA612(16,0,6,80,1,0,1,0,$P($T(@("T8"_QT)),U,2),0,1,1,0,0)
S3D	S CODE=$P($G(^DMC(UQC,USC,"LINK",VOLGNR)),D)
S3E	S BINDEX=$P($G(^(VOLGNR)),D,2)
S3F	D SCHRIJF     
S3G	S R="VERWI\22\3\"_$P($T(@("T9"_QT)),U,2)_"\1\\$L(K)&("",V-""[K)\\\1" D R0 G S3Y:K=","
S3H	I VERWI="-" D C^cA612 G S3B
S3I	I VERWI="V" K ^DMC(UQC,USC,"LINK",VOLGNR) D SORT
S3Y	D C^cA612
S3Z	Q
	;
	;  In een venster plaatsen van de link
SCHRIJF	W /CUP(2,2),@F2,"1 ",@F6,$P($T(@("T1"_QT)),U,2),@F9,"    : ",$P($G(^DMC(UQC,USC,"LINK",VOLGNR)),D)
	W /CUP(3,2),@F2,"2 ",@F6,$P($T(@("T2"_QT)),U,2),@F9," : ",$P($G(^DMC(UQC,USC,"LINK",VOLGNR)),D,2)
SCHRIJFZ	Q
	;
	;  Sorteren van de links
SORT	S TEL=0,I1=""
	K ^HULP(boot,$J+.07)
	F  S I1=$O(^DMC(UQC,USC,"LINK",I1)) Q:I1=""  D
	. S TEL=TEL+1
	. M ^HULP(boot,$J+.07,TEL)=^DMC(UQC,USC,"LINK",I1)
	K ^DMC(UQC,USC,"LINK") 
	M ^DMC(UQC,USC,"LINK")=^HULP(boot,$J+.07)
	K ^HULP(boot,$J+.07)
SORTZ	Q
	;
YZ	Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q
	;
ZZ	; 18.05.01 - 11 u 18 * V7.86