cABVB03	;Functies ivm beheer grid : copy-functies;  cABVB01
	;
	G YZ
	;
T0	;Functies ivm beheer grid;
T1	;Kolom ; komt niet voor in tab ;Kolom werd niet gekopieerd;
T2	;Tab ; bestaat niet in grid ;
T3	;Tabs van grid ;Grid heeft nog geen tabs;
T4	;Kolommen van tab ;Tab heeft nog geen kolommen;
T5	;Kopieer kolom ;
	;
CPCOL(GRID,TABNR)	; copy kolom : vraagstelling + uitvoeren
	; GRID   = GRIDId naarwaar gekopieerd wordt
	; TABNR  = TABId naarwaar gekopieerd wordt
	;
	N COLID,B,GRIDF,TABNRF,COLNRF,OK,K,COLUI1,UI1
	S $ZT="TRAP^cAN000",COLUI1=""
	D P^cA612(15,1,25-15,80,1,1,1,1,$P($T(@("T5"_QT)),U,2),0,1,0,0,0)
CPCOLA	S COLID=$$CPCOLV() I '$L(COLID) G CPCOLZ
	S B=^VBN(0,"GRID.TAB.COL",COLID,0)
	S GRIDF=$P(B,D),TABNRF=$P(B,D,3),COLNRF=$P(B,D,4)
	; Bevestigen
	S K=$P($T(@("T5"_QT)),U,2)_GRIDF_" "_TABNRF_" "_COLNRF_" : "_$S($L($P(B,D,5)):$P(B,D,5),1:$P(B,D,6)) D TXT^cAFA1(250) I K="-" G CPCOLA
	S COLUI1=$$CPCOLNR(GRIDF,TABNRF,COLNRF,GRID,TABNR,1)
	I $P(COLUI1,D)=0 S K=$P(COLUI1,D,2)_$S($L($P(B,D,5)):$P(B,D,5),1:$P(B,D,6)) D TXT^cAFA1(250) G CPCOLA
	S UI1=COLUI1 D W^cAN200("GRIDN.TAB.COL","","","",$$IDEM^cAFA1)
CPCOLZ	D C^cA612 Q COLUI1
	;
CPCOLNR(GRIDF,TABNRF,COLNRF,GRID,TABNR,SWVBNET)	; Copy kolom (standaard)
	; GRIDF  = GRIDId standaard vanwaar gekopieerd wordt
	; TABNRF = TABId Standaard vanwaar gekopieerd wordt
	; COLNRF = ColumnNr standaard vanwaar gekopieerd wordt
	; LIJN0  = node 0 van de kolom waarvan gekopieerd wordt
	; GRID   = GRIDId naarwaar gekopieerd wordt
	; TABNR  = TABId naarwaar gekopieerd wordt
	N BEST,UI1,I1,I2,TAB,i,UI1TAB,UI1GRID,SWCPCOL
	S $ZT="TRAP^cAN000"
	S R=1,BEST=$S($G(SWVBNET):"VBN",1:"VB"),USA=$S($G(SWVBNET):"GRIDN",1:"GRID")_".TAB.COL"
	S UI1COL=GRIDF_" "_" "_" "_TABNRF_" "_COLNRF
	S TAB(1)=$G(@("^"_BEST_"(0,""GRID.TAB.COL"",UI1COL,0)")),TAB(2)=$G(^(1)),TAB(3)=$G(^(2))
	I '$L(TAB(1)) S R="0\"_$P($T(@("T1"_QT)),U,2)_COLNRF_$P($T(@("T1"_QT)),U,3)_GRIDF_" "_TABNRF G CPCOLNRZ
	S $P(TAB(1),D,1,3)=GRID_D_" "_D_TABNR  ; overnemen grid en tabnr
	S $P(TAB(1),D,4)=$$COLNR^cABVB01(GRID," ",TABNR,,$G(SWVBNET)) ; ophalen eerstvolgende nummer
	S $P(TAB(1),D,12-$G(SWVBNET))=$$COLNR^cABVB01(GRID," ",TABNR,112-$G(SWVBNET),$G(SWVBNET)) ; ophalen laatste positie voor de kolommen
	S $P(TAB(1),D,18+$G(SWVBNET))=""  ; parameter op ""
	S UI1TAB=GRID_" "_" "_" "_TABNR,UI1GRID=GRID
	I '$D(@("^"_BEST_"(0,""GRID.TAB"",UI1TAB)")) S R="0\"_$P($T(@("T2"_QT)),U,2)_TABNR_$P($T(@("T1"_QT)),U,3)_GRID G CPCOLNRZ
	S UI1=UI1TAB_" "_$P(TAB(1),D,4)
	S SWCPCOL=1 D P^cAN220(USA,"VB",UI1,"TAB","") S R=NUI1 I K="-" S R="0\"_$P($T(@("T1"_QT)),U,4)
CPCOLNRZ	Q R
	;
CPCOLV()	; Copy kolom vraagstelling : enkel maar voor VB.NET
	N SWVBNET,GRID,TABID,TABNR,RSORT,SWONE,SWCOL,COLID,COLNR,I1,A
	S $ZT="TRAP^cAN000"
	S SWVBNET=1,RSORT=$$GETSORT^cAFA1(),COLID=""
	; grid kiezen
CPCOLVA	S GRID=$$^cANSYN("GRIDN") I GRID="-" G CPCOLVY
CPCOLVB	; ophalen tabs en kiezen
	S I1=GRID_" ",SWONE="" K SWCOL,^HULP("SORT",RSORT)
	; enkel standaard-tabs bekijken, want user-tabs worden meeverwijderd met de standaardtab
	F  S I1=$O(^VBN(0,"GRID.TAB",I1)) Q:$E(I1,1,$L(GRID)+1)'=(GRID_" ")  D  
	. S A=^(I1,0)
	. S ^HULP("SORT",RSORT,$P(A,D,3))=A,^($P(A,D,3),1)=I1
	S TABNR=$O(^HULP("SORT",RSORT,"")) I '$L(TABNR) S K=$P($T(@("T3"_QT)),U,3) D TXT^cAFA1(250) G CPCOLVA
	I TABNR=$O(^HULP("SORT",RSORT,""),-1) S SWONE=1 G CPCOLVCC
CPCOLVC	S TABNR=$$^cANSYN("GRIDN.HULP.SORT","","","","","","",$P($T(@("T3"_QT)),U,2)_GRID) I TABNR="-" G CPCOLVA
CPCOLVCC	S TABID=$P(^HULP("SORT",RSORT,TABNR,1),D)	
CPCOLVD	; ophalen kolommen
	S I1=TABID_" ",SWCOL=1 k ^HULP("SORT",RSORT)
	; enkel standaard-tabs bekijken, want user-tabs worden meeverwijderd met de standaardtab
	F  S I1=$O(^VBN(0,"GRID.TAB.COL",I1)) Q:$E(I1,1,$L(TABID)+1)'=(TABID_" ")  D  
	. S A=^(I1,0)
	. S ^HULP("SORT",RSORT,$P(A,D,4))=A,^($P(A,D,4),1)=I1
	S COLNR=$O(^HULP("SORT",RSORT,"")) I '$L(COLNR) S K=$P($T(@("T4"_QT)),U,3) D TXT^cAFA1(250) G CPCOLVA:$G(SWONE),CPCOLVB
	S COLNR=$$^cANSYN("GRIDN.HULP.SORT","","","","","","",$P($T(@("T4"_QT)),U,2)_GRID_" "_TABNR) I COLNR="-" G CPCOLVA:$G(SWONE),CPCOLVB
	S COLID=$P(^HULP("SORT",RSORT,COLNR,1),D)	
CPCOLVY	D RELSORT^cAFA1(RSORT)
CPCOLVZ	Q COLID
	;
YZ	Q
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09