cAFA0(R0,LN,KL,RL,RC,KEYS,TM,SW,AUTO)	 ;Input ;%AFA0 ; [ 10/20/00  11:06 AM ]
	;
T0	;input ;
	;
T0F	;Input ;
	;
T0E	;input ;
	;
1	N R1,RI,RJ,RT S TM=$G(TM),SW=$G(SW),AUTO=$G(AUTO)
	N RH0,RH1,RHH D H0,H1    ; time-out voor $C(0) en F3
11	S R1=$S(AUTO:$P(AUTO,D,3),1:1),RI=$S(AUTO:$P(AUTO,D,2),1:0),RJ=$C(250),$P(RJ,RJ,RL)=RJ,RT=0
13	S R0=$E(R0_RJ,1,RL),KEYS=D_KEYS_D
15	I $ZV["MSM" U 0:(0::::1+4+64+4096+65536:524288+4194304:::$C(13))
17	I $ZV'["MSM" U 0:(0:"S")
19	I '$G(QW) G ^cAFA0V5
	;
	; extra input-venster
2	I RL D O^cA612(LN,KL,1,RL,0,1,1,1) W /SGR(RC),/WSCRON
	;
	; tonen volledige input
3	I RL W /CUP(1,1),/WCSGR(RC,4)
31	I 'SW W $TR(R0,$E(RJ),$C(U("D","RT")))
33	I SW=1 S K=$P(R0_RJ,RJ) W /WSCROFF,$TR(RJ,$E(RJ),$C(U("D","RT"))),/CUP(1,1) D  W /WSCRON
	. N I F I=1:1:$L(K) W "*"
	;
	; F4 = terug naar menu
	I $G(F4TOMENU),$G(F4TOMENU)<99 S RK=4 G 6
	;
	; positionering cursor
4	I RL W /CUP(1,R1) I RI W /WCSGR(5,0)
41	S RHH=$P($H,",",2)-RH0 I RHH<0 D H0
	I $G(U("T",0))>0,RHH>U("T",0) W $C(0) D H0        ; time-out $C(0)
	S RHH=$P($H,",",2)-RH1 I RHH<0 D H1
	I 'TM,$G(U("T",1))>0,RHH>U("T",1) S RK=3 G 6      ; time-out F3
	R *K:1                                            ; lees 1 karakter
	K F4TOMENU
	I $ZV["MSM" S RZA=$ZA,RZB=$ZB\256,RZC=$ZC
	I $ZV'["MSM" S RZA=$ZA,RZB=$ZB,RZC=RZA\256#2 I '$T S (RZB,RZC)=""
43	I RZC D S2 G 41                                   ; foutdetectie
45	I $ZV["MSM",K>0&'RZB S:K<27 RZB=K+64 S:K=27!(K=127) RZB=K
	I $ZV'["MSM",K>0,K=$A(RZB) D
	. I K=127 S RZB=K Q           ; backspace
	. I K<27 S RZB=K+64 Q         ; ^A ... ^Z
	. I K>27 S RZB=""             ; karakter
47	I $ZV["MSM",RZB S K="",RK=$G(U("D",RZB),0) G 6
	I $ZV'["MSM" I $L(RZB) D  S K="",RK=$G(U("D",RZB),0) G 6
	. I RZB?.E1C.E D              ; escape-string
	.. S RZC=RZB,RZB=""
	.. F K=1:1:$L(RZC) S RZB=RZB_$A(RZC,K) I K<$L(RZC) S RZB=RZB_" "
49	I K<1 S RT=RT+1 G 41:RT<TM!'TM S RK=35 G 6
	;
	; gewone input
5	D H0,H1 S RT=0,RK=$C(K) I RK?1C!(RK=D)!'RL D S2 G 41
51	I RI,$E(R0,RL)'=$E(RJ) D S2 G 41
53	S R0=$S(R1>1:$E(R0,1,R1-1),1:"")_RK_$E(R0,R1+1-RI,RL-RI)
54	I AUTO,R1=RL S RK=32 G Y                          ; wrap-functie
55	I R1<RL S R1=R1+1
57	G 3:RI!SW W RK G 4
	;
	; speciale toetsen
6	D H0,H1 S RT=0
601	;                                                 ; F1
602	;                                                 ; F2
603	I RK=3 S RK=27                                    ; F3
604	I RK=4 S F4TOMENU=$G(F4TOMENU)+1,RK=27            ; F4
	I RK'=28,KEYS[(D_RK_D) G Y
621	I RK=21 D  G 3                                    ; Insert
	. I 'RL D S2
	. E  S RI='RI I 'RI W /WCSGR(25,0)
622	I RK=22 D  G 3                                    ; Delete
	. I RL S R0=$S(R1>1:$E(R0,1,R1-1),1:"")_$E(R0,R1+1,RL)_$E(RJ)
	. E  D S2
623	I RK=23 D  G 3:RI,4                               ; Home
	. I RL S R1=1
	. E  D S2
624	I RK=24 D  G 3:RI,4                               ; End
	. I RL S R1=$F(R0_RJ,RJ)-RL I R1>RL S R1=RL
	. I 'RL D S2
625	I RK=25,'RL G Y                                   ; PgUp
626	I RK=26,'RL G Y                                   ; PgDn
627	I RK=27,'RL G Y                                   ; Escape
628	I RK=28 D  G Y                                    ; Enter
	. I RL S K=$P(R0_RJ,RJ),K=$TR(K,$E(RJ)," ")
629	I RK=29,'RL G Y                                   ; Tab     
630	I RK=30 D  G 3                                    ; Backspace
	. I RL,R1>1 S R0=$S(R1>2:$E(R0,1,R1-2),1:"")_$E(R0,R1,RL)_$E(RJ),R1=R1-1
	. E  D S2
631	I RK=31,'RL G Y                                   ; Pijl Omhoog
632	I RK=32,'RL G Y                                   ; Pijl Omlaag
633	I RK=33 D  G 3:RI,4                               ; Pijl Links
	. I RL,R1>1 S R1=R1-1
	. E  D S2
634	I RK=34 D  G 3:RI,4                               ; Pijl Rechts
	. I RL,R1<RL S R1=R1+1
	. E  D S2
635	I RK=35 D  G Y                                    ; Timed-out
	. I RL S K=$P(R0_RJ,RJ),K=$TR(K,$E(RJ)," ")
668	I RK=68 D  G Y:R1=1&AUTO,3                        ; ^D
	. I RL S R0=$E($S(R1>1:$E(R0,1,R1-1),1:"")_RJ,1,RL)
	. E  D S2
	;
7	D S2 G 41
	;
Y	I RL D C^cA612
YA	I AUTO S RK=RK_D_RI_D_R1 I RL S K=$P(R0_RJ,RJ),K=$TR(K,$E(RJ)," ")
YX	I $ZV["MSM" U 0:(0:::::1+64+2097152+8388608:::$C(13))
YY	I $ZV'["MSM" U 0:(0:"")
YZ	S %time=$H Q
	;
H0	S RH0=$P($H,",",2) Q     ; time-out $C(0)
H1	S RH1=$P($H,",",2) Q     ; time-out F3
	;
S2	W $C(7) Q
	;
	; opladen driver
DRV	N R1,R2,R3 I $ZV["MSM" D OFF^cMODESET(13)
	D MASTER^cQ5:'$D(boot) s io=$G(io,$$IO^cQ5)
DRVA	S R1=$P($G(^cLOG(boot,"DEV",io)," "),D),R2=1 I $ZV'["MSM" S R2=3
DRVB	I $D(^cLOG(0,"DRV",R1)),$L(^(R1)) S R2=^(R1)
DRVC	S R1="" F  S R1=$O(^cLOG(0,"DRV",R2,R1)) Q:R1=""  S R3=^(R1) I R3<5!(R3>20) S U("D",R1)=R3
DRVZ	Q
	;
ZZ	; 29.10.02 - 11 u 38 * V7.93