cABVBP17	;Vrije velden
	;
	G YZ
	;
YZ	Q
	;
DEF(DPID)	; Haalt default omschrijvingen + lengte input op voor gekozen referentie
	; Input: DPID: Referentieklasse
	; Output: gescheiden door "\"
	;         1. Omschrijving NL
	;         2. Omschrijving FR
	;         3. Omschrijving DU
	;         4. Omschrijving EN
	;         5. Lengte input
	N @$$INITVAR^cAFVBA01("DPID")
	S $ZT="^dmERROR"
	;
	; Controle parameters
DEF1	S DEF="" I '$L($G(DPID)) G DEFZ
	;
	; ID van doorgegeven klasse bepalen
DEF2	S PROPID=$P($$FORMDEF^cABVBP15(DPID),D,4) I '$L(PROPID) G DEFZ
	; 
	; Tabel met omschrijvingen opbouwen
DEF3	S GRIDID=$$FORMTL^cABVBP15("",PROPID) I 'GRIDID G DEFZ
	;
	; Tabel omzetten naar output
DEF4	S i="" F  S i=$O(^mtemp99(GRIDID,"COMMON",i)) Q:'$L(i)  D
	. S N=^(i,0),TK=$P(N,D,2),TKOMS=$P(N,D,3)
	. S $P(DEF,D,$S(TK="N":1,TK="F":2,TK="D":3,TK="E":4,1:5))=TKOMS
	K ^mtemp99(GRIDID) S DEF=$P(DEF,D,1,4)
	;
	; Lengte input
DEF5	S $P(DEF,D,5)=$$SIG^cAFA1("DP.PROP",PROPID,203)
	;
DEFZ	Q DEF
	;
VV(DDC,VB)	; Verwerk vrije velden
	; Input: DDC: Klasse
	;        VB: Opgestart vanuit dotNET?
	;
	N @$$INITVAR^cAFVBA01("DDC,VB")
	S $ZT="^dmERROR"
	;
	; Opzetten variabelen
VV1	D DMS^cAN000("UQC","USC","DC",1) I '$L(UQC)!'$L(USC) G VVZ
	S UREF=^DMC(UQC,USC,"DATA","REF"),R=1
	;
	; Controle parameters
VV2	I '$L($G(DDC)) G VVZ
	S UI1=DDC I '$D(@UREF) G VVZ
	S DDP=DDC I $L($P(@UREF@(0),D,33)) S DDP=$P(@UREF@(0),D,33)
	;
	; Stap I: Einddefinitie aanmaken
VV3	I $G(VB) W !,"START"
	S GRIDID=$$BTEMPSEL^cABVBK1("",DDC) I 'GRIDID S R=GRIDID G VVY
	S R=$$BDDP^cABVBK1(GRIDID,"") I 'R G VVY
	I $G(VB) W !,"STEP"
	;
	; Stap II: Klasse aanmaken + compileren + DMA aanpassen
VV4	S R=$$BTEMPSEL^cABVBP1(GRIDID,DDP)
	S R=$$BUILD^cABVBP1(GRIDID,Q,1,1,1,2,"","","","0;") I 'R G VVY
	I $G(VB) W !,"STEP"
	;
VV5	; Stap III: Forms aanpassen
	D DMS^cAN000("UQC","USC","FORMN",1) I '$L(UQC)!'$L(USC) G VVY
	S UREF=^DMC(UQC,USC,"DATA","REF")
	S UI1="" F  S UI1=$O(@UREF) Q:'$L(UI1)  D  Q:'R
	. S N=^(UI1,0) I $P(N,D,4)'=DDP Q ; Check op klasse
	. I '$P(N,D,5) Q ; Check op switch vrije velden                  
	. I $E(UI1,1,3)="VV." Q ; Check op grid opgezet via beheer VV
	. S R=$$MKFORM^cABVBP15(UI1,DDP,.OVERWR,4,"")
	I $G(VB) W !,"STEP"
	;
VV6	; Stap IV: Grids aanpassen
	I $G(VB) W !,"STEP"
	D DMS^cAN000("UQC","USC","GRIDN",1) I '$L(UQC)!'$L(USC) G VVY
	S UREF=^DMC(UQC,USC,"DATA","REF")
	S UI1="" F  S UI1=$O(@UREF) Q:'$L(UI1)  D  Q:'R
	. S N=^(UI1,0) I $P(N,D,21)'=DDP Q ; Check op klasse
	. I '$P(N,D,22) Q ; Check op switch vrije velden
	. S OVERWR(101)=UI1
	. S R=$P($$MKGRID^cABVBP14(DDP,.OVERWR,"","",4,""),D)
	I $G(VB) W !,"STEP"
	;
	; Opkuis
VVY	I $G(GRIDID) K ^mtemp99(GRIDID)
	I $G(VB) W !,"STOP"
	;
VVZ	Q R
	;
	; *******************************************************************************
	; Functies
	; *******************************************************************************
	; 
ISVV(UI1,SW)	
	; SW = "",0: UI1 = DP.PROP
	;      1: UI1=DD
	;      2: UI1 = DC.PROP  
	N R
	I $G(SW)=1 S R=(UI1="11111") G ISVVZ
	S R =($$DATA^cAFVBO01($S($G(SW)=2:"DDC",1:"DDP"),0,"KLASSE.PROP",UI1,105)="11111")
	;
ISVVZ	Q R
	;
VVN1()	; Node 1 van default vrij veld
VVN1Z	Q "1000\0\10\\\10\\\3\0\0\\"
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09